My Experiments with ABAP

Inbound EDI Message Processing with Custom Function Module

2012-02-13T21:03:00.003+05:30

SAP supports almost all industry standards EDI Message. All components to process these EDI messages are already defined in system and just need to be activated for business partner to make it work. However there are occasions when you need to start from blank canvas, build all the components to process a totally new message. If you are unfortunate enough here are steps you must follow to make it work. You can reuse some of SAP standard component for example IDoc segments, IDoc type Message type etc. if you do so you can skip corresponding steps below.

1. IDoc Structure

This defines the structure of data. SAP runtime will use this structure definition to validate, store and display data. It’s a two-step process you defined structures first similar to one you defined in SE11 and then using these structures define IDoc type which is tree like structure of IDoc segments with parent and child relationship.

a. WE31 - Define IDoc segments

b. WE30- Define IDoc Type

2. Define Message Type-WE81

Message type is logical definition of what information will be there in IDoc.

3. Link IDoc type and message type Link using transaction WE82

An IDoc type can be used in one or more Message type and vice versa.

For example in SAP inbound message type ORDERS (purchase order) and ORDCHG (purchase order change) uses same IDoc type. This means that although ORDERS and ORDCHG are different type of transactions, the data is in same format (ORDER05). Other way round also possible i.e. same message type for example ORDCHG can be represented by different IDoc type.

In WE82 you define what possible combination of IDoc Type and Message Type is possible in system.

4. Create a new function module

Data in IDoc is usually processed by a function module. This function module extract data from IDoc structure, validates, store/post and update status of IDoc in SAP. This function module is called at run time by SAP runtime and must have following interface.


*"       IMPORTING
*"              INPUT_METHOD          LIKE  BDWFAP_PAR-INPUTMETHD
*"              MASS_PROCESSING       LIKE  BDWFAP_PAR-MASS_PROC
*"       EXPORTING
*"              WORKFLOW_RESULT       LIKE  BDWFAP_PAR-RESULT
*"              APPLICATION_VARIABLE  LIKE  BDWFAP_PAR-APPL_VAR
*"              IN_UPDATE_TASK        LIKE  BDWFAP_PAR-UPDATETASK
*"              CALL_TRANSACTION_DONE LIKE  BDWFAP_PAR-CALLTRANS
*"       TABLES
*"              IDOC_CONTRL           STRUCTURE  EDIDC
*"              IDOC_DATA             STRUCTURE  EDIDD
*"              IDOC_STATUS           STRUCTURE  BDIDOCSTAT
*"              RETURN_VARIABLES      STRUCTURE  BDWFRETVAR
*"              SERIALIZATION_INFO    STRUCTURE  BDI_SER
*"       EXCEPTIONS
*"              WRONG_FUNCTION_CALLED

IDoc processing function modules are usually named based on direction of IDoc (inbound/outbound) and message type. So an inbound processing routine for message ORDRSP would be IDOC_INPUT_ORDRSP. An outbound processing routine for message ORDRSP would be IDOC_OUTPUT_ORDRSP.

Refer to a standard inbound processing function module like IDOC_INPUT_ORDRSP to see how data is extracted and IDoc status are updated from function module. You can copy one of these function module to create your own with similar interface.

5. Configure your inbound function module - BD51

Add a line in BD51 for your inbound function module.

6. Assignment of Function Module to Logical Message and IDoc Type – WE57

Here you bring everything together i.e. define a line with you Function Module, IDoc Type and Message Type.

7. Inbound Process Code – WE42

Define a new process code which refers to your Inbound Function Module.

8. Partner Profile configuration – WE20

Finally in partner profile configure this new message and process code.

Adding Custom field(s) to Quality Notification QM01/QM02//QM03/QM10

2011-12-30T16:13:00.001+05:30

As you can gather from the heading this is about adding custom field to Quality Notification transactions in SAP, this change will affect transaction QM01, QM02 and QM03. And with few modifications new field(s) which you will add will also be shown in report QM10.

We will start with modifying the base table to add new field to table, of course append table will be used to add new field and this is where data will be stored. After this user-exit (screen-exit) need to be implemented which will be used to accept input and display data in QM0x transactions. There is small config required at this stage and to end with we will modify a sap standard structure again using append structure so this new field will be displayed in report QM10.

1. Modify Base Table

Table QMEL stores QM notification data and new field should be added to this table.

To add new field, first thing we need to do is add an append structure. Open table QMEL in SE11 and navigate to 'Append Structure' option.

On next screen click on 'Create Append'

Give a name starting with ZZ. If an append structure already exists with name starting with ZZ then you can skip adding new append structure and instead you can add your field to that append structure. Once structure is in place, add your fields to the structure. Use appropriate data element and domain.

If any field is of type quantity or amount don’t forget to mention unit and currency.And define enhancement category as you would do while defining any table.

Finish this step with activating the append structure. If QMEL table in Production system is huge then consider moving transport when in weekends.

2. Config to Add Customer screen to Notification type Screen

If you are involved in initial configuration of notification type then you would probably know that screen tabs and screen groups (subscreen) within screen tabs are configurable in QM01 transaction. Anyways, even if you don’t know just remember we need to specify the position of these new fields on the screen.

In next few steps we will place these new fields on subscreen (screen-exit). In notification type configuration we need to specify under which tab this subscreen is going to appear in QM01.

So in transaction SPRO, navigate to menu path Quality Management, Quality Notification, Overview of Notification Type.

Select the notification type which you would like to modify and double click on 'Screen Structure for Extented view'. Extended view shows you all the tabs available and configured to be shown on QM data entry transaction. Double click on the tab where you would like to display you subscreen. Note that on each tab maximum 5 subscreens can be shown.

Here, before you choose the position of customer subscreen you need to make a decision. SAP allows you to use either one customer-specific area (090) for all notification type or one for each notification type (091). In simple terms if the field you are going to add is valid across all notification type and you would like this field to appear in every notification type then use customer specific area 090. Otherwise, if field is specific to a notification type then you would select 091 in customer screen. When you enter 091 as customer screen SAP would let to enter screen number where the fields are defined.

In this particular case I am going to choose 091 as screen area as my field are specific to this notification type. And I am going to define subscreen number as 100.

At this point save the config and exit.

If you execute QM01 transaction for given notification type then system should throw ABAP runtime error. As subscreen area 100 does not exist in system yet. Good way to check if config is right.

3. Implement Enhacement (User and Screen exit)

Create a new project in transaction CMOD and add enhacement QQMA0001 to project.
Open function group XQQM in SE80 and create subscreen 100 in it, make sure to define width of screen as 83 column so that it blend in with SAP standard subscreens.

Place your input field on the subscreen. Write code to disable input when transaction is QM03. You also need to implement following functon moodule and create respective include.

EXIT_SAPMIWO0_008 include ZXQQMU07

This function module will pass data from QM0x transaction to you subscreen.

EXIT_SAPMIWO0_009 include ZXQQMU08

Use this function module to pass data from custom input fields back to QM0x transaction. So when user hit Save button your data will be saved along with all sap-standards field.

4. Modifying Reporting Structure to include customer field in QM10 transaction

Now its time to add custom field to report QM10 - List quality notification.
Modify structure RQMQMEL1 to include your custom field(s). Again use append structure and activate once done. After this your fields will automatically appear in report.

Update SAP Shipment

2011-12-29T21:12:00.003+05:30

Below are two very basic code to update shipment data in SAP. First method uses BDC on VT02N and second uses funcion module BAPI_SHIPMENT_CHANGE. Code can be easily modified to suit your requirement.


*&---------------------------------------------------------------------*
*&      Form  update_shipment
*&---------------------------------------------------------------------*
*       Update Shipment using BDC
*----------------------------------------------------------------------*
*      -->IV_TKNUM   Shipment Number
*      -->IV_DATE    Actual Shipment End Date
*      -->IV_TIME    Actual Shipment End Time
*----------------------------------------------------------------------*
FORM update_shipment  USING    iv_tknum TYPE vttk-tknum
                               iv_date  TYPE vttk-daten
                               iv_time  TYPE vttk-uaten .

  DEFINE insert_field.
    clear ls_bdcdata .
    ls_bdcdata-fnam = &1 .
    ls_bdcdata-fval = &2 .
    append ls_bdcdata to li_bdcdata .
  END-OF-DEFINITION.
 
  DEFINE insert_scr.
    clear ls_bdcdata .
    ls_bdcdata-program  = &1 .
    ls_bdcdata-dynpro   = &2 .
    ls_bdcdata-dynbegin = 'X' .
    append ls_bdcdata to li_bdcdata .
  END-OF-DEFINITION.
 
  DATA : li_bdcdata TYPE TABLE OF bdcdata ,
         ls_bdcdata TYPE          bdcdata ,
 
         lv_date    TYPE          char10  ,
         lv_time    TYPE          char8   ,
 
         lv_mode    TYPE          char01  VALUE 'N' .
 
  insert_scr   'SAPMV56A'   '1011' .
  insert_field 'BDC_OKCODE' '=MM_TKAL' .
  insert_field 'VTTK-TKNUM' iv_tknum .
 
  WRITE iv_date TO lv_date .
  WRITE iv_time TO lv_time .
  insert_scr   'SAPMV56A'   '1020'       .
  insert_field 'BDC_OKCODE' '=MM_SICH'   .
  insert_field 'VTTK-DATEN' lv_date .
  insert_field 'VTTK-UATEN' lv_time+0(5) .
 
  CALL TRANSACTION 'VT02N' USING li_bdcdata MODE lv_mode.
 
ENDFORM.                    "update_shipment

Beware that this function module BAPI_SHIPMENT_CHANGE is not released officially.


*&---------------------------------------------------------------------*
*&      Form  update_shipment
*&---------------------------------------------------------------------*
*       Update Shipment using BAPI
*----------------------------------------------------------------------*
*      -->IV_TKNUM   text
*      -->IV_TEXT1   text
*----------------------------------------------------------------------*
FORM update_shipment  USING    iv_tknum TYPE vttk-tknum
                               iv_text1  TYPE vttk-text1 .
 
  DATA: ls_hdrdata    TYPE bapishipmentheader       ,
        ls_hdrdataact TYPE bapishipmentheaderaction ,
        lt_return     TYPE TABLE OF bapiret2        ,
        ls_return     TYPE bapiret2                 .
 
  ls_hdrdata-shipment_num           = iv_tknum.
 
  ls_hdrdata-text_1                 = iv_text1.
  ls_hdrdataact-text_1              = 'C'.
 
  CALL FUNCTION 'BAPI_SHIPMENT_CHANGE'
    EXPORTING
      headerdata       = ls_hdrdata
      headerdataaction = ls_hdrdataact
    TABLES
      return           = lt_return.
 
  CALL FUNCTION 'BAPI_TRANSACTION_COMMIT' .
 
ENDFORM.                    "update_shipment

Table Maintenance with Create/Modified Information Automatically Filled in

2011-11-15T04:47:00.001+05:30

If you are creating custom table which would be used as configuration table i.e. content of table would be rarely changed, then creating a custom build data entry screen is not worth the effort. In such cases using table maintenance generator is highly justified. Table Maintenance Generator is very powerful tool to create basic data entry screen. Although entry screen is basic, it comes with standard function of value help, value checked against check table, duplication check on primary key etc. With all these features within few minute it can provide you data entry screen with insert, change and delete function.

Table maintenance generator creates a function group which is combination of sap-standard includes, custom program and screen. The custom (usually name starting with Z) part of function group can be changed to add specific requirement. In this blog I will discuss about filling Created by username, create on date, created on time automatically when new record is inserted. And filling Updated by username, updated on date and updated on time when the record is modified.

Using this information you can certainly answer who created or last updated the record and when. If there is further requirement to track every change then I would recommend creating you own data entry screen and use Change Object Technique to log changes.

So, I have created a table as shown in screen shot below.

Notice that it has field ERNAM, ERDAT, ERZET and AENAM, AEDAT, AEZET. These fields stores the information which I would like table maintenance to fill-in automatically.

All these changes are done in following steps.

1. Create table maintenance
2. Hide the columns
3. Event to fill-in Created by Information
4. Event to fill-in Updated information

Step 1 Create table maintenance
Create table maintenance using table maintenance generator. At this stage you will have every column displayed in your screen.

Step 2 Hide the columns
You can either hide or deactivate these columns as we don’t want users to change these values. Open then function group created in SE80 and double click on screen which has table control. In the PBO just before the LOOP AT extract WITH CONTROL add a module.

Here, I’ve added module modify_element. Double click on the module and the module in new include.

This code will hide the column from table control.

MODULE modify_element OUTPUT.
  LOOP AT -cols INTO vim_tc_cols.
    IF vim_tc_cols-screen-name = 'ZLBN_ROUTETM-ERNAM' OR
       vim_tc_cols-screen-name = 'ZLBN_ROUTETM-ERDAT' OR
       vim_tc_cols-screen-name = 'ZLBN_ROUTETM-ERZET' OR
       vim_tc_cols-screen-name = 'ZLBN_ROUTETM-AENAM' OR
       vim_tc_cols-screen-name = 'ZLBN_ROUTETM-AEDAT' OR
       vim_tc_cols-screen-name = 'ZLBN_ROUTETM-AEZET' .
 
      vim_tc_cols-invisible = 1 .
      MODIFY -cols FROM vim_tc_cols .
    ENDIF.
  ENDLOOP.
ENDMODULE.                 " MODIFY_ELEMENT  OUTPUT

Note: If you just want to deactivate the column you need to add module within LOOP AT extract WITH CONTOL and put deactivation code in there.

After this, save and activate the function module. At this point if you run table maintenance it should not show you the fields as shown in below screen shot.

Step 3 Event to fill-in Created by Information

We will add two events here which will be used to fill information in field at the time of adding new record and when records are changed.
To add event open table maintenance generator in change mode then in menu path Enviroment->Events add event 01 and 05 put a subroutine name and create subroutine by hitting button next to name.

In the form routine under event 05 add code which will fill created user, date and time information.

FORM zlbn_routetm_new_entry .
  zlbn_routetm-ernam = sy-uname .
  zlbn_routetm-erdat = sy-datum .
  zlbn_routetm-erzet = sy-uzeit .
ENDFORM.                    "ZLBN_ROUTETM_NEW_ENTRY

Step 4 Event to fill-in Updated information

In the form routine under event 01 put following code. This will fill update by information in respective fields.

FORM zlbn_routetm_save .
  FIELD-SYMBOLS : <fs_field> TYPE ANY .
 
  LOOP AT total .
    CHECK <action> EQ aendern.
    ASSIGN COMPONENT 'AENAM' OF STRUCTURE <vim_total_struc> TO <fs_field> .
    IF sy-subrc = 0 .
      <fs_field> = sy-uname .
    ENDIF.
 
    ASSIGN COMPONENT 'AEDAT' OF STRUCTURE <vim_total_struc> TO <fs_field> .
    IF sy-subrc = 0 .
      <fs_field> = sy-datum .
    ENDIF.
 
    ASSIGN COMPONENT 'AEZET' OF STRUCTURE <vim_total_struc> TO <fs_field> .
    IF sy-subrc = 0 .
      <fs_field> = sy-uzeit .
    ENDIF.
 
    READ TABLE extract WITH KEY <vim_xtotal_key>.
    IF sy-subrc = 0.
      extract = total .
      MODIFY extract INDEX sy-tabix.
    ENDIF.
 
    MODIFY total.
  ENDLOOP.
 
ENDFORM.                    "ZLBN_ROUTETM_SAVE

At this point all you need is a transaction code and your config table is good to go.

Using field-symbol to speed up LOOP on internal table

2011-10-13T17:26:00.005+05:30

Often we need to LOOP on internal table to apply processing logic to all its record, it also requires updating its contents towards the end of processing.

Most of us use work area to LOOP on an internal table and then use MODIFY statement to update its contents. With every loop pass content of internal table is copied to work area and with MODIFY statement its copied back to internal table. This copying of data to and fro from internal table takes considerable CPU time on application server. Alternative to work area is to use field-symbol to LOOP and MODIFY internal table contents. Field-symbol doesn't hold any data during LOOP, it just point to right record in internal table. And when you change field content it directly modify the content of table. So, there is no copy step involved when field-symbol is used and it increases the performance by many folds.

I am going to demonstrate this performance boost using below example. Below program loops on internal table of type MARA using work area and field-symbol, and reports the time it took to execute these after the execution. Since I haven’t got good number of records in my development server I am going to increase the number of LOOP passes by increasing number of time program loop on internal table using variable C_MULTIPLE.

Program is executed 4 times with increasing number of passes. Result is show in table with time in seconds.

Passes	Work Area	Field-Symbols
5,34,400	0.188	0.031
53,44,000	1.938	0.250
5,34,40,000	19.265	2.515
53,44,00,000	191.226	25.452

With increasing number of loop passes the difference in execution time becomes obivous. Roughly, field-symbol LOOP is 7 times faster than work area LOOP.

REPORT  ztest5.
 
TABLES : mara.
CONSTANTS : c_multiple TYPE i VALUE 10 .
 
DATA : i_mara  TYPE TABLE OF mara ,
       ls_mara TYPE mara          ,
       i_lines TYPE i             .
 
DATA : BEGIN OF wa_times ,
         before_processing TYPE timestampl ,
         after_processing  TYPE timestampl ,
         diff              TYPE tzntstmpl  ,
       END OF wa_times.
 
FIELD-SYMBOLS : <fs_mara> TYPE mara.
 
*Select option for material
SELECT-OPTIONS s_matnr FOR mara-matnr .
 
*--------------------------------------------------------------------*
* Start of Selection
*--------------------------------------------------------------------*
START-OF-SELECTION .
 
* Data selection
  SELECT *
    INTO TABLE i_mara
    FROM mara
   WHERE matnr IN s_matnr .
 
* Find Number of Lines
  DESCRIBE TABLE i_mara LINES i_lines .
  i_lines = i_lines * c_multiple .
  WRITE : 'Number of Lines : ' , i_lines.
 
*--------------------------------------------------------------------*
* Loop using work ares
*--------------------------------------------------------------------*
  GET TIME STAMP FIELD wa_times-before_processing .
  DO c_multiple TIMES.
    LOOP AT i_mara INTO ls_mara .
    ENDLOOP.
  ENDDO.
  GET TIME STAMP FIELD wa_times-after_processing .
 
  CALL METHOD cl_abap_tstmp=>subtract
    EXPORTING
      tstmp1 = wa_times-after_processing
      tstmp2 = wa_times-before_processing
    RECEIVING
      r_secs = wa_times-diff.
 
  WRITE : / 'LOOP INTO TABLE      , time in seconds:' , wa_times-diff .
 
*--------------------------------------------------------------------*
* Loop using field symbol
*--------------------------------------------------------------------*
  GET TIME STAMP FIELD wa_times-before_processing .
  DO c_multiple TIMES.
    LOOP AT i_mara ASSIGNING <fs_mara> .
    ENDLOOP.
  ENDDO.
  GET TIME STAMP FIELD wa_times-after_processing .
 
  CALL METHOD cl_abap_tstmp=>subtract
    EXPORTING
      tstmp1 = wa_times-after_processing
      tstmp2 = wa_times-before_processing
    RECEIVING
      r_secs = wa_times-diff.
 
  WRITE : / 'LOOP ASSIGNING TABLE , time in seconds:' , wa_times-diff .

Defining Context Menu in SAP ABAP Module Pool

2011-09-01T20:21:00.001+05:30

Menu which appear on right mouse button (Shift+F10) are called Context Menus. Usually they are used to provide context sensitive options. In SAP Module pool programming you can define context menu on screen, input/output, text, box and table control. When you define context menu on screen, box or table control all control defined under these element inherits context menu. For example if you define context menu on screen then all elements in screen will show same context menu unless they have got their own context menu defined.

You can create context menu from menu painter by selecting status type 'Context Menu'.

This is how it works. Screen elements on which you can define context menu have property called 'Context Menu Form ON_CTMENU'. Here you need to define a routine name which will be called when user hit right mouse button. See below screen shot which defines context menu forms on screen and box.

Then you need to define these callback routine in your program and name should be in form ON_CTMENU_<name> where name is the input on screen element. In this particular case the callback routine on screen and box will be ON_CTMENU_SCREEN and ON_CTMENU_BOX respectively.

Signature of the form goes as follows.



*&---------------------------------------------------------------------*

*&      Form  on_ctmenu_screen

*&---------------------------------------------------------------------*

*       text

*----------------------------------------------------------------------*

*      -->OB_MENU    text

*----------------------------------------------------------------------*

FORM on_ctmenu_screen USING ob_menu TYPE REF TO cl_ctmenu .

 

  CALL METHOD cl_ctmenu=>load_gui_status

    EXPORTING

      program = sy-cprog

      status  = 'SCR_100'

      menu    = ob_menu.

 

ENDFORM.                    "on_ctmenu_scr_right

 

*&---------------------------------------------------------------------*

*&      Form  on_ctmenu_box

*&---------------------------------------------------------------------*

*       text

*----------------------------------------------------------------------*

*      -->OB_MENU    text

*----------------------------------------------------------------------*

FORM on_ctmenu_box USING ob_menu TYPE REF TO cl_ctmenu .

 

  CALL METHOD cl_ctmenu=>load_gui_status

    EXPORTING

      program = sy-cprog

      status  = 'BOX_100'

      menu    = ob_menu.

 

ENDFORM.                    "on_ctmenu_scr_right

Context menu defined with menu painter are loaded using static method LOAD_GUI_STATUS of class CL_CTMENU. Context menu name is passed to parameter STATUS. In above two subroutine context menu SCR_100 and BOX_100 were loaded.

To summarise steps are

Define context menu in menu painter
Fill name in ON_CTMENU_ on screen element where you want context menu to be assigned.
Define callback routine in program and loaded the required context menu be calling method CL_CTMENU=>LOAD_GUI_STATUS.
Write code to handle user input as usual in USER_COMMAND.

SAP QM Notification - Setting up Output/Shop floor paper

2011-08-25T02:29:00.004+05:30

SPRO->Quality Management->Quality Notifications->Notification Processing->Print Control->Define Shop paper, Form, Print Program

It’s two-step process, in first step 'Define Shop Paper' output is defined in terms of print program in and sap-script name. For example if you have three different kind of output which needs to be printed from Notification then you define each in 'Define Shop Papers'.

After outputs are defined, they are assigned to Notification type using second option. While assigning the outputs to Notification type you can use wild card, you can save time if you carefully name the output types in first step.

If your required output is similar to the one defined in SAP then you can just copy the existing output type, use same output program and change the form (sapscript) name. Create this sapscript by copying the sap-standard sapscript and modify that.

However if your requirement is totally different and you would like to change the output program as well then copy the output in here and change both output and form name.

Pay attention to the number used to define outputs here, both these output 5010 and 5011 is used in Notification type F1 and in next step we will see how these are assigned.

Once you have defined all outputs save and exits screen. Then select option 'Assign Shop Papers to Notification Type'.

To assign both form 5010 and 5011 to notification type F1 you can use wild card 501*.

Individual outputs can also be assigned by inserting record and entering notification type and output number.

Selection Screen and ALV Grid Report on One Screen

2011-08-24T21:50:00.001+05:30

In this blog I am going to show you how you can put both selection screen and ALV Grid on same screen so that user can see both their input and report together.

Concept is based in fact that you can put selection-screen on a module pool subscreen area. For more information read blog SELECT-OPTION in module pool. Based on this idea define a screen with subscreen on the top where a selection screen can be loaded, below that define a customer container where a ALV Grid can be displayed. In user-command of screen reterive and process data and refresh that in ALV Grid.

Ok, lets start with programming.

1. Create a report.
2. Define screen 100 with subscreen area SUB200 on top and a custom container with name CUSTOM below it.
3. Put below code in screen Flow logic tab

PROCESS BEFORE OUTPUT.

MODULE status_0100.

 

CALL SUBSCREEN sub200 INCLUDING sy-repid '0300' .

 

PROCESS AFTER INPUT.

 

CALL SUBSCREEN sub200.

MODULE user_command_0100.

4. Define GUI status ZPF01 with function code BACK, CANC, EXIT and OK.

5. Create a GUI Tile ZTITLE01.

Then copy-paste following code in report.

REPORT  zpwreport.

TABLES : mara .

 

DATA : i_mara TYPE TABLE OF mara ,

       ob_custom TYPE REF TO cl_gui_custom_container ,

       ob_grid   TYPE REF TO cl_gui_alv_grid         .

 

SELECTION-SCREEN BEGIN OF SCREEN 300 AS SUBSCREEN .

SELECT-OPTIONS : s_matnr FOR mara-matnr.

SELECTION-SCREEN END OF SCREEN 300.

 

START-OF-SELECTION .

  CALL SCREEN 100 .

 

*&---------------------------------------------------------------------*

*& Module status_0100 OUTPUT

*&---------------------------------------------------------------------*

MODULE status_0100 OUTPUT.

  SET PF-STATUS 'ZPF01' .

  SET TITLEBAR  'ZTITLE01' .

 

  PERFORM create_grid .

ENDMODULE. " status_0100 OUTPUT

 

*&---------------------------------------------------------------------*

*& Module user_command_0100 INPUT

*&---------------------------------------------------------------------*

MODULE user_command_0100 INPUT.

 

  CASE sy-ucomm.

    WHEN 'BACK' OR 'CANC' OR 'EXIT'.

      LEAVE TO SCREEN 0 .

    WHEN 'OK'.

      SELECT *

        INTO TABLE i_mara

        FROM mara

       WHERE matnr IN s_matnr .

    WHEN OTHERS.

  ENDCASE.

ENDMODULE. " user_command_0100 INPUT

 

*&---------------------------------------------------------------------*

*&      Form  create_grid

*&---------------------------------------------------------------------*

*       text

*----------------------------------------------------------------------*

FORM create_grid .

  IF ob_custom IS INITIAL .

    CREATE OBJECT ob_custom

      EXPORTING

        container_name = 'CUSTOM'.

 

    CREATE OBJECT ob_grid

      EXPORTING

        i_parent = ob_custom.

 

    CALL METHOD ob_grid->set_table_for_first_display

      EXPORTING

        i_structure_name = 'MARA'

      CHANGING

        it_outtab        = i_mara.

 

  ELSE.

    CALL METHOD ob_grid->refresh_table_display.

  ENDIF.

FB60 Enter Vendor Invoice - Base Amount column invisible on Tax Tab

2011-08-18T21:28:00.001+05:30

Usually if a column is not visible in table control, with layout option you can make it visible or change position or length. But on this Tax Data table control which is in FB60 transaction; columns are shown based on certain configuration setting. One such column is 'Tax base amount in document currency' (RTAX1U12-FWBAS). This column is shown only if VAT Proc is configured as 'Changeable Tax Base Amount'

You can see the below screen shot from FB60 before configuration.

Goto to SPRO menu path Financial Accounting(New)->Financial Accounting Global Settings(New)->Tax on Sales/Purchases->Basic Settings->Change Field Control for Tax Base Amount

Add you Tax Procedure in table, if its already not there and tick the checkbox.

And this is screen shot after the configuration.

This setting will also be applied to transaction FB65.

Executing quickview (SQVI) of another user

2011-08-16T15:27:00.000+05:30

List of all quickviews for a user can be found in table AQLTS. In SE16 select records where SPRAS = 'EN', HEAD = 'X', TEXT = 'USERNAME*'. Replace USERNAME by actual SAP user name.
You should get list of all quickviews that particular user have. It's in column TEXT in format USERNAME:QUICKVIEW .
Now go to table TRDIR and select record with name 'AQTG*QUICKVIEW*'. Replace QUICKVIEW with quickview name.
Step3 should give you name of program which is created by quickview. Once you get that you can then use this program name in SE38 to execute the quickview.

SD Tables Access-Performance Tips (from SAP Note 185530)

2011-08-08T01:07:00.030+05:30

Are you having performance problem in your report or considering a secondary index on table to boost performance? Below are the most common ways a SD report can kill a SAP system and how to avoid them.

1. Accesses to sales orders (tables VBAK, VBAP)

a) Search orders for customer number (field VBAK-KUNNR):

*Incorrect:
SELECT FROM vbak WHERE kunnr = ...
*Correct:   
SELECT FROM vakpa WHERE kunde = ...  
SELECT FROM vbak WHERE vbeln = vakpa-vbeln.

b) Search order items for material number (field VBAP-MATNR):

*Incorrect:
SELECT FROM vbap WHERE matnr = ...
*Correct:   
SELECT FROM vapma WHERE matnr = ...    
SELECT FROM vbap WHERE vbeln = vapma-vbeln
                   AND posnr = vapma-posnr

c) Other search helps for sales orders offer the matchcode tables and views M_VMVAx, x. = A, B, C, ... M; for example search for purchase order number of the customer, description and so on

2. Accesses to deliveries (tables LIKP, LIPS)

a) Search for deliveries with customer number (field LIKP-KUNNR):

*Incorrect:
SELECT FROM likp WHERE kunnr = ...
*Correct:
SELECT FROM vlkpa WHERE kunde = ...    
SELECT FROM likp WHERE vbeln = vlkpa-vbeln.

b) Search for delivery items with material number (field LIKP-MATNR):

*Incorrect:
SELECT FROM lips WHERE matnr = ...
*Correct:
SELECT FROM vlpma WHERE matnr = ...    
SELECT FROM lips WHERE vbeln = vlpma-vbeln
                   AND posnr = vlpma-posnr

c) Search for deliveries with sales order number (preceding document, field LIPS-VGBEL):

*Incorrect:
SELECT FROM lips WHERE vgbel = ...
*Correct:
SELECT FROM vbfa WHERE VBELV  = ... 
                   AND VBTYP_N = 'J'    
SELECT FROM lips WHERE vbeln = vbfa-vbeln
                   AND posnr = vbfa-posnn

d) Other search helps for deliveries offer matchcode tables and views M_VMVLx, x. = A, B, C, ... M; for example search for goods issue date, picking date, transportation planning date and so on.

3. Accesses to invoices (tables VBRK, VBRP)

a) Search for invoices with customer number ("payer") (field VBRK-KUNRG):

*Incorrect:
SELECT FROM vbrk WHERE kunrg = ...
*Correct:
SELECT FROM vrkpa WHERE kunde = ...    
SELECT FROM vbrk WHERE vbeln = vrkpa-vbeln

b) Search for invoice items with material number (field VBRP-MATNR):

*Incorrect:
SELECT FROM vbrp WHERE matnr = ...
*Correct:
SELECT FROM vrpma WHERE matnr = ...    
SELECT FROM vbrp WHERE vbeln = vrpma-vbeln
                   AND posnr = vrpma-posnr

c) Search for invoices with delivery number (preceding document, field VBRP-VGBEL):

 
*Incorrect:
SELECT FROM vbrp WHERE vgbel = ...
*Correct:
SELECT FROM vbfa WHERE vbtyp_n = 'M'
                   AND vbelv  = ...    
SELECT FROM vbrp WHERE vbeln = vbfa-vbeln
                   AND posnr = vbfa-posnn

d) Search for invoices with order number (preceding document, field VBRP-AUBEL):

*Incorrect:
SELECT FROM vbrp WHERE aubel = ...
*Correct:
SELECT FROM vbfa WHERE vbtyp_n = 'M'                    
                   AND vbelv   = ...
SELECT FROM vbrp WHERE vbeln = vbfa-vbeln
                   AND posnr = vbfa-posnn

4. Other accesses in SD:

a) Document flow:

*Incorrect:
SELECT vbelv FROM vbfa WHERE vbeln ...

In table VBFA only the preceeding document is used to search for the subsequent document (for example, delivery for order). Searching the other way makes no sense with this table since the preceding documents (for example, order for delivery) are stored directly in the document tables. Thus reading in table VBFA is a one-way street.

*Correct:
SELECT vgbel FROM lips WHERE vbeln = ... 
or
SELECT vgbel FROM vbrp WHERE vbeln = ... 
or
SELECT aubel FROM vbrp WHERE vbeln = ...

b) Search for shipping unit item with delivery

Incorrect:
SELECT FROM vepo WHERE vbtyp = 'J'                    
                   AND vbeln = i_lips-vbeln
Correct:
SELECT FROM vbfa WHERE vbtyp_n = 'X'                    
                   AND vbelv = i_lips-vbeln
SELECT FROM vepo WHERE venum = vbfa-vbeln

Collapsible Area Module Pool Screen - ABAP

2011-07-05T19:20:00.004+05:30

To put it straight and simple, collapsible area is not a predefined screen element or GUI control but it is technique of putting multiple screens in right sequence.

The example which I am going to explain below has one input for material and two blocks representing 'General data' and 'Dimention' (similar to MM02). See screen shot below, for time being just ignore the comments on the screen.

These two blocks are collapible area and to make it work there are 7 screens in total. Out of 7 screens 4 screens are just for layout which represent combination of collapsed and expanded area possible. Below are screen shot of these four layout screen. Each screen has subscreen area where the data will be loaded and a button. Note the icon of button, and the text next to it which helps the user to identify what is missing (collapsed) on the screen. Note thatn these screen are defined as Subscreen.

Both Open.

Top Open, Bottom Collapsed

Top Collapsed, Bottom Open

Both Collapsed

Then there is a main screen will host all above defined subscreen depeding on which button is pressed by user (this will be logic on user command). SUBSCREEN_MAIN is scubscreen area defined on the screen.

And as you might have guessed rest two screen are screens represnting data.

Putting the screen together screen 100 is the main screen which will host one of the screens from 200, 210, 220 and 230 and these screens will in turn load screen 300 and 310 in them. You may like to revisit the first screen shot, it might make more sense now.

Ok that’s enough of explanation let’s start it.

1.Create a report in SE38. You can also create module pool program and then use transaction code to kick start program. Once report is create, I would suggest you to open report in SE80.
2.Add a 'Normal' screen, name it as screen 100. Add an input field MARA-MATNR and a subscreen area SUBSCREEN_MAIN. Put following code in flow logic tab.

3. Create a 'Subscreen', name it as 200 put two buttons and two subscreen area SUB1 and SUB2 as shown in screen shot above. Use icon ICON_DATA_AREA_COLLAPSE for push buttons. Assign function code ‘220’ to the button on top and ‘210’ to button in bottom. Put following code in the flow logic tab of screen.

4.Create a 'Subscreen' 210 as shown in snapshot above. Use icon ICON_DATA_AREA_COLLAPSE and ICON_DATA_AREA_EXPAND. Function code for buttons will be 230 200. Put following code in the flow logic tab of screen.

5.Create 'Subscreen' 220 as shown in snapshot above. Function code for button will be 200 and 230. Put following code in the flow logic tab of screen.

6. Create 'Subscreen' 230 as shown in snapshot above. Function code for buttons will be 210 and 220 respectively. Flow logic for this screen will be empty since there is no subscreen to load in it.

7. Finally define 'Subscreen' 300 and 310 as shown in above screen shot. Use fields from MARA. Flow logic for both the screen will be empty.

8. You need define a PF status 'PFSTAT' and Gui title 'TITLE' . Put BACK and EXIT function code in PF Status.

9. Put following code in report.


*&---------------------------------------------------------------------*
*& Report  ZPWCOLLAPSE
*&---------------------------------------------------------------------*
REPORT  zpwcollapse.
 
TABLES mara .
DATA : gv_screen TYPE char10 VALUE '0200' .
 
CALL SCREEN 100.
 
*&---------------------------------------------------------------------*
*&      Module  STATUS_0100  OUTPUT
*&---------------------------------------------------------------------*
MODULE status_0100 OUTPUT.
  SET PF-STATUS 'PFSTAT'.
  SET TITLEBAR 'TITLE' .
ENDMODULE.                 " STATUS_0100  OUTPUT
 
*&---------------------------------------------------------------------*
*&      Module  USER_COMMAND_0100  INPUT
*&---------------------------------------------------------------------*
MODULE user_command_0100 INPUT.
 
  CASE sy-ucomm.
    WHEN 'BACK' OR  'EXIT'.
      LEAVE TO SCREEN 0 .
    WHEN '200' .
      gv_screen = sy-ucomm .
    WHEN '210' .
      gv_screen = sy-ucomm .
    WHEN '220' .
      gv_screen = sy-ucomm .
    WHEN '230 '.
      gv_screen = sy-ucomm .
    WHEN '' .
      SELECT SINGLE *
        FROM mara
       WHERE matnr = mara-matnr .
      IF sy-subrc <> 0 .
        CLEAR mara .
      ENDIF.
    WHEN OTHERS.
  ENDCASE.
ENDMODULE.                 " USER_COMMAND_0100  INPUT

At this point your SE80 object list should look like this

Ok, that is all. If you now start you report/transaction enter material code in press enter, it should populate corresponding values on screen and then you can play with collapsible part of it. Enjoy!!

Number Range Setting and Enhancement for Sales Order, Billing, Deliveries and Shipment - Part II

2011-07-04T20:40:00.005+05:30

Part I: Number Range Explained, Number range config for Sales Order, Billing, Delivery and Shipment

Number range object for Sales Order, Billing and Deliveries is RV_BELEG. You can either uses transaction SNRO with this object name RV_BELEG or use special transaction created for this number range object, which is VN01.

Number Range Object for Shipment is RV_TRANSPO, which you can see in SNRO transaction or use special transaction VN07.

Configuration of Number range in SAP is can be only done on document types. This poses limitation that one can only have sequential number based on document types. In case these is a legal requirement to maintain sequential number of documents based on other parameters for example customer or country then this cannot be achieved using SAP standard configuration and needs enhancements. Fortunately, SAP has provides exits specifically for this purpose.
Enhancement

Sales Order

Maine Program: SAPMV45A
Include: MV45AFZZ


*---------------------------------------------------------------------*
*       FORM USEREXIT_NUMBER_RANGE                                    *
*---------------------------------------------------------------------*
*       This userexit can be used to determine the numberranges for   *
*       the internal document number.                                 *
*                                                                     *
*       US_RANGE_INTERN - internal number range                       *
*                                                                     *
*       This form is called from form BELEG_SICHERN                   *
*                                                                     *
*---------------------------------------------------------------------*
FORM USEREXIT_NUMBER_RANGE USING US_RANGE_INTERN.
 
* Example: Numer range from TVAK like in standard
* US_RANGE_INTERN = TVAK-NUMKI.
 
ENDFORM.                    "USEREXIT_NUMBER_RANGE

Billing

Function Group: V60A
Include: RV60AFZZ


*---------------------------------------------------------------------*
*       FORM USEREXIT_NUMBER_RANGE                                    *
*---------------------------------------------------------------------*
*       This userexit can be used to determine the numberranges for   *
*       the internal document number.                                 *
*       US_RANGE_INTERN - internal number range                       *
*       This form is called from form LV60AU02                        *
*---------------------------------------------------------------------*
FORM USEREXIT_NUMBER_RANGE USING US_RANGE_INTERN.
 
* Example: Number range from TVFK like in standard
* US_RANGE_INTERN = TVFK-NUMKI.
 
ENDFORM.

Deliveries

Main program: SAPMV50A
Include: MV50AFZ1


*---------------------------------------------------------------------*
*       FORM USEREXIT_NUMBER_RANGE                                    *
*---------------------------------------------------------------------*
*       This userexit can be used to determine the numberranges for   *
*       the internal document number.                                 *
*                                                                     *
*       US_RANGE_INTERN - internal number range                       *
*                                                                     *
*       This form is called from form BELEG_SICHERN                   *
*                                                                     *
*---------------------------------------------------------------------*
FORM USEREXIT_NUMBER_RANGE USING US_RANGE_INTERN.
 
* Example: Numer range from TVLK like in standard
* US_RANGE_INTERN = TVLK-NUMKI.
 
ENDFORM.

Shipment

Enhacement: V56UNUMB Shipment number allocation
EXIT_SAPLV56U_003

Number Range Setting and Enhancement for Sales Order, Billing, Deliveries and Shipment - Part I

2011-07-04T20:29:00.002+05:30

Part II: Number range definition for Sales Order, Billing, Delivery and Shipment and User-exit enhance sap standard functionality.

Number range in SAP is used to across modules to automatically number documents as and when they are created. Number range contains one or more intervals, each one of them define range of number and stores current value of counter. Each range is assigned or used to number a specific type of document for example a Sales Order, Deliveries, Billing document and so on. When these documents are create SAP reads assigned number range object and interval to get current value of counter, which is then assigned to the new document, and then counter is increased by one. This way documents created are always in sequence, except when number range is buffered where gaps can occur. Refer SAP Help for more detail.

Number range objects are maintained using transaction SNRO. Intervals can be marked as 'external'. External number range intervals only contains interval, it does not maintain the current value. External number ranges are used to validate number. For example, if user chooses to enter Sales Order number, it will be then validated against an external number range. As users are free to enter any number within range there is no point in maintaining current value.

Number ranges intervals are assigned to documents type in SPRO. Two or more documents type can be assigned to same number range interval. Below are the settings in SPRO where number range intervals are assigned to Sales Order, Billing, Deliveries and Shipment.

Sales Order

Billing/Invoice

Delivery

Shipment

Month Input with Value Help

2011-06-24T15:22:00.001+05:30

Select-option for month input can be created using dictionary field S012-SPMON and the code to display a pretty value help is in sap standard include RMCS0F0M. Just include the program and call subroutine MONAT_F4.

REPORT  zpwtest7 .
 
INCLUDE rmcs0f0m .
 
TABLES  s012.
 
SELECT-OPTIONS s_months FOR s012-spmon.
 
AT SELECTION-SCREEN ON VALUE-REQUEST FOR s_months-low.
  PERFORM monat_f4.
 
AT SELECTION-SCREEN ON VALUE-REQUEST FOR s_months-high.
  PERFORM monat_f4.

Displaying SAP Icon in Documentation Text

2011-04-20T18:58:00.001+05:30

Recently I was creating program documentation and found problem with the way SAP has given option to insert SAP icon. This problem will be there in any kind of documentation i.e. while creating SE38 documentation, data element documentation, long text of message etc. While define documentation you would normally think, using option Insert->Character->SAP Icons (as in screen shot below) will do the job. But it seems that is not the case.

It inserts a decimal code, corresponding to selected icon in the text. But when you actually view this it looks anything but SAP Icon.

With some trial and error what I found was if you simply put hexadecimal code of SAP icon (which you can get from ICON type group from SE11) within @, e.g. to print OK icon use @01@ as shown in below screen shot.

And here is the output

Configure SAP Printer to send spool as PDF attachment

2011-02-28T18:25:00.002+05:30

This cool method will allow you to convert any SAP output in PDF format and send it as email attachment.

You must have used program RSTXPDFT4 earlier for similar purpose, however for normal user finding spool number and then executing program is too much. And I have seen users printing and scanning outputs to forward it to customer/vendor. This will simplify the whole process and provides an easy method to achieve the end result. Basically you define a printer in SAP with deriver type PDF and access method 'M'. And anything printed on this printer will be send as pdf attachment to email specified.

To define such printer follow below steps

1. Goto transaction SPAD (Spool Administrator) and Hit 'Display' button.

2. On next screen hit 'Create' button.

3. On 'Device Attributes' tab fill in 'Output device' and 'Short name'. Select device type 'PDF1 : PDF:ISO Latin-1 4.6D+'. Press F4 on Spool server and select relevant spool server from list.

4. On 'Access method' tab select 'M' as access method. Input 'Email address' and 'Only use This Mail Address' will appear. If you want all emails to be sent to one email address and would not allow user to change that email adderss then enter adddres and check the box. If left blank system will prompt user to enter email addrres before printing.

Auto Refresh ALV List - CL_GUI_TIMER

2010-12-23T21:04:00.001+05:30

Class CL_GUI_TIMER trigger event FINISHED at given intervals (in seconds). This event can be used to select the data, carry out processing and update the content internal table attached to ALV. Below sample code illustrate how to use this class to refresh ALV. To summarise the program logic in short, you need to define object of CL_GUI_ALV_GRID, a local class to handle event FINISHED, couple this event method defined in local class, specify time interval in seconds and kick start the timer.

Note that I have used SELECT.. APPENDING TABLE to show change in data after refresh. And I think it is good idea to inform user about last time report was refresh with MESSAGE statement.

REPORT  zpwtest8.
 
CLASS lcl_timer DEFINITION DEFERRED .
 
DATA : i_spfli TYPE TABLE OF spfli .
 
DATA : ob_grid    TYPE REF TO cl_gui_alv_grid ,
       ob_recev   TYPE REF TO lcl_timer       ,
       ob_timer   TYPE REF TO cl_gui_timer    .
 
*----------------------------------------------------------------------*
*       CLASS lcl_receiver DEFINITION
*----------------------------------------------------------------------*
CLASS lcl_timer DEFINITION.
  PUBLIC SECTION.
    METHODS:
      handle_finished FOR EVENT finished OF cl_gui_timer.
ENDCLASS.                    "lcl_receiver DEFINITION
 
*----------------------------------------------------------------------*
*       CLASS lcl_receiver IMPLEMENTATION
*----------------------------------------------------------------------*
CLASS lcl_timer IMPLEMENTATION.
  METHOD handle_finished.
    PERFORM refresh_data .
    MESSAGE s003(z001) WITH 'Report refreshed at' sy-uzeit.
    CALL METHOD ob_timer->run.
  ENDMETHOD.                    "handle_finished
ENDCLASS.                    "lcl_receiver IMPLEMENTATION
 
*--------------------------------------------------------------------*
*     Start of Selection
*--------------------------------------------------------------------*
START-OF-SELECTION .
  PERFORM select_data .
 
*--------------------------------------------------------------------*
*     End of Selection
*--------------------------------------------------------------------*
END-OF-SELECTION .
 
* Step 1 : Initialise Time control
  CREATE OBJECT ob_timer.
 
* Step 2 : Initialise object to receive event
  CREATE OBJECT ob_recev.
 
* Step 3 : Couple event to method
  SET HANDLER ob_recev->handle_finished FOR ob_timer. "
 
* Step 4 : Set Interval in seconds
  ob_timer->interval = 20 .
 
* Step 5 : Start Timer
  CALL METHOD ob_timer->run.
 
  PERFORM display_data .
 
*--------------------------------------------------------------------*
*&      Form  Select_Date
*--------------------------------------------------------------------*
FORM select_data .
  SELECT *
    APPENDING TABLE i_spfli
    FROM spfli .
ENDFORM.                    "SELECT_DATA
 
*&---------------------------------------------------------------------*
*&      Form  refresh_data
*&---------------------------------------------------------------------*
FORM refresh_data .
 
* Get grid reference
  IF ob_grid IS INITIAL .
    CALL FUNCTION 'GET_GLOBALS_FROM_SLVC_FULLSCR'
      IMPORTING
        e_grid = ob_grid.
  ENDIF.
 
  IF ob_grid IS NOT INITIAL. "Sanity Test
    PERFORM select_data .
    CALL METHOD ob_grid->refresh_table_display.
  ENDIF.
 
ENDFORM.                    "refresh_data
 
*&---------------------------------------------------------------------*
*&      Form  display_data
*&---------------------------------------------------------------------*
FORM display_data .
 
  CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY_LVC'
    EXPORTING
      i_structure_name = 'SPFLI'
    TABLES
      t_outtab         = i_spfli
    EXCEPTIONS
      program_error    = 1
      OTHERS           = 2.
 
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
 
ENDFORM .                    "display_data

VAT Code Change (UK)

2010-12-16T15:34:00.003+05:30

In UK VAT is changing from 17.5% to 20% effective from 4th Jan 2011, first working day of the Year. Following are the changes required in our SAP system. The steps are not exclusive for every SAP implementation but will give you an idea where to start from. To start with, existing VAT code were kept unchanged and new VAT code are created by copying them and changing the rates. Once these code are transported to production system you need to set condition and change VAT code in documents like scheduling agreement, purchase info records, purchase order, sales orders etc.

1. Copy existing VAT code into new codes, and change the rate using transaction FTXP. Note that system will not prompt for transport.

2. Adding VAT code in transport.

Create transport and add new tax codes in transport.
In transaction SE10 release the task and transport. Before releasing, make sure all tax codes are there in transport by expanding the task node of transport.

3. Import transport in target system.

Import transport in target system using STMS. Note that just by importing transport tax rate will not be imported in target system as tax rates are stores in conditional tables and which can be transported because of number assignment (KONH-KNUMH and KONP-KNUMH) which is sequential numbers

Next step will create condition records.
Again go to transaction FTXP and choose Transport->Import.

If Import option is disable then change setting in SCC4 to 'Change w/o automatic recording, no transport allowed'

In import option input transport number and country as GB. This executes transaction FTXP in BDC each tax code. You can check status in SM35.

4. In VK12 for condition MWST change the valid to date of existing VAT code until 3rd Jan 2011 and add a line for new VAT code starting from 4th Jan 2011. As the condition table works on Validity dates this cab be done earliest convenience to avoid problems during the New Year.

5. Use program RM06ENMW to mass update Purchasing Documents e.g. Purchase Order, Scheduling Agreement.

6. Use program RM06IMWS to mass update Purchase Info Record.

Best way is to schedule a background job to execute on 4th Jan early morning for RM06ENMW and RM06IMWS .

7. Open Sales orders with delivery date after 3rd Jan should repriced for new VAT code.

8. Ensure new VAT codes are entered for the determination of the tax code (configuration). Transaction OBCD - EDI: Conversion of External Tax Rate <-> Tax Code

Further reading:
Note 117983 - Change of tax on sales/purchases (w/o tax jur.code)
Note 96389 - Chng cntrl rcrd for MM-PUR: purchasing info record
Note 97144 - Change tax rate for MM-PUR: Purchasing documents

Uploading excel data into ABAP from presentation server

2010-07-17T22:06:00.001+05:30

You can upload text based file using method CL_GUI_FRONTEND_SERVICES=>GUI_UPLOAD or function module GUI_UPLOAD. This method or function module does not work with excel file. For excel files function module ALSM_EXCEL_TO_INTERNAL_TABLE can be used. This function module returns data in internal table with three columns ROW, COL and VALUE. Basically it returns data for each cell in excel file. With little bit of logic this data then can be populated in desired internal table.

Below sample code uploaded data from excel file using ALSM_EXCEL_TO_INTERNAL_TABLE.

REPORT  zpwtest5.

*&---------------------------------------------------------------------*
*&      Data Definition
*&---------------------------------------------------------------------*
TYPES : BEGIN OF ty_excel ,
          col0001 TYPE char50 ,
          col0002 TYPE char50 ,
          col0003 TYPE char50 ,
          col0004 TYPE char50 ,
          col0005 TYPE char50 ,
          col0006 TYPE char50 ,
          col0007 TYPE char50 ,
          col0008 TYPE char50 ,
          col0009 TYPE char50 ,
          col0010 TYPE char50 ,
          col0011 TYPE char50 ,
          col0012 TYPE char50 ,
          col0013 TYPE char50 ,
          col0014 TYPE char50 ,
          col0015 TYPE char50 ,
          col0016 TYPE char50 ,
          col0017 TYPE char50 ,
          col0018 TYPE char50 ,
          col0019 TYPE char50 ,
          col0020 TYPE char50 ,
        END OF ty_excel .

CONSTANTS : column  TYPE i VALUE 17 .

DATA      : i_excel TYPE TABLE OF ty_excel .

*&---------------------------------------------------------------------*
*&      Selection Screen
*&---------------------------------------------------------------------*
PARAMETERS : p_file TYPE char255  DEFAULT 'C:\' OBLIGATORY .

*&---------------------------------------------------------------------*
*&      AT SELECTION-SCREEN
*&---------------------------------------------------------------------*
AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_file .
  PERFORM browse_file .

AT SELECTION-SCREEN .
  PERFORM check_file_exist .

*&---------------------------------------------------------------------*
*&      Start of Selection
*&---------------------------------------------------------------------*
START-OF-SELECTION .
  PERFORM upload_data  .

*&---------------------------------------------------------------------*
*&      Form  browse_file
*&---------------------------------------------------------------------*
FORM browse_file .

  DATA : i_files TYPE filetable ,
         ls_file TYPE file_table,
         lv_subrc TYPE i        ,
         lv_user TYPE i         ,
         lv_def TYPE string .

  lv_def = p_file .

  CALL METHOD cl_gui_frontend_services=>file_open_dialog
    EXPORTING
      window_title            = 'Select file to upload'
      default_extension       = 'XLS'
      default_filename        = lv_def
      initial_directory       = 'C:\'
    CHANGING
      file_table              = i_files
      rc                      = lv_subrc
      user_action             = lv_user
    EXCEPTIONS
      file_open_dialog_failed = 1
      cntl_error              = 2
      error_no_gui            = 3
      not_supported_by_gui    = 4
      OTHERS                  = 5.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE 'S' NUMBER sy-msgno
               WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

  CHECK lv_user IS INITIAL .
  CHECK i_files IS NOT INITIAL .
  READ TABLE i_files INTO ls_file INDEX 1.
  p_file = ls_file-filename.

ENDFORM .                    "browse_file


*&---------------------------------------------------------------------*
*&      Form  check_file_exist
*&---------------------------------------------------------------------*

FORM check_file_exist .

  DATA : lv_file TYPE string ,
         lv_result TYPE abap_bool .

  lv_file = p_file .

  CALL METHOD cl_gui_frontend_services=>file_exist
    EXPORTING
      file                 = lv_file
    RECEIVING
      result               = lv_result
    EXCEPTIONS
      cntl_error           = 1
      error_no_gui         = 2
      wrong_parameter      = 3
      not_supported_by_gui = 4
      OTHERS               = 5.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
               WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

  IF lv_result = abap_false .
    MESSAGE e003(z001) WITH 'File' p_file 'does not exist' .
  ENDIF.

ENDFORM .                    "check_file_exist


*&---------------------------------------------------------------------*
*&      Form  upload_data
*&---------------------------------------------------------------------*

FORM upload_data  .

  DATA : i_raw   TYPE TABLE OF alsmex_tabline,
         lv_file TYPE rlgrap-filename        ,
         lv_name TYPE string                 ,
         ls_raw  TYPE alsmex_tabline         ,
         ls_excel TYPE ty_excel .

  FIELD-SYMBOLS :  TYPE ANY .

  DATA : begin_col TYPE  i VALUE 1  ,
         begin_row TYPE  i VALUE 1  ,
         end_col   TYPE  i VALUE column ,
         end_row   TYPE  i VALUE 200 .

  CALL FUNCTION 'SAPGUI_PROGRESS_INDICATOR'
    EXPORTING
      text = 'Uploading Excel File ...'.

  lv_file = p_file .

  CALL FUNCTION 'ALSM_EXCEL_TO_INTERNAL_TABLE'
    EXPORTING
      filename                = lv_file
      i_begin_col             = begin_col
      i_begin_row             = begin_row
      i_end_col               = end_col
      i_end_row               = end_row
    TABLES
      intern                  = i_raw
    EXCEPTIONS
      inconsistent_parameters = 1
      upload_ole              = 2
      OTHERS                  = 3.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE 'I'      NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    LEAVE LIST-PROCESSING .
  ENDIF.

  CALL FUNCTION 'SAPGUI_PROGRESS_INDICATOR'
    EXPORTING
      text = 'Extracting data from Excel File ...'.

  SORT i_raw BY row col.

  LOOP AT i_raw INTO ls_raw .
    AT NEW row .
      CLEAR ls_excel .
    ENDAT.

*   Check column is not more than constant 'COLUMN'
    CHECK ls_raw-col <= column  .

*   Prepare the name of field
    CLEAR lv_name .
    CONCATENATE 'COL' ls_raw-col INTO lv_name .
    ASSIGN COMPONENT lv_name OF STRUCTURE ls_excel TO .
    IF sy-subrc = 0 .
       = ls_raw-value .
    ENDIF.

*   Assign to field

    AT END OF row.
      APPEND ls_excel TO i_excel .
    ENDAT .
  ENDLOOP.

ENDFORM.                    "upload_data

I tried below excel file to uploaded with this program.

This is content of I_RAW table, which is returned by function module ALSM_EXCEL_TO_INTERNAL_TABLE.

And this is content if I_EXCEL after some processing on I_RAW. Notice that column header are also extracted which you need to discard if you logic doesn’t need them.

Config to copy Sales order header text to Invoice Item text

2010-06-21T18:50:00.001+05:30

In the previous blog Defining new TEXT ID for Sales Order - Sales Order Header Text I have shown how to create Text Type for Sales Order Header. My requirement was to capture a piece of information in Sales Order, transfer it to Invoice and then transmit that with outbound EDI message. I am using Sales order header text to store that information, to transfer that information to Invoice I am going to activate same TEXT ID in Invoice and then define config which will copy the text from Sales Order to Invoice text.

Step 1: Create/Activate Text ID in Invoice Item.
Select 'Item' radio button next to 'Billing Doc' and hit 'Change' button

Step 2: Add TEXT ID to Text procedure (see blog Defining new TEXT ID for Sales Order - Sales Order Header Text for more detail)

Step 3: Define new Access Sequence.
Double click on Access sequences node and add a new Access sequence in the table displayed on right.

Step 4: Specify source Text ID.
Now select the access sequence and double click on Access sequence for Text ID’s. In the table insert a row for TEXT ID from which content will be copied. In this case it will be VBBK( Sales Order header Text).

Updating Delivery Date in Delivery(VL02N) using Function Module

2010-06-20T23:25:00.001+05:30

DATA : ls_vbkok TYPE vbkok      ,
       lv_vbeln TYPE likp-vbeln .

START-OF-SELECTION .

  ls_vbkok-lfdat    = '20100626' .
  ls_vbkok-lfuhr    = '110000'   .
  ls_vbkok-kzlfd    = 'X' .
  lv_vbeln          = '0088800562' .

  CALL FUNCTION 'WS_DELIVERY_UPDATE_2'
    EXPORTING
      vbkok_wa = ls_vbkok
      delivery = lv_vbeln
      commit   = 'X'.

ALV Grid OO - Tips

2010-06-17T20:06:00.004+05:30

Refreshing ALV Grid

Refreshing ALV grid in OO ABAP using method REFRESH_TABLE_DISPLAY does not refresh the layout settings of grid to frontend, for example if you are refreshing the content of alv grid then column does not automatically optimise their width according to new content. To avoid this right way to refresh grid is to first call SET_FRONTEND_LAYOUT then REFRESH_TABLE_DISPLAY .

CALL METHOD ob_grid->set_frontend_layout
  EXPORTING
    is_layout = gs_layout.
 
CALL METHOD ob_grid->refresh_table_display.

GS_LAYOUT is the same layout structure which was used with method SET_TABLE_FOR_FIRST_DISPLAY .

Hiding ALV Grid toolbar button.

Buttons in the ALV toolbar can be hidden by specifying parameter IT_TOOLBAR_EXCLUDING in method SET_TABLE_FOR_FIRST_DISPLAY. Every button is defined by a constant in class CL_GUI_ALV_GRID. Below are some example

MC_FC_FIND - Find
MC_FC_LOC_DELETE_ROW - Local: Delete Row
MC_FC_LOC_INSERT_ROW - Local: Insert Row
MC_FC_PRINT - Print
MC_FC_SAVE_VARIANT - Save Variant
MC_FC_SELECT_ALL - Select All Rows
MC_FC_SORT_ASC - Sort in Ascending Order
MC_FC_SORT_DSC - Sort in Descending Order
MC_FC_SUBTOT - Subtotals

Passing these constant values in internal table to parameter IT_TOOLBAR_EXCLUDING will hide them from screen.

DATA : li_exclude TYPE ui_functions,
       ls_exclude TYPE ui_func     .
  
ls_exclude = cl_gui_alv_grid=>mc_fc_sort_asc.
APPEND ls_exclude TO li_exclude.
 
ls_exclude = cl_gui_alv_grid=>mc_fc_sort_dsc.
APPEND ls_exclude TO li_exclude.
 
CALL METHOD ob_grid->set_table_for_first_display
  EXPORTING
    is_variant           = gs_variant
    i_save               = 'A'
    is_layout            = gs_layout
    it_toolbar_excluding = li_exclude
  CHANGING
    it_outtab            = i_rep
    it_fieldcatalog      = i_fld.

Refresh Field Catelog buffer

ALV function modules which format fields on ALV based on tablename and fieldname stores the setting in buffer for performance reason. For example, if you are referring to MARA-MATNR then ALV program will read column heading of data element MATNR from buffer. If you have modified the label in data dictionary it will not be refreshed immediately. To reset this buffer and see your changes immediately you need to clear buffer using program BALVBUFDEL.

Defining new TEXT ID for Sales Order - Sales Order Header Text

2010-06-17T12:09:00.002+05:30

Lately, I got requirement to hold a piece of data coming with customer order and pass it on the same piece of info to customer with corresponding Invoice. I identified TEXT ID to be best place to hold this information as it would not require any ABAP changes as long as data is filled in the right segment from EDI subsystem. Additionally text determination can be configured to transfer the TEXT ID from Sales Order to Invoice and then it will automatically create Invoice IDoc with required value in TEXT ID.

As the existing TEXT IDs were already in use for other purposes it would be wise to create a new TEXT ID for Sales order and Invoice for this purpose.

Below procedure can be used to add new TEXT ID in all Sales document .i.e. Customer, Info rec, Sales order, Delivery etc.

Step 1: Define TEXT ID

Follow path Sales and Distribution->Basic Functions->Text Control->Define Text Types

Add new TEXT ID and description, and Save data.

Step 2 : Find correct ‘Text determination procedure’

TEXT IDs are grouped under ‘Text determination procedure’ and ‘Text determination procedure’ is assigned to sales document type. You need to find first what ‘Text determination procedure’ is used by your sales document type. To find out double click on ‘Text procedure assignment’ and note the ‘Text determination procedure’ assigned to Order type OR (assuming you are using this order type).

Step 3: Add TEXT ID to ‘Textprocedure’
Now double click on ‘Textprocedure’, highlight line ‘01’ then double click on ‘Text ID’s in textprocedure.

Add new TEXT ID here on the table.

That’s it, if you now create sales order of type OR you will find new text ‘GLN Number’ in header text tab.

Next Blog : Config to copy Sales order header text to Invoice Item text.

Some Dynamic Stuff with ABAP

2010-02-20T21:03:00.005+05:30

Getting the component of work area at runtime. Below code snippet will loop though all the component of work area wa_data .

TYPES : BEGIN OF ty_data        ,
         matnr  TYPE mara-matnr ,
         werks  TYPE marc-werks ,
         num    TYPE i          ,
       END OF ty_data .
 
DATA          : ob_type TYPE REF TO cl_abap_structdescr .
FIELD-SYMBOLS : <comp>  TYPE abap_compdescr.
 
DATA : ws_data TYPE ty_data .
 
START-OF-SELECTION .
 
  ob_type ?= cl_abap_typedescr=>describe_by_data( ws_data ).
  LOOP AT ob_type->components ASSIGNING <comp>.
    WRITE : / <comp>-name .
  ENDLOOP.

Creating data where type will be known at runtime.

DATA: ty_type TYPE REF TO data .
  FIELD-SYMBOLS <fs_data> TYPE ANY .
 
  CREATE DATA: ty_type TYPE (‘MARA’) .
  ASSIGN: ty_type->* TO <fs_data> .

Using above two concept to select data from table, table name will be given on selection screen.

PARAMETERS : p_table TYPE char20 .
 
START-OF-SELECTION .
  PERFORM get_data USING p_table .
 
*&---------------------------------------------------------------------*
*&      Form  GET_DATA
*&---------------------------------------------------------------------*
FORM get_data USING iv_type TYPE char20 .
 
  DATA: ty_type TYPE REF TO data .
  FIELD-SYMBOLS <fs_data> TYPE ANY .
 
  CREATE DATA: ty_type TYPE (iv_type) .
  ASSIGN: ty_type->* TO <fs_data> .
 
  SELECT *
    INTO <fs_data> UP TO 1 ROWS
    FROM (iv_type) .
  ENDSELECT .
 
  DATA          : ob_type TYPE REF TO cl_abap_structdescr .
  FIELD-SYMBOLS : <comp>  TYPE abap_compdescr ,
                  <field> TYPE ANY            .
 
  IF sy-subrc = 0 .
    ob_type ?= cl_abap_typedescr=>describe_by_data( <fs_data> ).
    LOOP AT ob_type->components ASSIGNING <comp>.
      ASSIGN COMPONENT <comp>-name OF STRUCTURE <fs_data> TO <field> .
      IF sy-subrc = 0 .
        WRITE : / <comp>-name , <field> .
      ENDIF.
    ENDLOOP.
  ENDIF.
 
ENDFORM .                    "GET_DATA

Regular Expression in SAP ABAP

2010-02-11T18:39:00.001+05:30

A regular expression is a special text string which describes a pattern to search for. In most simple form single character string, for example ‘a’ is actually a regular expression. On the other hand in complex form it is used by compilers to parse a piece of code to identify any syntax error. ABAP statements FIND and REPLACE support the use of regular expression with additional clause REGEX for example:

FIND REGEX 'a' IN 'ancient' .

With the obvious use in FIND and REPLACE command, regular expressions are also used to validate the format of data and conversion of data from one format to other. Typical example would be to check the format of email address, putting thousand separator in number, conversion of date from one format to other.

Few characters have special meaning if used in regular expression, these characters are called as ‘meta characters’

1. Opening and closing Square bracket [ ]
2. Backslash \
3. Caret ^
4. Dollar sign $
5. Dot .
6. Pipe symbol |
7. Question Mark ?
8. Star *
9. Plus sign +
10. Opening and closing bracket ( )

You can find further information on each of above meta character in http://www.regular-expressions.info/tutorialcnt.html . DEMO_REGEX_TOY is very helpful program to test and build your regular expression which you can later use with FIND/REPLACE command. Below is screen shot which demonstrate the use of DEMO_REGEX_TOY program to check regex \b(\w+)\s*\1\b which look for repeated words in a string.

Copy ALV Layout Between Report

2010-01-21T20:43:00.000+05:30

This little program can be used to copy ALV report layout from one report to another. Obviously, the layout to work on target report, it should have same column name .i.e. the internal table (used in ALV) field name should be identical. I must confess, program is not perfect and might needs some fix.

REPORT zalvcopy  .
 
TYPES : r_report  TYPE RANGE OF ltdx-report  ,
        r_user    TYPE RANGE OF ltdx-username,
        r_variant TYPE RANGE OF ltdx-variant ,
 
        tr_report  TYPE LINE OF r_report ,
        tr_user    TYPE LINE OF r_user   ,
        tr_variant TYPE LINE OF r_variant.
 
DATA : i_report  TYPE r_report ,
       i_user    TYPE r_user   ,
       i_variant TYPE r_variant,
       s_report  TYPE tr_report ,
       s_user    TYPE tr_user   ,
       s_variant TYPE tr_variant,
 
       i_result  TYPE TABLE OF ltvariant ,
       s_result  TYPE ltvariant          .
 
DATA : s_varkey TYPE ltdxkey ,
       i_dbfieldcat TYPE TABLE OF ltdxdata ,
       i_dbsortinfo TYPE TABLE OF ltdxdata ,
       i_dbfilter   TYPE TABLE OF ltdxdata ,
       i_dblayout   TYPE TABLE OF ltdxdata .
 
DEFINE insert_row .
  &1-sign   = 'I'.
  &1-option = 'EQ' .
  &1-low    = &2 .
  &1-high   = &3 .
END-OF-DEFINITION.
 
PARAMETERS : p_fr_pg TYPE ltdx-report   OBLIGATORY , "From Program Name
             p_fr_vr TYPE ltdx-variant  OBLIGATORY , "Variant Name

             p_fr_to TYPE ltdx-report              . "To Program Name
 
START-OF-SELECTION .
 
  insert_row s_report p_fr_pg space .
  APPEND s_report TO i_report .
 
  insert_row s_variant p_fr_vr space .
  APPEND s_variant TO i_variant .
 
  CALL FUNCTION 'LT_VARIANTS_READ_FROM_LTDX'
    TABLES
      et_variants   = i_result
      it_ra_report  = i_report
      it_ra_variant = i_variant
    EXCEPTIONS
      not_found     = 1
      OTHERS        = 2.
 
  IF sy-subrc <> 0.
 
  ENDIF.
 
  READ TABLE i_result INTO s_result INDEX 1 .
 
  MOVE-CORRESPONDING s_result TO s_varkey .
 
  CALL FUNCTION 'LT_DBDATA_READ_FROM_LTDX'
    EXPORTING
      is_varkey    = s_varkey
    TABLES
      t_dbfieldcat = i_dbfieldcat
      t_dbsortinfo = i_dbsortinfo
      t_dbfilter   = i_dbfilter
      t_dblayout   = i_dblayout
    EXCEPTIONS
      not_found    = 1
      wrong_relid  = 2
      OTHERS       = 3.
 
  IF sy-subrc <> 0.
 
  ENDIF.
 
  DATA : s_varkey1     TYPE ltdxkey    ,
         s_disvariant  TYPE disvariant .
 
  MOVE-CORRESPONDING s_varkey TO s_varkey1 .
  s_varkey1-report = p_fr_to .
 
  MOVE-CORRESPONDING s_varkey1 TO s_disvariant .
  s_disvariant-text = s_result-text .
 
  CALL FUNCTION 'LT_DBDATA_WRITE_TO_LTDX'
    EXPORTING
      is_varkey    = s_varkey1
      is_variant   = s_disvariant
    TABLES
      t_dbfieldcat = i_dbfieldcat
      t_dbsortinfo = i_dbsortinfo
      t_dbfilter   = i_dbfilter
      t_dblayout   = i_dblayout
    EXCEPTIONS
      not_found    = 1
      wrong_relid  = 2
      OTHERS       = 3.
 
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

Soundex Function Module for ABAP

2010-01-10T17:40:00.006+05:30

Spelling of a word in English language can vary depending on number of factor, most common being spelling mistakes. Soundex algorithm can be effectively used to compare two strings irrespective of any spelling mistake. Although Soundex algorithm doesn't guarantee correct result but it is considered as effictive way of eliminating spelling mistakes while searching. Both SQL server and Oracle has built in function for this.

Soundex function returns four-character aplha numeric code which represent phonetic representation of word. For example word 'Education' and 'Edukation' will have same code .i.e. E323. There are different versions of Soundex algorithm which are derived by making few enhancement and change to original version. This function module supports three version

0: Enhanced SoundEx:

1: Normal Census : Properly calculated SoundEx codes found in all census years.

2: Special Census : Improperly calculated SoundEx codes found in SOME of the censuses performed in 1880, 1900, and 1910.

You can specify this option in parameter CENSUSOPTION of function module, by default it takes option 0.

The function module code is based on information given on page Understanding Classic SoundEx Algorithms

FUNCTION zsoundex.
*"----------------------------------------------------------------------
*"*"Local Interface:
*"  IMPORTING
*"     REFERENCE(WORDSTRING) TYPE  STRING
*"     VALUE(LENGTHOPTION) TYPE  I DEFAULT 4
*"     VALUE(CENSUSOPTION) TYPE  I OPTIONAL
*"  EXPORTING
*"     REFERENCE(SOUNDEX_CODE) TYPE  STRING
*"----------------------------------------------------------------------
 
* Adapted from info available at
* http://www.creativyst.com/Doc/Articles/SoundEx1/SoundEx1.htm
 
  DATA : lv_input   TYPE string     ,
         lv_option  TYPE i          ,
         lv_soundex TYPE char10     ,
         lv_length  TYPE i          ,
         lv_codelen TYPE i          ,
         lv_tmp     TYPE string     .
 
* Option = 0
*   Enhanced SoundEx
* Option = 1 - Normal Census
*   Properly calculated SoundEx codes found in all census years.
* Option = 2
*   Special Census - Improperly calculated SoundEx codes found
*   in SOME of the censuses performed in 1880, 1900, and 1910.
* Other values will be treated as 0
 
  lv_option = censusoption .
 
  IF lv_option = 0 OR
     lv_option = 1 OR
     lv_option = 2 .
  ELSE.
    lv_option = 0 .
  ENDIF.
 
* Set length based on Option and length specified
  IF lv_option > 0 .
    lv_codelen  = 4 .
  ENDIF.
  IF lengthoption > 0  .
    lv_codelen = lengthoption .
  ENDIF .
  IF lv_codelen > 10 .
    lv_codelen = 10 .
  ENDIF .
  IF lv_codelen < 4 .
    lv_codelen = 4 .
  ENDIF .
 
* Step 1
* Capitalize all letters in the word and drop all punctuation marks.
* Pad the word with rightmost blanks as needed during each procedure step.
 
  lv_input = wordstring .
 
  REPLACE ALL OCCURRENCES OF REGEX '[^A-Z]' IN lv_input WITH space IGNORING CASE.
 
  CONDENSE  lv_input NO-GAPS  .
  TRANSLATE lv_input TO UPPER CASE.
 
  CHECK lv_input IS NOT INITIAL .
 
  IF lv_option = 0 .
*   DG with G
    REPLACE ALL OCCURRENCES OF 'DG' IN lv_input WITH 'G' .
 
*   GH with H
    REPLACE ALL OCCURRENCES OF 'GH' IN lv_input WITH 'H' .
 
*   GN with N (not 'ng')
    REPLACE ALL OCCURRENCES OF 'GN' IN lv_input WITH 'N' .
 
*   KN with N
    REPLACE ALL OCCURRENCES OF 'KN' IN lv_input WITH 'N' .
 
*   PH with F
    REPLACE ALL OCCURRENCES OF 'PH' IN lv_input WITH 'F' .
 
*   MP with M ...WHEN... it is followed by S, Z, or T
    REPLACE ALL OCCURRENCES OF 'MPS' IN lv_input WITH 'MS' .
    REPLACE ALL OCCURRENCES OF 'MPZ' IN lv_input WITH 'MZ' .
    REPLACE ALL OCCURRENCES OF 'MPT' IN lv_input WITH 'MT' .
 
*   PS with S ...WHEN... it starts a word
    REPLACE ALL OCCURRENCES OF REGEX '^PS' IN lv_input WITH 'S' .
 
*   PF with F ...WHEN... it starts a word
    REPLACE ALL OCCURRENCES OF REGEX '^PF' IN lv_input WITH 'F' .
 
*   MB with M
    REPLACE ALL OCCURRENCES OF 'MB' IN lv_input WITH 'M' .
 <>
*   TCH with CH
    REPLACE ALL OCCURRENCES OF 'TCH' IN lv_input WITH 'CH' .
 
*   A or I with E WHEN - starts word+followed by[AEIO]
    REPLACE ALL OCCURRENCES OF REGEX '^A[AEIO]' IN lv_input WITH 'E' .
  ENDIF.
 
* Step 2
* Retain the first letter of the word.
  lv_soundex = lv_input+0(1) .
 
  IF lv_input+0(1) = 'H' OR lv_input+0(1) = 'W' .
    CONCATENATE '-' lv_input+1 INTO lv_input .
  ENDIF.
 
  IF lv_option = 1 .
    REPLACE ALL OCCURRENCES OF 'H' IN lv_input WITH space .
    REPLACE ALL OCCURRENCES OF 'W' IN lv_input WITH space .
    CONDENSE lv_input NO-GAPS .
  ENDIF.
 
* Step 3
* Change all occurrence of the following letters to '0' (zero):
* 'A', E', 'I', 'O', 'U', 'H', 'W', 'Y'.
  REPLACE ALL OCCURRENCES OF REGEX '[AEIOUHWY]' IN lv_input WITH '0' .
 
* Step 4
* Change letters from the following sets into the digit given:
* 1 = 'B', 'F', 'P', 'V'
* 2 = 'C', 'G', 'J', 'K', 'Q', 'S', 'X', 'Z'
* 3 = 'D','T'
* 4 = 'L'
* 5 = 'M','N'
* 6 = 'R' 
 
  REPLACE ALL OCCURRENCES OF REGEX '[BFPV]'     IN lv_input WITH '1' .
  REPLACE ALL OCCURRENCES OF REGEX '[CGJKQSXZ]' IN lv_input WITH '2' .
  REPLACE ALL OCCURRENCES OF REGEX '[DT]'       IN lv_input WITH '3' .
  REPLACE ALL OCCURRENCES OF REGEX '[L]'        IN lv_input WITH '4' .
  REPLACE ALL OCCURRENCES OF REGEX '[MN]'       IN lv_input WITH '5' .
  REPLACE ALL OCCURRENCES OF REGEX '[R]'        IN lv_input WITH '6' .
 
* Step 5
* Remove all pairs of digits which occur beside each other
* from the string that resulted after step (4). 
  lv_length = STRLEN( lv_input ) .
 
  DATA : lv_last  TYPE char01     ,
         lv_index TYPE syst-index .
 
  DO lv_length TIMES .
    IF sy-index = 1 .
      lv_tmp  = lv_input+0(1) .
      lv_last = lv_input+0(1) .
    ELSE.
      lv_index = sy-index - 1 .
      IF lv_last <> lv_input+lv_index(1) .
        lv_last = lv_input+lv_index(1) .
        CONCATENATE lv_tmp lv_last INTO lv_tmp .
      ENDIF.
    ENDIF.
  ENDDO.
 
  lv_input = lv_tmp+1 .
 
* Remove all zeros from the string that results from step 5.0 (placed there in step 3) 
  REPLACE ALL OCCURRENCES OF '0' IN lv_input WITH space .
  CONDENSE lv_input .
 
*  Pad the string that resulted from step (6) with trailing zeros
*  and return only the first four positions, which will be of the
*  form    . 
  lv_soundex+1 = lv_input .
 
  IF lv_soundex+1(1) = space .
    lv_soundex+1(1) = 0 .
  ENDIF.
 
  IF lv_soundex+2(1) = space .
    lv_soundex+2(1) = 0 .
  ENDIF.
 
  IF lv_soundex+3(1) = space .
    lv_soundex+3(1) = 0 .
  ENDIF.
 
  soundex_code = lv_soundex+0(lv_codelen) .
 
ENDFUNCTION.

Defining Range Type in ABAP

2009-12-22T03:31:00.003+05:30

Range is internal table of structure which has four component in it namely SIGN, OPTION, LOW and HIGH. The data type of LOW and HIGH is specified while creating the range.

For example, if you want to define a range of type MARA-MATNR then statement would be.

DATA :  r_matnr TYPE RANGE OF mara-matnr .

To insert data in range table you will need compatible work area which can be defined using TYPE LINE OF clause.

DATA : ty_matnr TYPE LINE OF r_matnr.

You can use range to specify complex criteria in many statements in ABAP .i.e. IF, LOOP, CHECK, SELECT etc.

Range type can be defined centrally in data dictionary which can be very useful in case of passing values between program and function module or smartform.

Step 1 : Go to transaction SE11 and enter name of range in Data type input and hit create.

Step 2 : Select ‘Table Type’

Step 3 : Enter short text and select menu Edit->Define as range table type.

Step 4: Specify ‘Data Element’ as MATNR and enter name in ‘Structured Row Type’ then Save. After saving hit ‘Create’ button.

Step 5: Work are will be created automatically with data element MATNR. Enter short text, save and activate.

MD04 - Display Stock/Requirements Situation

2009-12-18T01:07:00.002+05:30

MD04 transaction gives a live information about current material stock in plant and how various MRP element will affect the stock in future. It will show outbound deliveries, sales orders, inbound deliveries, purchase orders, purchase requisitions and forecasts with there respective quantity and date and how much stock will remain in plant after that transaction.

User exit available
EXIT_SAPLM61R_001
EXIT_SAPMM61R_001

BADIs
MD_ADD_COL_EZPS
MD_ADD_COL_OVERVIEW
MD_DISPLAY_ELEMENT

FM to get the data displayed in MD04
MD_STOCK_REQUIREMENTS_LIST_API

Add column to MD04 transaction

User exit available allows to add up to three columns in transaction MD04. To add column to MD04 screen you need to put code in both EXIT_SAPLM61R_001 and EXIT_SAPMM61R_001 exits. Code in exit EXIT_SAPLM61R_001 determines the column header text of new column(s) and exit EXIT_SAPMM61R_001 contains code to derive value which will be displayed in column.

You can find the sample code for each user exit in include LXM61F04 and LXM61F03. For more information on this see documentation of Enhancement M61X0002 in transaction SMOD.

These two user exits are now replaced by BADI MD_ADD_COL_EZPS. For backward compatibility, SAP still allows users to use exits to add column in MD04. However if you implement BADI BADI MD_ADD_COL_EZPS then call to user exits will be skipped. See the code below from program SAPLM61R.

* Call the user-exit if the BADI (that replaces the exit) is not active
  PERFORM badi_get_business_add_in USING    'MD_ADD_COL_EZPS'
                                   CHANGING lo_badi.
  IF lo_badi IS INITIAL.
    CALL CUSTOMER-FUNCTION '001'
        EXPORTING imdkp = mdkp
                  imt61d = mt61d
        IMPORTING button1_ez   = usex1-text "text  Button1  Einzelzeil.
                  button2_ez   = usex2-text "text  Button2  Einzelzeil.
                  button3_ez   = usex3-text "text  Button3  Einzelzeil.
                  button1_ps   = usex1_ps"text  Button1  Periodensum
                  button2_ps   = usex2_ps"text  Button2  Periodensum.
                  button3_ps   = usex3_ps.  "text  Button3  Periodensum.
  ENDIF.

BADI MD_ADD_COL_EZPS has methods ACTIVATE_ADD_COLUMNS and FILL_ADD_COLUMNS and like exists you use one method to activate and put column heading to columns and other to fill the value in columns. Again, you can find the sample code for these methods in class CL_EXM_IM_MD_ADD_COL_EZPS in SE24, just double click on the method and you will see the code. BADI MD_ADD_COL_EZPS is not multi use BADI, which means you can only have one implementation of BADI, which make sense. You can get additional information about BADI MD_ADD_COL_EZPS from transaction SE18.

Basis Bits

2009-12-11T03:14:00.001+05:30

Below are few Basis transactions which are nice to know for ABAP developer. Being an ABAP developer you might have authorisation to execute these transactions in DEV or TEST system and knowing their capability might help you out solving problems, specially related to performance and authorisation. Below information is from a developers point of view and definitely not meant for Basis consultants.

SU01

This is user maintenance transaction. Broadly, you can use this transaction to create, change, delete, lock and unlock users. This is the transaction where you can reset the user password. You can see and change all the information which user can access using transaction SU3 namely their default printer, currency and number formats and parameters id assigned to them. Roles tab will give you information about the roles user has in system.

Almost all the changes which can be done using SU01 can also be performed using SU10 on many number of users at once, for example putting a parameter id in user profile.

USR01 – User master record, will give you printer info, different formats for given user(s)
USR02 – Logon data, will give you creation date, last logon, user locked etc.
PFCG

It is Role maintenance transaction. Every user have role assigned to them in SU01, these roles are defined here. Role is collection of transaction and/or authority object which when assigned to user allow users to access them. For example consider role SAP_LO_SD_SALES_DISPLAY, as you can see in below screen shot this role has a list of transaction in it. Which means, users having this role can access these transaction.

Having access to these transaction does not mean that user can access any data and perform any activity in these transaction. Further restrictions on data e.g. Company code, Sales Org etc is controlled using authority objects and their corresponding values and all these are defined on second tab ‘Authorization’. All the authority objects in a role is clubbed together and store in object called as ‘Profile’. When you add Role to user in SU01, corresponding profile is automatically added to it.

On the third tab ‘User’ you can see user name who has this Role assigned to them.
You can find more information on Role Maintenance in http://help.sap.com/saphelp_nw04/helpdata/EN/52/6714a9439b11d1896f0000e8322d00/frameset.htm

Below are few important tables which can give you data being displayed in PFCG

AGR_DEFINE – Data about role e.g. created by, created on etc.
AGR_USERS – To find role assigned to user
AGR_TCODES – To find transaction assigned to Role

ST01

System trace, most of the option available in ST01 is also available in ST05, However the option which I use more frequently in ST01 is Authorisation Trace. Once activated it will logs all the authority checks performed in system using AUTHORITY-CHECK statement and their result. While most of the authorisation problems can be solve using SU53, there are times when SU53 information is not enough and you need all the authorisation checks executed.

You can use General filters to specify filter in logging process e.g. logging trace for particular user or transaction.

Date formatting/processing in SAP

2009-09-27T16:34:00.000+05:30

Format of the date depends on various factors, to give you example it can depend on the country, type of business and even on personal choice. Internally SAP stores the date in YYYYMMDD format in char length 8 type field. Storing the date in this format makes it format independent, take less space to store and easy to sort and easy to compare. Although date is stored in ‘YYYYMMDD’ format but it is never displayed to user as it is (unless intended). While displaying the date to user SAP always takes care of date format active for user. Statements WRITE automatically display date field based on user date format. This statement is particularly important if you are using a date in BDC. Always remember to format date using WRITE statement before pass date to screen in BDC mode. A user can change the date format for his/her profile using transaction SU3. Centrally it can change by administrators using SU01/SU10.

Basic addition and subtracts in days work perfectly fine on date type field in SAP. It takes care of number of days in month and leap year. For example, adding 5 to 29-dec-2009 will return 03-Jan-2010. And subtracting 1-Mar-2009 and 27-Feb-2009 will result in 2. Remember you can always determine the year month and day of a date variable by extracting the correct characters. So if V_DATE is your date variant in SAP then

Year = V_DATE(4).
Month = V_DATE+4(2).
Day = V_DATE+6(2).

It worth noting that table T247 stores the short and Long description of month or you can use function module MONTH_NAMES_GET for the same.

Related Blogs.

First Day and Last Day of Month
Simple Date Formatting
FM ADD_TIME_TO_DATE

First and Last Day of the Month

2009-09-27T16:32:00.001+05:30

Getting first day of the month is easy as first day of month is always 01, so you can replace the day (DD) part of the date field with 01 and you are done. However getting the last day of month is but tricky as last can 28, 30 or 31 depending on what month and leap year. Easier way to find the last day of month is subtract 1 from 1 days of next month.

REPORT zpwtest .
 
DATA : v_date  TYPE syst-datum ,
v_first TYPE syst-datum ,
v_last  TYPE syst-datum .
 
v_date = sy-datum .
 
*First day of month will be
CONCATENATE v_date(4) v_date+4(2) '01' INTO v_first .
WRITE : / 'First day of month : ' , v_first .
 

*And to find last day, first get a date in next month
IF v_date+6(2) > 15 .
v_date = v_date + 20 .
ELSE.
v_date = v_date + 30 .
ENDIF.

*Then get first day of next month
CONCATENATE v_date(4) v_date+4(2) '01' INTO v_last .

*Subtract one day will be last day of previous month
v_last = v_last - 1 .
WRITE : / 'Last day of month : ' , v_last .

Simple formatting of date

2009-09-27T16:28:00.000+05:30

Function module FORMAT_DATE_4_OUTPUT is handy in case you need simple formatting on date. Formatting which involves change in position day, month and year, changing the separator to can be achieved with this function module. Below is sample code.


REPORT  zpwdate.
 
DATA : v_date TYPE syst-datum ,
       lv_foramt TYPE char10  .
 
START-OF-SELECTION .
 
  PERFORM format_date USING 'DD.MM.YYYY' .
  PERFORM format_date USING 'DD/MM/YYYY' .
  PERFORM format_date USING 'DD/MM/YY' .
  PERFORM format_date USING 'YY-MM-DD' .
  PERFORM format_date USING 'MM*DD*YYYY' .
  PERFORM format_date USING 'YY,MM,DD' .
 
*&---------------------------------------------------------------------*
*&      Form  format_date
*&---------------------------------------------------------------------*
FORM format_date USING iv_format TYPE rn1datum-format.
 
  DATA : lv_date TYPE rn1datum-datex .
 
  CALL FUNCTION 'FORMAT_DATE_4_OUTPUT'
    EXPORTING
      datin  = sy-datum
      format = iv_format
    IMPORTING
      datex  = lv_date.
 
  WRITE : / sy-datum , ' Format : ' , iv_format , lv_date .
 
ENDFORM.                    "format_date

Here is the output


23.09.2009  Format :  DD.MM.YYYY 23.09.2009
23.09.2009  Format :  DD/MM/YYYY 23/09/2009
23.09.2009  Format :  DD/MM/YY   23/09/09
23.09.2009  Format :  YY-MM-DD   09-09-23
23.09.2009  Format :  MM*DD*YYYY 09*23*2009
23.09.2009  Format :  YY,MM,DD   09,09,23

Sending Smartform in SAP Inbox or external Mail

2009-09-20T03:46:00.000+05:30


REPORT zpwtest .
 
DATA : lv_fname TYPE rs38l_fnam ,
      lv_mail_recipient TYPE swotobjid ,
      lv_mail_sender    TYPE swotobjid ,
      lv_control        TYPE ssfctrlop ,
      lv_name           TYPE so_name   ,
      lv_output         TYPE ssfcompop .
 
START-OF-SELECTION .
 
* Get fucntion module name of Smartform
 CALL FUNCTION 'SSF_FUNCTION_MODULE_NAME'
   EXPORTING
     formname = 'ZPWTEST'
   IMPORTING
     fm_name  = lv_fname.
 
* Create recepient object
*Check the User Type to send email to external address use
U - Internet address

 lv_name = sy-uname .
 CALL FUNCTION 'CREATE_RECIPIENT_OBJ_PPF'
   EXPORTING
     ip_mailaddr       = lv_name "Recipient SAP user Name
     ip_type_id        = 'B'     "SAP User Type
   IMPORTING
     ep_recipient_id   = lv_mail_recipient
   EXCEPTIONS
     invalid_recipient = 1
     OTHERS            = 2.
 
 IF sy-subrc <> 0.
 
 ENDIF.
 
* Create Sender Object
 CALL FUNCTION 'CREATE_SENDER_OBJECT_PPF'
   IMPORTING
     ep_sender_id   = lv_mail_sender
   EXCEPTIONS
     invalid_sender = 1
     OTHERS         = 2.
 
 IF sy-subrc <> 0.
 
 ENDIF.
 
* Device will be MAIL
 lv_control-device = 'MAIL' .
 lv_output-tdtitle = 'Mail subject Line' .
 
 CALL FUNCTION lv_fname
   EXPORTING
     control_parameters = lv_control
     mail_recipient     = lv_mail_recipient
     mail_sender        = lv_mail_sender
     output_options     = lv_output
   EXCEPTIONS
     formatting_error   = 1
     internal_error     = 2
     send_error         = 3
     user_canceled      = 4
     OTHERS             = 5.
 
 IF sy-subrc <> 0.
   MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
           WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
 ENDIF.

Sending Multiple Sapscript output in single Spool

2009-09-10T23:05:00.001+05:30

Usually we use OPEN_FORM to start executing a sapscript and CLOSE_FORM to close it and issue output to spool. This works perfectly fine when you single execution of sapscript per spool request. However OPEN_FORM and CLOSE_FORM function modules alone can not enable you to include multiple execution of sapscript in same spool number. With 'Multiple Execution' I mean when you have same sapscript executed more than once, or multiple sapscript executed one or more time. Let take two example to understand both scenario.

Scenario 1 : Same Sapscript executed more than once.
All Purchase Orders created on a day should be in same spool. In this case you need to execute same sapscript multiple time for each PO in put it in single spool.

Scenario 2: Multiple sapscript executed one or more time.
Purchase Order, Order confirmation and corresponding Invoice should come in same spool. This this case you need to execute sapscript of PO, Order Confirmation and Invoice and put output of all of them in same spool.

Alright, getting back to the function modules, strictly speaking OPEN_FORM and CLOSE_FORM is used to open and close a spool request for sapscript output. Importing parameter FORM of OPEN_FORM function module is optional. But when you have single sapscript to generate output then OPEN_FORM can also be used to open sapscript. But in above two scenario two function module which comes in picture is START_FORM and END_FORM.With function module START_FORM you can open sapscript and END_FORM is used to close the sapscript. Below is the sequence in which the function module should be called for scenario 1.

CALL 'OPEN_FORM' .
 
Loop at Purchase Orders.
*   Start sapscript for given PO. Specify sapscript name here
CALL 'START_FORM'
 
 
*   End Sapscript Output
CALL 'END_FORM'.
End Loop.
  
CALL 'CLOSE_FORM'

Futher reading..
Formatting Option in Sapscript
Code to Upload and Download Standard Text
Display Two ALV Grid on Screen

Config setting to make Shelf Life Exp Date input mandatory in system

2009-08-05T01:54:00.002+05:30

How to make Shelf Life Exp Date (SLED) input mandatory in system (MSC1N/MSC2N/VL32N)

Concept: The way it designed is input fields on screen of transaction MSC1N are grouped together and setting are applied on the group. For argument sake if Production date and Shelf life exp date are grouped together the attribute set on the group is shared by both the input. The attributes you can set is optional/ required and display/hide. Additionally these setting are made independently for transaction MSC1N MSC2N MSC3N and MSC4N. So you can have a field mandatory on MSC1N, optional in MSC2N.

Below steps and setting are specific to make SLED input mandatory on MSC1N and MSC2N however you can use this to set attribute of any input on these transactions.

First step is to find out the technical name of the input field. Press F1 on the field and then hit ‘Technical information’ button on the screen. Note down the screen field name which is DFBATCH-MHD_IO for SLED.

Now in SPRO follow menu path Logistics General->Batch Management->Batch Master->Field Selection Batch Master->Assign Fields to Field Groups.

Here you will see the field names and there Field group. Field Group can be any number between 1 and 40. Here field DFBATCH-MHD_IO is assigned to Field group 003. So if you change the attribute to group 003 it will be applied to SLED. Problem is there are few more fields which belong to this group and in turn they all will be mandatory.

Because of this reason we need to move field DFBATCH-MHD_IO to new field group.
Find a field group number which is not assigned and change the field group of input to that number.

Here in this case I am assigning Field group as 010 to DFBATCH-MHD_IO. Save the changes and exit the transaction.

Now go to next item in SPRO i.e. ‘Edit Field Selection Control’. In this screen you can assign attributes to each field group which is defined in previous step. In case you are wondering how, each dot in column ‘Field Selection String’ represent one field group depending on its position. For example third dot represent field group 030. Since we have assigned SLED to 010 put cursor on 10th dot and press change button.

Notice in next dialog box the field SLED appeared and now you can change the attribute of the field or rather the group. So select option button ‘Required Entry’ and click OK.

Repeat same for MSC2N. Then save the setting and that’s it, you are ready to go.

Additionally user can use transaction VL031N or VL032N to create batches without using MSC1N. To restrict user to create batch without SLED date you can check the value of SLED in user exit EXIT_SAPLVBMD_001 (Enhancement name SAPLMHD1). Just put a code to issue error message if SLED date is initial.

Create New Screen Variant for transaction FKMT (FI Acct Assignment Model Management).

2009-08-04T01:42:00.000+05:30

Data entry screen of transaction FKMT can be modified based on user requirement. There are five sap standard screen variant defined which user can select from menu Setting->Screen Variant.

SAP01 Standard one-line
SAP02 Standard two lines
SAP03 RE admin.: Object assignmt
SAP04 RE: Service charges sett.
SAP05 RE: Contract assignment

Custom screen variant can be defined from customizing.
To define custom screen variant for transaction FKMT, follow below menu path in SPRO

Financial Accounting (New)->Financial Accounting Global Setting (New) -> Document -> Recurring Entries -> Account Assignment Models: Define Entry Screen Templates

On the initial screen you will see the sap standard screen variants. You can either copy then modify the existing ones or can create one from scratch.

Note:

You can choose any field from structure KMZEI for input on FKMT screen.
You can use ‘Standard Offset + length’ button to calculate the offset and length automatically.
Field 'Equivalence number' (KMZEI-KMZIF) should be on the screen. You can have it at the end as it not displayed

Enhancement - Sales Order transactions VA01/VA02/VA03

2009-08-04T01:31:00.001+05:30

Transactions VA01, VA02 and VA03 are used to create, change and display sales order respectively.

User exit available

EXIT_SAPMV45A_910	IS-OIL/TAS: Exit Change-Flag Output determination
EXIT_SAPMV45A_911	TAS - Customer exit after creation of calloff
EXIT_SAPMV45A_920	User Exit: TAS data Incompletion Log on Doc.-header-level
EXIT_SAPMV45A_930	Userexit to allow overdelivery in Quantity schedule
EXIT_SAPMV45A_001	User Exit for Determining the Billing Plan Type
EXIT_SAPMV45A_002	Preassignment of Sold-to Party in Sales Documents
EXIT_SAPMV45A_003	Rev.Rec.: Copy Requirements An Header Level
EXIT_SAPMV45A_004	Rev.Rec.: Field Modification Sales
EXIT_SAPMV45A_005	Copyy Packing Proposal Into Outobund Delivery Orders

Screen exit

4309	4.0: Subscreen: Header - Additional data A
4312	4.0: Subscreen: Header - Additional data B
8309	Sales Document Header User Exit Header
8310	Sales Document Header User Exit Header
8459	Sales doc. Item User exit item (Additional data A)
8460	Sales Document Item User Exit Item (Additional data B)

PBO and PAI module of these screens are defined in user modifiable include, so correspoding code can written there.

Apart from above mentioned user-exit there many form exits define in program where you can put custom code. These form exits are well documented in in program SAPMV45A with sample code. To see these form exits open program SAPMV45A in SE80 and expand 'subroutine' node of tree. All form starting with USEREXIT can be used to write custom code. Some of the commonly used are

USEREXIT_AVAIL_CHECK_CREDIT
USEREXIT_CHECK_VBAK
USEREXIT_CHECK_VBAP
USEREXIT_CHECK_VBEP
USEREXIT_CHECK_VBKD
USEREXIT_CUST_MATERIAL_READ
USEREXIT_NEW_PRICING_VBAP
USEREXIT_NEW_PRICING_VBKD
USEREXIT_NUMBER_RANGE
USEREXIT_READ_DOCUMENT
USEREXIT_REFRESH_DOCUMENT
USEREXIT_SAVE_DOCUMENT
USEREXIT_SAVE_DOCUMENT_PREPARE

Most of the enhacement in VA01/VA02/VA03 are done using these form exits.

Adding additional input field to transaction:

Roughly using below step you can modify these transaction to include new input field.
1) First include the new field in table VBAK or VBAP, depending on what level to want to add the input. VBAK is sales order header data and VBAP is sales order item data.
2)Modify the screen exit to include you field.
3)Implement PBO modules to enable disable fields based on transaction VA01, VA02 and VA03.
4)Write code in PAI module or form-exit (depending on the requirement) to validate the input and give error message.

BAPI related with Sales Order processing

BAPI_SALESORDER_CHANGE	Change or delete sales order
BAPI_SALESORDER_CREATEFROMDAT2	Create Sales Order
BAPI_SALESORDER_GETLIST	Returns list of all Orders for Customer
BAPI_SALESORDER_GETSTATUS	Returns status with regard to availability, processing status (for example, delivery status) and prices.
BAPI_SALESORDER_SIMULATE	Same as Create Sales Order BAPI, however Sales Order is not updated. Simulate the Sales Order creation.

Note 93091 - Information about the BAPIs in Sales and Distribution
Note 550431 - FAQ: BAPI in sales - general questions

Tables related with sales order processing

VBAK Sales Document: Header Data
VBAP Sales Document: Item Data
VBEP Sales Document: Schedule Line Data
VBPA Sales Document: Partner
VBUK Sales Document: Header Status and Administrative Data
VBUP Sales Document: Header Status and Administrative Data
VBFA Sales Document Flow
VBKD Sales Document: Business Data
VBKFZ Cumulative Quantity Corrections
VBSN Change status relating to scheduling agreements

Controlling Excel Using OLE Automation in ABAP

2009-07-18T23:54:00.001+05:30

Excel remains the most powerful tool of the Microsoft office package, the ease of use and function available make it favorite among the users. I have seen people using the SAP report just as a tool to export the data in excel and then carry out the entire remaining task in Excel. Believe me they have compelling reason for that. There are function module and class available in SAP which will directly export (or import) the data from internal table to excel document, however in some complex situation you end up with no other solution but OLE Automation.

OLE Automation method allow ABAP program to communicate with any Application which support OLE Automation. Excel is one of them. In simple terms you can consider whole Excel as an object and as long as you know structure of the class to which this object belong you can control it as you may like.

Working with excel has its own advantage, you don’t need to know the whole object model of excel to carry out your stuff. You can simply record a macro for the desire task you want to control from ABAP and then use that macro code with little modification in ABAP to carry out same thing from ABAP. Let’s work through it with an example.

In below example we will download the data from table T005 and T005T to excel sheet with some formatting and then save it at specified location. To know what will be excel equivalent code to perform these activity we need to first record a macro in excel which will create a excel sheet, put some data on it with some formatting and save it.

To records a macro select Tool->Macro->Record New Macro

Specify the name of macro and hit OK on next screen

Once recording has started do the stuff you would like to do from ABAP, in this case I have created two columns with some formatting to it as seen in below screen shot. Once you are done stop the recording and to see the code generated choose menu Tool->Macro->Macro.

On next screen select the macro name and press Edit button. You can now see the code which will very much look like below.

Sub Macro1()
'
' Macro1 Macro
' Macro recorded 14/07/2009 by kesarip
'
'
Wookbooks.Add
ActiveCell.FormulaR1C1 = "Country "
Range("B1").Select
ActiveCell.FormulaR1C1 = "Country Name"
Range("A2").Select
ActiveCell.FormulaR1C1 = "Uk"
Range("B2").Select
ActiveCell.FormulaR1C1 = "United Kingdom"
ActiveWorkbook.SaveAs Filename:="H:\Book2.xls", FileFormat:=xlNormal, _
Password:="", WriteResPassword:="", ReadOnlyRecommended:=False, _
CreateBackup:=False
End Sub

Lets analyse some code which we will use in ABAP.

Workbooks.Add

will create new excel sheet.

Range("B1").Select

will select a particular cell

ActiveCell.FormulaR1C1 = "Coutry Name"

will put value in the selected cell.

ActiveWorkbook.SaveAs

is to save the sheet.

REPORT  zpwexcel.
 
*&---------------------------------------------------------------------*
*&      Types and Data
*&---------------------------------------------------------------------*
TYPE-POOLS ole2 .
 
TYPES: BEGIN OF ty_t005,
land1 TYPE t005-land1,
landx TYPE t005t-landx,
END OF ty_t005.
 
DATA : i_t005  TYPE TABLE OF ty_t005  ,
ls_t005 TYPE ty_t005           .
 
DATA: h_excel_application TYPE ole2_object,        " Excel object
h_activewindow      TYPE ole2_object,        " Active Window
h_work_books        TYPE ole2_object,        " List of workbooks
h_work_book         TYPE ole2_object,        " Workbook
h_active_cell       TYPE ole2_object.        " Cell
 
DATA : lv_row TYPE i   ,
lv_col TYPE i   ,
i_val  TYPE string ,
l_prop TYPE i   .
 
*&---------------------------------------------------------------------*
*&      Start of Selection
*&---------------------------------------------------------------------*
START-OF-SELECTION .
 
SELECT t005~land1
t005t~landx
INTO TABLE i_t005
FROM t005 INNER JOIN t005t ON t005~land1 = t005t~land1
WHERE t005t~spras = sy-langu .
 
*&---------------------------------------------------------------------*
*&      End of Selection
*&---------------------------------------------------------------------*
END-OF-SELECTION .
 
CREATE OBJECT h_excel_application 'EXCEL.APPLICATION'.
 
* Workbooks.Add
GET PROPERTY OF h_excel_application 'Workbooks' = h_work_books .
CALL METHOD OF h_work_books 'Add' = h_work_book .
 
* Set header values
lv_row = 1 .
lv_col = 1 .
CALL METHOD OF h_excel_application 'Cells' = h_active_cell
EXPORTING #1 = lv_row #2 = lv_col .
 
i_val = 'Country code' .
SET PROPERTY OF h_active_cell 'FormulaR1C1' = i_val .
 
lv_row = 1 .
lv_col = 2 .
CALL METHOD OF h_excel_application 'Cells' = h_active_cell
EXPORTING #1 = lv_row #2 = lv_col .
 
i_val = 'Country Name' .
SET PROPERTY OF h_active_cell 'FormulaR1C1' = i_val .
 
LOOP AT i_t005 INTO ls_t005 .
lv_row = sy-tabix + 1 .
lv_col = 1 .
CALL METHOD OF h_excel_application 'Cells' = h_active_cell
EXPORTING #1 = lv_row #2 = lv_col .
 
i_val = ls_t005-land1 .
SET PROPERTY OF h_active_cell 'FormulaR1C1' = i_val .
 
lv_col = 2 .
CALL METHOD OF h_excel_application 'Cells' = h_active_cell
EXPORTING #1 = lv_row #2 = lv_col .
 
i_val = ls_t005-landx .
SET PROPERTY OF h_active_cell 'FormulaR1C1' = i_val .
ENDLOOP.
 
* Save
CALL METHOD OF h_work_book 'SaveAs'
EXPORTING
#1 = 'H:\1.xls'.
 
* Close the current window
GET PROPERTY OF h_excel_application 'ActiveWindow'  = h_activewindow .
CALL METHOD OF h_activewindow 'Close' .

Render Charts in SAP using Google Chart API

2009-07-05T01:58:00.000+05:30


REPORT zpwtest1 .
 
DATA : i_html TYPE w3htmltabtype,
       g_url  TYPE w3url         .
 
DATA: g_html_control  TYPE REF TO cl_gui_html_viewer .
 
START-OF-SELECTION .
  CALL SCREEN 100.
 
*&---------------------------------------------------------------------*
*&      Module  STATUS_0100  OUTPUT
*&---------------------------------------------------------------------*
MODULE status_0100 OUTPUT.
 
  SET PF-STATUS 'PF01' .
  SET TITLEBAR 'TIL01' WITH 'Sample'.
 
  IF g_html_control IS INITIAL .
 
    CREATE OBJECT g_html_control
      EXPORTING
        parent = cl_gui_container=>default_screen.
 
    PERFORM bar_chart .
 
    CALL METHOD g_html_control->load_data
      EXPORTING
        type                 = 'text'
        subtype              = 'html'
      IMPORTING
        assigned_url         = g_url
      CHANGING
        data_table           = i_html
      EXCEPTIONS
        dp_invalid_parameter = 1
        dp_error_general     = 2
        cntl_error           = 3
        OTHERS               = 4.
    IF sy-subrc <> 0.
      MESSAGE ID sy-msgid TYPE 'S' NUMBER sy-msgno
                 WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    ENDIF.
 
    CALL METHOD g_html_control->show_url
      EXPORTING
        url = g_url.
 
  ENDIF .
ENDMODULE.                 " STATUS_0100  OUTPUT
 
*&---------------------------------------------------------------------*
*&      Module  USER_COMMAND_0100  INPUT
*&---------------------------------------------------------------------*
MODULE user_command_0100 INPUT.
  IF sy-ucomm = 'BACK' .
    CLEAR g_html_control .
    FREE g_html_control .
 
    LEAVE TO SCREEN 0 .
  ENDIF.
ENDMODULE.                 " USER_COMMAND_0100  INPUT
 
*&---------------------------------------------------------------------*
*&      Form  BAR_CHART
*&---------------------------------------------------------------------*
FORM bar_chart .
 
  DATA lv_html TYPE string .
 
  CONCATENATE
  '<html>'
  '<body>'
 
  '<img src="http://chart.apis.google.com/chart?'
 
*  Data
  '&chd=t:10,20,90,40,70,60,50,40,20,40'
 
*  Chart Type
  '&cht=bhs'
 
*  Size
   '&chs=700x350'
 
*  Scale
  '&chds=0,100'
  '&chxt=x,y'
  '&chxl=1:|Dollar|Yen|Pound|Franks|Euro|Ruble|Peso|Dirham|Rupee|Dinar|'
            '0:|0|10|20|30|40|50|60|70|80|90|100'
 
* Chart Heading
  '&chtt=Sample+Bar+Chart'
 
* Backgroud lines
  '&chg=10,0'
 
  '&alt="Sample chart" />'
 
  '</body>'
  '</html>'
  INTO lv_html .
 
  CALL FUNCTION 'HR_EFI_CONVERT_STRING_TO_TABLE'
    EXPORTING
      i_string         = lv_html
      i_tabline_length = 255
    TABLES
      et_table         = i_html.

ENDFORM.                    " BAR_CHART

Display ALV Grid (OOP) Fullscreen

2009-07-05T01:46:00.000+05:30

Normally to display ALV Grid fullscreen we use CL_GUI_DOCKING_CONTAINER and put grid on it (or use FM method and live happily ever after). Problem with this approach is user can resize the docking container at runtime. Its not a big problem but you know how proud user feels when they discover this kind of stuff.

Anyway, the point is you can achieve fullscreen functionality with Custom Control so why use Docking Container.

Simply define your screen bigger than the maximum resolution of any user. Put a Custom Control on the whole screen i.e. custom control should occupy all the area availble on the screen (assuming there is nothing else is there). Double on Custom Control and on the property, under group Resizing tick Vertical and Horizontal. And thats it, create object of CL_GUI_CUSTOM_CONTAINER and put your grid on it.

While defining the Customer Container object do remember to specify all exception as in backgroud mode it throws exception and if you don't specify exception then your job will be in cancelled status.


    CREATE OBJECT ob_cont
      EXPORTING
        container_name              = 'GRID'
      EXCEPTIONS
        cntl_error                  = 1
        cntl_system_error           = 2
        create_error                = 3
        lifetime_error              = 4
        lifetime_dynpro_dynpro_link = 5.
 
    IF sy-subrc = 0 .
 
    ENDIF.

If there is screen element on the right hand side of your Custom Control then you can not allow horizontal resizing. In that case uncheck 'Horizontal' resizing. Same is the case with Vertical scrolling if there is any screen element under you Custom Container.

Processing xml with XSLT transformation in ABAP

2009-05-29T23:11:00.000+05:30

XML string in ABAP can be directly converted to internal table or vice-versa using command CALL TRANSFORMATION. Before you use the command you need to define XSLT transformation. XSLT transformation defines structure of XML data. CALL TRANSFORMATION then use this XSLT to process the xml and convert it to ABAP variable. Below sample code which consumes a Web service and process result XML string using CALL TRANSFORMATION to convert it into ABAP variables/internal table.

Before we continue with ABAP part of it worth looking at webservice. This webservice GetDirection provides driving direction from one address to another based on parameter 'distanceUnit' and 'expresswayEnabled' (avoid motorway).

Below is the screen shot of xml result, returned by webservice, which will be processed using CALL TRANFORMATION. Click on this link to see the XML result.

In short data is organized in tags <drivingdirections> <route> <totalDistance> and <totalTime> . Tag <route> repeats for each driving instruction so for obvious reasons data in <routes> tag will result in internal table. XSLT file will have more or less same structure as below.

<?xml version="1.0" encoding="utf-8"?>
<drivingdirections>
  <route id="XX" distanceToTravel="XXXX" finalStep="XXXX">XXXX</route>
  <totalDistance>XXX</totalDistance>
  <totalTime>XXX</totalTime>
</drivingdirections>

To create XSLT file open transaction SE80, hit 'Edit Object' under 'More' tab enter name next to 'Transformation' and press 'New' button.

Enter description and choose 'Simple Transformation' press Ok.

Below is screen shot thats shows how the final XSLT transformation looks like for above XML string. Below three lines defines the reference ABAP variables where the data will be transfered


  <tt:root name="T_ROUTE" type="?"/>
  <tt:root name="TOTDISTANCE" type="?"/>
  <tt:root name="TIME" type="?"/>

The structure of XML data is defined between tags

<tt:template>
</tt:template>

Note how <route> tag is defined


<?sap.transform simple?>
<tt:transform xmlns:tt="http://www.sap.com/transformation-templates" xmlns:ddic="http://www.sap.com/abapxml/types/dictionary" xmlns:def="http://www.sap.com/abapxml/types/defined">
 
  <tt:root name="T_ROUTE" type="?"/>
  <tt:root name="TOTDISTANCE" type="?"/>
  <tt:root name="TIME" type="?"/>
 
  <tt:template>
 
    <drivingdirections>
 
      <tt:loop name="Route" ref="T_ROUTE">
        <route>
          <tt:attribute name="id" value-ref="$Route.ID"/>
          <tt:attribute name="distanceToTravel" value-ref="$Route.DISTANCE"/>
          <tt:attribute name="finalStep" value-ref="$Route.FINAL"/>
          <tt:value ref="$Route.ROUTETXT"/>
        </route>
      </tt:loop>
 
      <totalDistance>
        <tt:value ref="TOTDISTANCE"/>
      </totalDistance>
 
      <totalTime>
        <tt:value ref="TIME"/>
      </totalTime>
 
    </drivingdirections>
 
  </tt:template>
 
</tt:transform>

And here is the sample code ...


REPORT  zpw_websrvice_direction.
 
*&---------------------------------------------------------------------*
*&      Types and Data
*&---------------------------------------------------------------------*
DATA:  http_client    TYPE REF TO if_http_client ,
       http_url       TYPE string                ,
       p_content      TYPE string                .
 
DATA : v_unit TYPE string ,
       v_motor TYPE string .
*&---------------------------------------------------------------------*
*&      Selection Screen
*&---------------------------------------------------------------------*
SELECTION-SCREEN BEGIN OF BLOCK m1 WITH FRAME .
PARAMETERS : p_strt TYPE char7 ,
             p_end  TYPE char7 .
SELECTION-SCREEN SKIP 1  .
PARAMETERS : p_mile TYPE char01 RADIOBUTTON GROUP r1 ,
             p_km   TYPE char01 RADIOBUTTON GROUP r1 .
SELECTION-SCREEN SKIP 1  .
PARAMETERS : p_motor TYPE char01 AS CHECKBOX DEFAULT 'X' .
SELECTION-SCREEN END OF BLOCK m1.
 
*&---------------------------------------------------------------------*
*&      Start of Selection
*&---------------------------------------------------------------------*
START-OF-SELECTION .
 
* Build the url string based on input
  IF p_mile = 'X' .
    v_unit = 'mile' .
  ELSE.
    v_unit = 'km' .
  ENDIF.
 
  IF p_motor = 'X' .
    v_motor = 'true' .
  ELSE.
    v_motor = 'false' .
  ENDIF.
 
  CONCATENATE 'http://www.ecubicle.net/driving.asmx'
              '/GetDirections?fromAddress=' p_strt
              '&toAddress=' p_end
              '&distanceUnit=' v_unit
              '&expresswayEnabled=' v_motor
              INTO http_url .
 
* Creation of new IF_HTTP_Client object
  CALL METHOD cl_http_client=>create_by_url
    EXPORTING
      url                = http_url
    IMPORTING
      client             = http_client
    EXCEPTIONS
      argument_not_found = 1
      plugin_not_active  = 2
      internal_error     = 3
      OTHERS             = 4.
 
  http_client->request->set_header_field( name  = '~request_method'
                                          value = 'GET' ).
* Send the request
  http_client->send( ).
 
* Reterive the result
  CALL METHOD http_client->receive
    EXCEPTIONS
      http_communication_failure = 1
      http_invalid_state         = 2
      http_processing_failed     = 3
      OTHERS                     = 4.
 
  p_content = http_client->response->get_cdata( ).
  REPLACE  ALL OCCURRENCES OF '<' IN p_content WITH '<' .
  REPLACE ALL OCCURRENCES OF '>' IN p_content WITH '>' .
 
  TYPES : BEGIN OF ty_route ,
            id       TYPE string ,
            distance TYPE string ,
            final    TYPE string ,
            routetxt TYPE string ,
           END OF ty_route .
 
  DATA : l_route TYPE TABLE OF ty_route ,
         l_totdistance TYPE string ,
         l_time TYPE string .
 
  TRY .
 
      CALL TRANSFORMATION zpw_direct
            SOURCE XML p_content
            RESULT     t_route = l_route
                       totdistance = l_totdistance
                       time =  l_time .
    CATCH cx_st_error.
 
  ENDTRY.
 
  DATA : ls_route TYPE ty_route .
 
  LOOP AT l_route INTO ls_route .
    IF ls_route-final <> 'true' .
      WRITE : /1 ls_route-id ,
              10 ls_route-distance ,
              20 ls_route-routetxt .
    ENDIF.
  ENDLOOP.
 
  WRITE : / 'Total Distance : ' , l_totdistance ,
          / 'Time           : ' , l_time        .

Click here to read more about Consuming Webservice in ABAP.

Use of Application Log FMs to display Message List/Log

2009-05-22T04:25:00.000+05:30


 
REPORT zpwtest .
 
*&---------------------------------------------------------------------*
*&      Types and Data
*&---------------------------------------------------------------------*
DATA: l_log_handle        TYPE balloghndl,
      l_s_log             TYPE bal_s_log ,
      l_s_msg             TYPE bal_s_msg ,
      l_msgno             TYPE symsgno   ,
      l_s_display_profile TYPE bal_s_prof.
 
DATA : i_t100  TYPE TABLE OF t100 ,
       ls_t100 TYPE t100          .
 
*&---------------------------------------------------------------------*
*&      Selection Screen
*&---------------------------------------------------------------------*
PARAMETERS : p_arbgb TYPE t100-arbgb OBLIGATORY DEFAULT 'SD' .
 
*&---------------------------------------------------------------------*
*&      Start of Selection
*&---------------------------------------------------------------------*
START-OF-SELECTION .
 
  SELECT *
    INTO TABLE i_t100
    FROM t100
    WHERE sprsl = sy-langu
     AND arbgb = p_arbgb .
 
*&---------------------------------------------------------------------*
*&      End of Selection
*&---------------------------------------------------------------------*
END-OF-SELECTION .
 
* Create an initial log file ------------------------------------------*
  l_s_log-extnumber  = 'Messages'.
  CALL FUNCTION 'BAL_LOG_CREATE'
    EXPORTING
      i_s_log      = l_s_log
    IMPORTING
      e_log_handle = l_log_handle
    EXCEPTIONS
      OTHERS       = 1.
  IF sy-subrc <> 0.
  ENDIF.
 
  DATA lv_int TYPE sy-tabix .
 
* Fill up corresponding error messages to log --------------------------*
  LOOP AT i_t100 INTO ls_t100.
    CLEAR l_s_msg .
    lv_int = sy-tabix MOD 3 .
    IF lv_int = 0 .
      l_s_msg-msgty = 'S' .
    ELSEIF lv_int = 1 .
      l_s_msg-msgty = 'E' .
    ELSE.
      l_s_msg-msgty = 'W' .
    ENDIF.
 
    l_s_msg-msgid = ls_t100-arbgb .
    l_s_msg-msgno = ls_t100-msgnr .
    l_s_msg-msgv1 = '&' .
    l_s_msg-msgv2 = '&' .
    l_s_msg-msgv3 = '&' .
    l_s_msg-msgv4 = '&' .
 
    CALL FUNCTION 'BAL_LOG_MSG_ADD'
      EXPORTING
        i_log_handle = l_log_handle
        i_s_msg      = l_s_msg
      EXCEPTIONS
        OTHERS       = 1.

    IF sy-subrc <> 0 .
    ENDIF .
  ENDLOOP.
 
* Prepare to display the error log -------------------------------------*
  CALL FUNCTION 'BAL_DSP_PROFILE_NO_TREE_GET'
    IMPORTING
      e_s_display_profile = l_s_display_profile.
 
* l_s_display_profile-use_grid = 'X' .
  l_s_display_profile-disvariant-report = sy-repid.
  l_s_display_profile-disvariant-handle = 'LOG'.
 
* Display error messages in grid ---------------------------------------*
  CALL FUNCTION 'BAL_DSP_LOG_DISPLAY'
    EXPORTING
      i_s_display_profile = l_s_display_profile
    EXCEPTIONS
      OTHERS              = 1.
  IF sy-subrc <> 0.
  ENDIF.
 
* Delete the messages inserted to application log ----------------------*
  CALL FUNCTION 'BAL_LOG_MSG_DELETE_ALL'
    EXPORTING
      i_log_handle  = l_log_handle
    EXCEPTIONS
      log_not_found = 1
      OTHERS        = 2.
 
  IF sy-subrc <> 0.
  ENDIF.

Reset ALV Export Option for User

2009-05-22T04:14:00.000+05:30

On any ALV screen when user selects Export->Spreadsheet they usually get a dialog box for selection of format in which output needs to be exported.

As long as user doesn't select 'Always Use selected format', this dialog will be presented every time user select to export. However once the 'Always Use Selected Format' is checked user will never get this dialog box and the selected format will get automatically selected while exporting the ALV List.

Report SALV_BS_ADMIN_MAINTAIN is used to reset this setting. It's easy, run the report, select and delete the record for the specific user from report output and that user will get the dialog again.

This works fine with all other format but ‘Excel (In Existing XXL)’. If user has selected this format and checked ‘Always Use selected format’ you will not see anything in report SALV_BS_ADMIN_MAINTAIN for that user unless parameter id SALV_BS_ADMIN_XXL is set in your profile (not users).

Simple Code to consume Web service using SAP ABAP

2009-05-17T22:40:00.006+05:30

Below is very simple code, which demonstration how to call a webservice using class CL_HTTP_CLIENT. Web service used in this example is GetCitiesByCountry which returns all major cities by country name. It returns the result in xml format. The request is invoke in form http://www.webservicex.net/globalweather.asmx/GetCitiesByCountry?CountryName=india.

REPORT  zpw_webservice.
 
*&---------------------------------------------------------------------*
*&      Selection Screen
*&---------------------------------------------------------------------*
PARAMETERS : p_cnt TYPE t005t-landx .
 
*&---------------------------------------------------------------------*
*&      Types and Data
*&---------------------------------------------------------------------*
DATA:  http_client    TYPE REF TO if_http_client ,
http_url       TYPE string                ,
p_content      TYPE string                .
 
*&---------------------------------------------------------------------*
*&      Start of Selection
*&---------------------------------------------------------------------*
START-OF-SELECTION .
 
* Build the url string based on input
CONCATENATE 'http://www.webservicex.net/globalweather.asmx'
'/GetCitiesByCountry?CountryName='
p_cnt
INTO http_url .
 
* Creation of new IF_HTTP_Client object
CALL METHOD cl_http_client=>create_by_url
EXPORTING
url                = http_url
IMPORTING
client             = http_client
EXCEPTIONS
argument_not_found = 1
plugin_not_active  = 2
internal_error     = 3
OTHERS             = 4.
 
http_client->request->set_header_field( name  = '~request_method'
value = 'GET' ).
* Send the request
http_client->send( ).
 
* Reterive the result
CALL METHOD http_client->receive
EXCEPTIONS
http_communication_failure = 1
http_invalid_state         = 2
http_processing_failed     = 3
OTHERS                     = 4.
 
p_content = http_client->response->get_cdata( ).
REPLACE  ALL OCCURRENCES OF '&lt;' IN p_content WITH '<' .
REPLACE ALL OCCURRENCES OF '&gt;' IN p_content WITH '>' .
 
*&---------------------------------------------------------------------*
*&      Processing the string
*&---------------------------------------------------------------------*
DATA : moff  TYPE syst-tabix ,
moff1 TYPE syst-tabix ,
len   TYPE syst-tabix .
 
DO .
   FIND '<City>' IN SECTION OFFSET moff OF p_content IGNORING CASE MATCH OFFSET moff .
  IF sy-subrc = 0 .
    moff = moff + 6 .
    FIND '</City>' IN SECTION OFFSET moff OF p_content IGNORING CASE MATCH OFFSET moff1 .
    len = moff1 - moff .
    WRITE : / p_content+moff(len) .
  ELSE.
    EXIT.
  ENDIF.
 
ENDDO .

In this code processing of XML string is done using FIND statement. SAP has introduced command CALL TRANSFORMATION since Basis release 6.10 for XML processing. This command CALL TRANSFORMATION process the whole XML string based on defined transformation and return it in variable/internal table. Transformations can be defined using transaction SE80. Ok I am leaving this topic for next blog ;)

Creating custom page format for sapscript/smartform

2009-05-13T12:20:00.000+05:30

You can print any size of output from SAP, it all depends on what page format is defined and configured in your SAP system. Most of the standard page format are already defined in SAP but often you come across the situation where the required output doesn’t even come close to any of these predefined page format. Printing cheques and receipts are some common example. Defining and configuring Page format is multi-step process and often is printer specific. In short its very easy to get your setting wrong and situation is worse when printer is physically away from you.

Its very important to understand how this page format works in SAP. The process starts with defining the Page Format, but you need few more setting to actually print this page size on printer. Page format just define the size of page for sapscript (this size info defined in page format is not passed to printer), next step is to define Format type which defines 'Type of format' and what orientation are allowed with this page format. It is important to note that Page Format and Format type should have same name. Well, you can argue why do we need to define Format Type. To find out that, which you may find bit confusing refer sap note 2374. Still you can not print with this page size on printer. To allow printer to use this new page format you need to add this page format to device type of printer. This step will enable you to print the output but correct page size information will not be passed to printer. You need to actually put printer specific code to set desire page size on printer.

Before we start it worth checking where do we specify page format in sapscript.

Now let us go through each step with screen shot. You need to have access to transaction SPAD and changes to the repository and cross-client customizing should be permitted in the client where you will create/change page format.

Execute transaction SPAD. By default transaction will not show all the tabs, you need to click on 'Full administration' to get the desire tab.

Go to 'Device Types' tabs and hit 'Display' button next to Page Formats.

On next screen hit 'change' button then you will button to create new Page format, now press New button.

Fill in the required input, below is an example.

Congrats you just created a new page format.

At this stage you can use this page format in sapscript, however you can not print that sapscript. This information of page dimension is just for sapscript. You will get warning message while adding page format to sapscript 'There is no form for page format XYZ' and error message while printing 'Device type ABC does not support page format XYZ'.

Next step is to create Format Type. Remember Format Type should have same name as your Page Format name. Start from transaction SPAD, on 'Device Type’ tab press display button next to 'Format Type'. Click on change then new button and create Format Type as shown in screen-shot below.

To allow printer to use this new Format Type you need to add this format to device type of printer. You can find the device type of printer from table TSP03D, it is stored in field PATYPE.

On 'Device Types' table enter Device name and press Display button next to it.

Go in change mode and press 'Formats'

On next screen press ‘New’ button and enter 'Format Type'.

Once the format type added to device type, double click on the line (on first column). On next screen as shown below double click on 'Printer initialization'

Input following code, this code will actually set the page length on printer. Page length is defined under the code '# set page length 72 lines'. Its defined in hex and is defined in lines. You might have to do some math to convert your page length from CM/MM to line considering lines per inch value set.

For example in this particular case the page length define Page format is 102 mm which is 4 inches. Using setting 6 lines per inch 4 inches comes out to be 24 lines. (ok, the comment is wrong, it should be '# set page length 24 lines'). And in hex 24 is represented as 18.

You might need to add this format and put this code for each device type of each printer on which you are planning to print the output.

With all these setting in place you can, hopefully, print the output on printer with correct page format.

Links

2009-04-19T20:16:00.000+05:30

A very useful blog, discuss about the various configuration setting in SAP to send email from SAP.

Step-by-Step Guide for using BAPI in LSMW including screen-shots.

Sample code to send smartform output as PDF attachement in mail to external email id.

SAP Factory Calendar

2009-03-17T22:18:00.000+05:30

Function module DATE_CONVERT_TO_FACTORYDATE can be used to check if a particular day is holiday. Below is the sample code to demosntration the use of functional module.


REPORT  zsample.
 
DATA : lv_date TYPE syst-datum  ,
       lv_ind  TYPE scal-indicator .
 
lv_date = sy-datum .
 
DO 365 TIMES .
 
 CALL FUNCTION 'DATE_CONVERT_TO_FACTORYDATE'
   EXPORTING
     date                 = lv_date
     factory_calendar_id  = 'GB'
   IMPORTING
     workingday_indicator = lv_ind.
 
 IF lv_ind = space .
   WRITE : / lv_date .
 ELSEIF lv_ind = '+' .
   WRITE : / lv_date , 'Holiday' .
 ELSE.
   WRITE : / lv_date , '########' .
 ENDIF.
 
 lv_date = lv_date + 1 .
 
ENDDO .

Traffic Light on Selection Screen

2009-02-22T05:06:00.001+05:30

Just a quick reference code to put traffic light option buttons on selection screen

 
REPORT zpwtest .
 
*&---------------------------------------------------------------------*
*&      Types and Data
*&---------------------------------------------------------------------*
CONSTANTS:  c_green           TYPE icon_d           VALUE '@08@'     ,
c_amber           TYPE icon_d           VALUE '@09@'     ,
c_red             TYPE icon_d           VALUE '@0A@'     .
 
*&---------------------------------------------------------------------*
*&      Selection Screen
*&---------------------------------------------------------------------*
SELECTION-SCREEN BEGIN OF BLOCK main10 WITH FRAME.
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT 01(31) v_cap .
PARAMETERS : p_all TYPE char01 RADIOBUTTON GROUP grp .
SELECTION-SCREEN COMMENT 40(5) v_all FOR FIELD p_all .
PARAMETERS : p_red TYPE char01 RADIOBUTTON GROUP grp .
SELECTION-SCREEN COMMENT 47(10) v_red FOR FIELD p_red .
PARAMETERS : p_amber TYPE char01 RADIOBUTTON GROUP grp .
SELECTION-SCREEN COMMENT 60(10) v_amber FOR FIELD p_amber .
PARAMETERS : p_green TYPE char01 RADIOBUTTON GROUP grp .
SELECTION-SCREEN COMMENT 73(10) v_green FOR FIELD p_green .
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN END OF BLOCK main10 .
 
*&---------------------------------------------------------------------*
*&      Start of Selection
*&---------------------------------------------------------------------*
INITIALIZATION.
v_cap   = 'Status'.
v_all   = 'All'.
v_red   = c_red .
v_amber = c_amber .
v_green = c_green .

Pricing Condition for Outline Agreement

2009-01-11T22:31:00.000+05:30


REPORT zpwtest .

TABLES : ekko ,  ekpo , lfa1 , komk , komp , t001 , t001w , komv .

DATA : tkomv  TYPE TABLE OF komv  .

PARAMETER : p_ebeln TYPE ekpo-ebeln ,
           p_ebelp TYPE ekpo-ebelp .

SELECT SINGLE *
 FROM ekko
 WHERE ebeln = p_ebeln .

SELECT SINGLE *
 FROM ekpo
 WHERE ebeln = p_ebeln
 AND ebelp = p_ebelp.

SELECT SINGLE *
 FROM lfa1
 WHERE lifnr = ekko-lifnr .

SELECT SINGLE *
 FROM t001
 WHERE bukrs = ekko-bukrs .

SELECT SINGLE *
 FROM t001w
 WHERE werks = ekpo-werks .

CALL FUNCTION 'ME_FILL_KOMK_PO'
 EXPORTING
   i_ekko  = ekko
   i_ekpo  = ekpo
   i_lfa1  = lfa1
   i_t001w = t001w
   i_t001  = t001
   i_kalsm = ekko-kalsm
   i_kappl = 'M'
   i_kvorg = '02'             "Preissimulation
 IMPORTING
   e_komk  = komk.

IF komk-prsdt EQ 0.
 komk-prsdt = sy-datlo.
ENDIF.

komk-fbuda = sy-datlo.

CALL FUNCTION 'ME_FILL_KOMP_PO'
    EXPORTING
         i_ekpo  = ekpo
         i_t001w = t001w
         i_ekko  = ekko
         i_komk  = komk
    IMPORTING
         e_komp  = komp.

CALL FUNCTION 'PRICING'
 EXPORTING
   calculation_type = 'B'
   comm_head_i      = komk
   comm_item_i      = komp
 IMPORTING
   comm_head_e      = komk
   comm_item_e      = komp
 TABLES
   tkomv            = tkomv.

LOOP AT tkomv INTO komv .
 WRITE : / komv-kschl , komv-kbetr CURRENCY komv-waers , komv-waers .
ENDLOOP.

Create New IDoc Status

2008-12-18T01:13:00.000+05:30

1. Use maintenance view VEDI_STATS to create new entry for IDOC status from transaction SM30. Save the entry in Workbench request. (You won't be able to see your status in WE47 yet).
2. Using transaction SE11 enter new record to table STACUST. Follow menu path Utilities->Table Content->Create Entries. You need to assign status group to your new custom status here. To see all status groups use transaction WELI.
3. In step 2, SAP might not ask for customizing request. In that case you need to attach IDoc status to customizing request manually using SE11/SE16.
4. OK, now you can see new IDOC status in WE47.

Even though you categorizes IDOC status as Inbound or Outbound in Step 1 (VEDI_STATS), in BD87 it is hard-coded to treat IDOC as outbound only if it is less than 50.

Reterieve Sales Pricing Condition

2008-11-14T02:25:00.000+05:30


*&---------------------------------------------------------------------*
*&      Report
*&---------------------------------------------------------------------*
REPORT zpwtest .
 
PARAMETERS : p_kunnr TYPE kunre OBLIGATORY,
             p_werks TYPE marc-werks OBLIGATORY,
             p_matnr TYPE mara-matnr OBLIGATORY,
             p_vkorg TYPE vkorg OBLIGATORY,
             p_vtweg TYPE vtweg OBLIGATORY,
             p_spart TYPE spart OBLIGATORY.
 
START-OF-SELECTION .
 
  PERFORM simulate_pricing .
 
*&---------------------------------------------------------------------*
*&      Form  simulate_pricing
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
FORM simulate_pricing .
 
  DATA : lt_items    TYPE TABLE OF bapiitemin  ,
         lt_partners TYPE TABLE OF bapipartnr  ,
         lt_pricing  TYPE TABLE OF bapicond    ,
         lt_messages TYPE TABLE OF bapiret2    ,            "#EC NEEDED
         ls_item     TYPE bapiitemin           ,
         ls_partner  TYPE bapipartnr           ,
         ls_head     TYPE bapisdhead           ,
         ls_price    TYPE bapicond             ,
         ls_message  TYPE bapiret2             ,            "#EC NEEDED
         ls_return   TYPE bapireturn           ,            "#EC NEEDED
         ls_vapma    TYPE vapma                ,
         ls_vbap     TYPE vbap                 ,
         ls_vbup     TYPE vbup                 ,
         ls_mbew     TYPE mbew                 .
 
* Header
  ls_head-doc_type = 'ZOR' .
  ls_head-sales_org = p_vkorg .
  ls_head-distr_chan = p_vtweg .
  ls_head-division = p_spart .
  ls_head-purch_no = 'DUMMY' .
 
* Partners
  CLEAR ls_partner .
  ls_partner-partn_role = 'AG' .
  ls_partner-partn_numb = p_kunnr .
  APPEND ls_partner TO lt_partners .
 
  CLEAR ls_partner .
  ls_partner-partn_role = 'WE' .
  ls_partner-partn_numb = p_kunnr .
  APPEND ls_partner TO lt_partners .
 
* Items
  CLEAR ls_item .
  ls_item-material = p_matnr .
  ls_item-plant    = p_werks .
  APPEND ls_item TO lt_items .
 
  CALL FUNCTION 'BAPI_SALESORDER_SIMULATE'
    EXPORTING
      order_header_in    = ls_head
    IMPORTING
      return             = ls_return
    TABLES
      order_items_in     = lt_items
      order_partners     = lt_partners
      order_condition_ex = lt_pricing
      messagetable       = lt_messages.
 
  LOOP AT lt_pricing INTO ls_price .
    IF ls_price-condisacti = 'X' .
      WRITE : / '@0A@' AS ICON .
    ELSE.
      WRITE : / '@08@' AS ICON .
    ENDIF.
 
    WRITE : ls_price-cond_type .
 
    IF ls_price-currency IS NOT INITIAL .
      WRITE : ls_price-cond_value CURRENCY ls_price-currency ,
              ls_price-currency .
    ELSE.
      WRITE ls_price-cond_value DECIMALS 2.
    ENDIF.
 
    IF ls_price-cond_p_unt IS NOT INITIAL .
      WRITE : 'Per' ,
              ls_price-cond_p_unt UNIT ls_price-cond_unit ,
              ls_price-cond_unit .
    ENDIF.
  ENDLOOP.
ENDFORM.                    "simulate_pricing

Parameter ID to set tab in MM03

2008-10-01T15:44:00.000+05:30

While implementing the drill down functionality for MM03 using statement CALL TRANSACTION.. SKIP INITIAL SCREEN you can set the initial tab in MM03 where user will land using parameter id MXX use following code for corresponding tabs.

K	Basic Data 1
C	Classification
V	Sales: Sales Org. Data 1
E	Purchasing
D	MRP 1
P	Forecasting
A	Work Scheduling
F	Production Resources/Tools
L	General Plant Data / Storage 1
S	Warehouse Management 1
Q	Quality Management
B	Accounting 1
G	Costing 1
X	Plant Stock
Z	Storage Location Stock

Clear Selection-Screen

2008-09-30T02:14:00.000+05:30

After the report execution when user press 'Back' button the selection-screen is displayed with the values entered in first place. If you want the selection-screen to be all clear then add following lines of code at the end of END-OF-SELECTION event.


FIELD-SYMBOLS : <fs>  .
  ASSIGN ('(RSDBRUNT)MEMKEY-INT_MODE') TO <fs> .
  IF sy-subrc = 0 .
    <FS> = '01' .
  ENDIF.

ADD_TIME_TO_DATE

2008-09-26T13:47:00.001+05:30

ADD_TIME_TO_DATE function module is very useful for mathematical operation on date. It can be used to add or subtract days, weeks, months or year from a given date. It takes care of all obvious complexities. Try it..


*&---------------------------------------------------------------------*
*&      Report
*&---------------------------------------------------------------------*
REPORT zpwtest .
 
DATA gv_date TYPE syst-datum .
 
*&---------------------------------------------------------------------*
*&      Selection Screen
*&---------------------------------------------------------------------*
PARAMETER : p_date TYPE syst-datum DEFAULT '20080131' .
 
CONSTANTS : c_day   TYPE mara-iprkz VALUE ' ' ,
            c_week  TYPE mara-iprkz VALUE '1' ,
            c_month TYPE mara-iprkz VALUE '2' ,
            c_year  TYPE mara-iprkz VALUE '3' .
 
*&---------------------------------------------------------------------*
*&      Start of Selection
*&---------------------------------------------------------------------*
START-OF-SELECTION .
 
* Add one day
  PERFORM date_action USING p_date '1' c_day CHANGING gv_date .
  WRITE : / p_date , '1' , 'Day' , gv_date .
 
* Add one week
  PERFORM date_action USING p_date '1' c_week CHANGING gv_date .
  WRITE : / p_date , '1' , 'Week' , gv_date .
 
* Add one month
  PERFORM date_action USING p_date '1' c_month CHANGING gv_date .
  WRITE : / p_date , '1' , 'Month' , gv_date .
 
* Add one year
  PERFORM date_action USING p_date '1' c_year CHANGING gv_date .
  WRITE : / p_date , '1' , 'Year' , gv_date .
 
* Subtract one day
  PERFORM date_action USING p_date '-1' c_day CHANGING gv_date .
  WRITE : / p_date , '-1' , 'Day' , gv_date .
 
* Subtract one Week
  PERFORM date_action USING p_date '-1' c_week CHANGING gv_date .
  WRITE : / p_date , '-1' , 'Week' , gv_date .
 
* Subtract one Month
  PERFORM date_action USING p_date '-1' c_month CHANGING gv_date .
  WRITE : / p_date , '-1' , 'Month' , gv_date .
 
* Subtract one Year
  PERFORM date_action USING p_date '-1' c_year CHANGING gv_date .
  WRITE : / p_date , '-1' , 'Year' , gv_date .
 
*&---------------------------------------------------------------------*
*&      Form  date_action
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*      -->I_DATE     text
*      -->I_HOWMUCH  text
*      -->I_WHAT     text
*      -->C_DATE     text
*----------------------------------------------------------------------*
FORM date_action USING i_date     TYPE syst-datum
                       i_howmuch  TYPE mara-mhdhb
                       i_what     TYPE mara-iprkz
                 CHANGING c_date TYPE syst-datum .
 
  CALL FUNCTION 'ADD_TIME_TO_DATE'
    EXPORTING
      i_idate = i_date
      i_time  = i_howmuch
      i_iprkz = i_what
    IMPORTING
      o_idate = c_date.

ENDFORM.                    "date_action

Retrieve Purchase Order Pricing Conditions

2008-09-23T23:00:00.000+05:30

Below code can be used to retrieve the pricing conditions of a Purchase Order which is shown in ME23N transaction.


*&---------------------------------------------------------------------*
*& Report  ZPWTEST2
*&---------------------------------------------------------------------*
 
REPORT  zpwtest2.
 
TABLES ekko .
 
*&---------------------------------------------------------------------*
*& Data
*&---------------------------------------------------------------------*
 
DATA : ls_head TYPE komk  ,
       ls_item TYPE komp  ,
       lt_komv  TYPE TABLE OF komv  ,
       lt_komvd TYPE TABLE OF komvd ,
       ls_komv  TYPE komv  .
 
*&---------------------------------------------------------------------*
*& Selection
*&---------------------------------------------------------------------*
 
PARAMETERS : p_ebeln TYPE ekko-ebeln OBLIGATORY.
 
*&---------------------------------------------------------------------*
*& Start of Selection
*&---------------------------------------------------------------------*
 
START-OF-SELECTION .
 
  SELECT SINGLE * FROM ekko WHERE ebeln = p_ebeln .
 
*&---------------------------------------------------------------------*
*& End of Selection
*&---------------------------------------------------------------------*
 
END-OF-SELECTION .
 
  ls_head-mandt = sy-mandt.
  ls_head-belnr = ekko-ebeln .
  ls_head-kalsm = ekko-kalsm.
  IF ls_head-kalsm IS INITIAL .
    ls_head-kalsm = 'RM0000'.
  ENDIF.
  ls_head-kappl = 'M'.
  ls_head-waerk = ekko-waers.
  ls_head-knumv = ekko-knumv.
  ls_head-lifnr = ekko-lifnr.
 
  CALL FUNCTION 'RV_PRICE_PRINT_REFRESH'
    TABLES
      tkomv = lt_komv.
 
  CALL FUNCTION 'RV_PRICE_PRINT_ITEM'
    EXPORTING
      comm_head_i = ls_head
      comm_item_i = ls_item
    TABLES
      tkomv       = lt_komv
      tkomvd      = lt_komvd.
 
  LOOP AT lt_komv INTO ls_komv .
    WRITE : / ls_komv-kschl ,
              ls_komv-kbetr CURRENCY ls_komv-waers,
              ls_komv-waers ,
              ls_komv-kpein UNIT ls_komv-kmein,
              ls_komv-kmein ,
              ls_komv-kwert CURRENCY ls_komv-waers.
  ENDLOOP.

Getting Statistic fields for stock - MD04

2008-09-04T01:17:00.000+05:30

In transaction MD04 if you double click on Available Qty a pop-up screen will appear with various stock figure which is defined in structure MDSTA.

These values are calculated by SAP standard code at run-time. Below code can be used to derive those values using material and plant as input



*&---------------------------------------------------------------------*
*& Report  ZPWTEST
*&
*&---------------------------------------------------------------------*
 
REPORT  zpwtest.
 
TYPE-POOLS m61x .
 
DATA mdsta TYPE mdsta .
 
PARAMETER : p_matnr TYPE marc-matnr ,
            p_werks TYPE marc-werks .
 
START-OF-SELECTION .
 
  PERFORM get_stock_fig USING p_matnr p_werks CHANGING mdsta .
 

*&---------------------------------------------------------------------*
*&      Form  get_stock_fig
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*      -->I_MATNR    text
*      -->I_WERKS    text
*      -->C_MDSTA    text
*----------------------------------------------------------------------*
FORM get_stock_fig  USING    i_matnr
                             i_werks
                    CHANGING c_mdsta.
 
  DATA  : ls_cm61m TYPE cm61m ,
          ls_mdkp  TYPE mdkp  ,
          ls_masel TYPE masel ,
          ls_m61b  TYPE m61x_cm61b ,
          cm61x    TYPE cm61x  ,
          cm61w    TYPE cm61w  ,
          ls_t399d TYPE t399d ,
          ls_mt61d TYPE mt61d ,
          lt_mdpsx TYPE TABLE OF mdps  ,
          ls_t001w TYPE t001w ,
          ls_t450n TYPE t450n ,
          lt_mdez  TYPE TABLE OF mdez ,
          cm61m  TYPE cm61m ,
          mdsta  TYPE mdsta .
 
 
  SELECT SINGLE *
    INTO ls_t001w
    FROM t001w
   WHERE werks = i_werks .
 
  SELECT SINGLE *
     INTO ls_t450n
     FROM t450n
    WHERE tcode = 'MD04' .
 
  SELECT SINGLE *
    INTO ls_t399d
    FROM t399d
   WHERE werks = i_werks .
 
  SELECT SINGLE *
    INTO ls_mdkp
    FROM mdkp
   WHERE dtart = 'MD'
     AND matnr = i_matnr
     AND plwrk = i_werks
     AND plscn = '000' .
 
  CALL FUNCTION 'MD_READ_MATERIAL_SIMPLE'
    EXPORTING
      ewerks                      = i_werks
      ematnr                      = i_matnr
    CHANGING
      cmt61d                      = ls_mt61d
      ccm61b                      = ls_m61b
    EXCEPTIONS
      material_mrp_area_not_found = 1
      missing_parameter           = 2
      material_plant_not_found    = 3
      material_mrp_area_deleted   = 4
      OTHERS                      = 5.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
 
  IF ls_mt61d-fxhor IS INITIAL.
    IF ls_m61b-berty IS INITIAL
    OR ls_m61b-berty EQ i_werks.
 
      SELECT SINGLE fixhz
        INTO ls_mt61d-fxhor
        FROM  t438m
       WHERE werks = ls_mt61d-werks
         AND mtart = ls_mt61d-disgr.
 
    ELSE.
 
      SELECT SINGLE fixhz
        INTO ls_mt61d-fxhor
        FROM  t438m
       WHERE werks = ls_mt61d-werks
         AND mtart = ls_m61b-disgr.

    ENDIF.
  ENDIF.
 
* --------
 
  MOVE ls_t450n-mdobj TO cm61x-plobj.
  MOVE ls_t450n-mdaty TO cm61x-plauf.
  MOVE ls_t450n-mdakt TO cm61x-plakt.
  MOVE sy-datlo       TO cm61x-dispd.
  MOVE '000'          TO cm61x-plscn.
 
* ---------------------
  MOVE ls_t001w-fabkl TO cm61w-fabkl.
  MOVE ls_t399d-umthz TO cm61w-umthz.
  MOVE cm61x-dispd    TO cm61w-dispd.
  MOVE ls_t399d-gterm TO cm61w-gterm.
  MOVE ls_t399d-selfe TO cm61w-selfe.
  MOVE ls_t399d-selbe TO cm61w-selbe.
  MOVE ls_t399d-selqm TO cm61w-selqm.
  MOVE ls_t399d-selba TO cm61w-selba.
  MOVE ls_t399d-selpa TO cm61w-selpa.
  MOVE ls_t399d-selpz TO cm61w-selpz.
  MOVE ls_t399d-selzr TO cm61w-selzr.
  MOVE ls_t399d-sella TO cm61w-sella.
 
  CALL FUNCTION 'AUFBAUEN_MDPSX_ANZEIGEN'
    EXPORTING
      ecm61w = cm61w
      ecm61x = cm61x
      emt61d = ls_mt61d
      et399d = ls_t399d
      ecm61b = ls_m61b
    IMPORTING
      icm61m = cm61m
      imdsta = mdsta
    TABLES
      mdpsx  = lt_mdpsx
    EXCEPTIONS
      error  = 1
      OTHERS = 2.
 
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
 
  CALL FUNCTION 'MDEZX_AUFBAUEN'
    EXPORTING
      ecm61m = cm61m
      emdkp  = ls_mdkp
      ecm61b = ls_m61b
      emt61d = ls_mt61d
    IMPORTING
      imasel = ls_masel
    TABLES
      mdezx  = lt_mdez
      mdpsx  = lt_mdpsx.
 
  CALL FUNCTION 'MDSTA_AUFBAUEN'
    EXPORTING
      emdsta = mdsta
      einitf = 'S'
      emt61d = ls_mt61d
      ekzdwb = ls_t399d-xfan1
      ekzumb = ls_t399d-kzumb
      enfvbc = ls_t399d-nfvbc
    IMPORTING
      imdsta = c_mdsta
    TABLES
      mdpsx  = lt_mdpsx.
 
ENDFORM.                    " GET_STOCK_FIG

Displaying Icon on Selection Screen

2008-09-04T01:12:00.001+05:30

REPORT  zpwtest.
 
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT 01(20) v_cap .
 
PARAMETERS : p_all TYPE char01 RADIOBUTTON GROUP grp .
SELECTION-SCREEN COMMENT 24(10) v_all FOR FIELD p_all .
 
 
PARAMETERS : p_red TYPE char01 RADIOBUTTON GROUP grp .
SELECTION-SCREEN COMMENT 36(10) v_red FOR FIELD p_red .
 
PARAMETERS : p_amber TYPE char01 RADIOBUTTON GROUP grp .
SELECTION-SCREEN COMMENT 48(10) v_amber FOR FIELD p_amber .
 
PARAMETERS : p_green TYPE char01 RADIOBUTTON GROUP grp .
SELECTION-SCREEN COMMENT 60(10) v_green FOR FIELD p_green .
SELECTION-SCREEN END OF LINE.
 

*--------------------------------------------------------------------*
* Initialization
*--------------------------------------------------------------------*
 
INITIALIZATION.
 
v_cap = 'Demo Option Button' .
v_all = 'All' .
v_red = '@0A@' .
v_amber = '@09@' .
v_green = '@08@' .

Display ListBox in Parameter of Selection Screen

2008-07-25T02:17:00.000+05:30

REPORT zpwtest.
 
TYPE-POOLS: vrm.
DATA: name TYPE vrm_id,
      list TYPE vrm_values,
      value LIKE LINE OF list.
 
PARAMETERS: ps_parm(10) AS LISTBOX VISIBLE LENGTH 10.
 
AT SELECTION-SCREEN OUTPUT.
 
  name = 'PS_PARM'.
  value-key = '1'.
  value-text = 'LINE 1'.
  APPEND value TO list.
  value-key = '2'.
  value-text = 'LINE 2'.
  APPEND value TO list.
  CALL FUNCTION 'VRM_SET_VALUES'
       EXPORTING
            id     = name
            values = list.
 
START-OF-SELECTION.
  WRITE: / 'PARAMETER:', ps_parm.

Important EDI Transactions and Programs

2008-07-24T16:35:00.000+05:30

SM59 - RFC Destination
WE21 - Port Definition
WE20 - Partner Profile

WE31 - Idoc Segement Definition
WE30 - Idoc Type Definition
WE81 - Logical Message Type
WE82 - Assign Message Type to Idoc

WE41 - Process Code Outbound
WE42 - Process Code Inbound

WE02 - Display Idoc

WE19 - Test Idoc Inbound
WE16 - Test Idoc Inbound with File

Hide F8 Button on Selection Screen

2008-07-20T23:30:00.000+05:30

REPORT ZREPORT.
 
DATA:
  gt_exclude TYPE TABLE OF rsexfcode,
  gs_exclude TYPE          rsexfcode.
 
PARAMETERS:
  pa_test TYPE c.
  
INITIALIZATION.
  gs_exclude-fcode  = 'ONLI'.
  APPEND gs_exclude TO gt_exclude.
  
AT SELECTION-SCREEN OUTPUT.
  
  CALL FUNCTION 'RS_SET_SELSCREEN_STATUS'
    EXPORTING
      p_status  = '%_00'
      p_program = 'RSSYSTDB'
    TABLES
      p_exclude = gt_exclude.

Find Obsolete Function Module

2008-07-20T23:29:00.001+05:30

DATA it_rodir TYPE TABLE OF rodir.
 
SELECT * 
  INTO TABLE it_rodir
  FROM rodir
 WHERE objecttype = 'FUNC'
   AND obsolete   = 'X'.

Sample RS_COVERPAGE_SELECTIONS

2008-07-18T15:59:00.000+05:30

Function Module RS_COVERPAGE_SELECTIONS is used to print user input on selection screen to report.

REPORT zpwtest.
 
TABLES : mara .
 
DATA: BEGIN OF mtab_sel_options OCCURS 0,
        flag(1) TYPE c,
        olength TYPE x,
        line  LIKE rsvar-infoline,
      END OF mtab_sel_options.
 
PARAMETERS p_matnr TYPE mara-matnr.
 
SELECT-OPTIONS : s_matnr FOR mara-matnr .
 
*&----------------------------------------------------------&*
* Start of Selection
*&----------------------------------------------------------&*
 
START-OF-SELECTION.
 
  CALL FUNCTION 'RS_COVERPAGE_SELECTIONS'
    EXPORTING
      report            = sy-repid
      variant           = ''
      no_import         = 'X'
    TABLES
      infotab           = mtab_sel_options
    EXCEPTIONS
      error_message     = 1
      variant_not_found = 2
      OTHERS            = 3.
 
  LOOP AT mtab_sel_options.
    WRITE: / mtab_sel_options-line.
  ENDLOOP.

SAP ABAP Dynamic Internal table and Processing 02

2008-07-18T15:47:00.000+05:30

Another method of creating and processing dynamic internal table in ABAP.

REPORT zpwtest .
 
DATA: lv_tablename TYPE string VALUE 'SFLIGHT'.
DATA: lv_dref      TYPE REF TO data.
 
DATA: sflighttype  TYPE REF TO cl_abap_structdescr,
      tabletype    TYPE REF TO cl_abap_tabledescr,
      comp_tab     TYPE cl_abap_structdescr=>component_table,
      new_comp_tab LIKE comp_tab,
      linetype     TYPE REF TO cl_abap_structdescr,
      dref         TYPE REF TO data.
 
FIELD-SYMBOLS: <wa_comp> LIKE LINE OF comp_tab.
FIELD-SYMBOLS: <table> TYPE ANY TABLE.
 
*&---------------------------------------------------------------------&
* Start of Selection
*&---------------------------------------------------------------------&
START-OF-SELECTION.
 
* Creation of dynamic internal table
  CREATE DATA lv_dref TYPE TABLE OF (lv_tablename).
 
  FIELD-SYMBOLS: <fs> TYPE STANDARD TABLE.
 
  ASSIGN lv_dref->* TO <fs>.
 
  SELECT *
    FROM sflight
    INTO TABLE <fs>.
 
  sflighttype ?= cl_abap_typedescr=>describe_by_name('SFLIGHT').
  comp_tab = sflighttype->get_components( ).
 
  LOOP AT comp_tab ASSIGNING <wa_comp>.
    CASE <wa_comp>-name.
      WHEN 'CARRID' OR 'CONNID' OR 'FLDATE' OR 'PRICE' OR 'CURRENCY'.
        APPEND <wa_comp> TO new_comp_tab.
    ENDCASE.
  ENDLOOP.
 
  linetype = cl_abap_structdescr=>create( new_comp_tab ).
  tabletype = cl_abap_tabledescr=>create(
  p_line_type = linetype
  p_table_kind = cl_abap_tabledescr=>tablekind_std ).
 
  CREATE DATA dref TYPE HANDLE tabletype.
  ASSIGN dref->* TO <table>.
 
  SELECT * FROM sflight INTO CORRESPONDING FIELDS OF TABLE <table>.
 
  FIELD-SYMBOLS: <wa_data> TYPE ANY.
  FIELD-SYMBOLS: <wa_field> TYPE ANY.
  LOOP AT <table> ASSIGNING <wa_data>.
    WRITE: /.
    LOOP AT new_comp_tab ASSIGNING <wa_comp>.
      ASSIGN COMPONENT sy-tabix OF STRUCTURE <wa_data> TO <wa_field>.
      WRITE: <wa_field>.
    ENDLOOP.
  ENDLOOP.

SAP ABAP Dynamic Internal table and Processing 01

2008-07-18T15:02:00.000+05:30

Sample code for creating dynamic internal table using method cl_alv_table_create=>create_dynamic_table and then processing the record in table.

REPORT zpwtest.
 
DATA: lt_data TYPE REF TO data.
DATA: lt_fieldcatalog TYPE lvc_t_fcat.
 
DATA: ls_fieldcatalog TYPE lvc_s_fcat.
 
DATA: new_line TYPE REF TO data.
 
FIELD-SYMBOLS: <fs_data> TYPE REF TO data,
               <fs_1> TYPE ANY TABLE,
               <fs_2>,
               <fs_3>.
 

*&-------------------------------------------------------------------&
*  START-OF-SELECTION
*&-------------------------------------------------------------------&
START-OF-SELECTION.
 
  ls_fieldcatalog-fieldname = 'MANDT'.
  APPEND ls_fieldcatalog TO lt_fieldcatalog.
 
  ls_fieldcatalog-fieldname = 'CARRID'. "Fieldname
  ls_fieldcatalog-inttype = 'C'. "Internal Type C-> Character
  APPEND ls_fieldcatalog TO lt_fieldcatalog.
 
  ls_fieldcatalog-fieldname = 'CONNID'.
  ls_fieldcatalog-inttype = 'N'.
  APPEND ls_fieldcatalog TO lt_fieldcatalog.
 
  ls_fieldcatalog-fieldname = 'FLDATE'.
  ls_fieldcatalog-inttype = 'D'.
  APPEND ls_fieldcatalog TO lt_fieldcatalog.
 
  ls_fieldcatalog-fieldname = 'PRICE'.
  ls_fieldcatalog-inttype = 'P'.
  APPEND ls_fieldcatalog TO lt_fieldcatalog.
 
  ls_fieldcatalog-fieldname = 'CURRENCY'.
  ls_fieldcatalog-inttype = 'C'.
  APPEND ls_fieldcatalog TO lt_fieldcatalog.
 
 
  ASSIGN lt_data TO <fs_data>.
 
 
  CALL METHOD cl_alv_table_create=>create_dynamic_table
       EXPORTING
         it_fieldcatalog = lt_fieldcatalog
       IMPORTING
         ep_table = <fs_data>
       EXCEPTIONS
         generate_subpool_dir_full = 1
         OTHERS = 2  .

  IF sy-subrc <> 0.
  ENDIF.
 
* So  now points to our dynamic internal table.
  ASSIGN <fs_data>->* TO <fs_1>.
 
* Next step is to create a work area for our dynamic internal table.
  CREATE DATA new_line LIKE LINE OF <fs_1>.
 
* A field-symbol to access that work area
  ASSIGN new_line->*  TO <fs_2>.
 
* And to put the data in the internal table
  SELECT mandt
         carrid
         connid
         fldate
         price
         currency
    FROM sflight
    INTO CORRESPONDING FIELDS OF TABLE <fs_1>.
 
* Access contents of internal table
  LOOP AT <fs_1> ASSIGNING <fs_2>.
 
    ASSIGN COMPONENT 2 OF STRUCTURE <fs_2> TO <fs_3>.
    WRITE: / <fs_3>.
 
    ASSIGN COMPONENT 3 OF STRUCTURE <fs_2> TO <fs_3>.
    WRITE: <fs_3>.
 
  ENDLOOP.

Smartform/Sapscript Page Counter - Mode

2008-07-08T02:15:00.000+05:30

Smart Forms records page numbering using page counters. You query these using system fields

&SFSY-PAGE& for the current page number
&SFSY-FORMPAGES& for the total number of pages in the form
&SFSY-JOBPAGE& for the total number of pages of all forms in the print job

You can use the following modes to define which values the different page counters can accept

Initialize : This will reset the page counter.
Increase : Increase the page counter by 1.
Leave Counter Unchanged : Does not increase page counter.
Page and Total Page Unchanged : Hold all the values.

Initialize, Increase, and Hold only change &SFSY-PAGE& accordingly. &SFSY-FORMPAGES& and &SFSY-JOBPAGES& are increased by one regardless of this setting.

Page and Total Page Unchanged has the effect that not only &SFSY-PAGE& but also &SFSY-FORMPAGES& remain unchanged.

Page numbering mode of a form page

Mode of the counter of a form page.

The page counter can be set so that the number of the previous page is incremented, the page number is reset to its initial value, or the previous page number is repeated.

SAP SD Pricing Overview

2008-07-03T17:01:00.000+05:30

Transporting Table Entry

2008-06-24T20:40:00.000+05:30

Content of a table can be transported from dev to quality and to production using transport system. First you need to attach the table entry to a transport and then same procedure applies as in case of transporting abap changes.

Step 1: Open the content of table which you want to transport using transaction SE11. Select 'Transport Entry' from menu.

Step 2 : If you already have a transport then enter in Request input otherwise click on 'new' button to create transport.

Step 3 : Following screen will appear, enter some description and press Save.

Step 4 : A new transport will be created and filled in previous screen as shown in below screen shot. Press OK and you are done.

Now if you see the transport in SE09 you will find that table contenr were attached to transport. Follow the regular transport procedure to transport these table contect further in your SAP landscape.

Sample/Demo code availble in SAP

2008-06-24T19:35:00.000+05:30

SAP has sample programs for all the important functionality available for developer to create report and user interface. Here is the list of important sample program which can be refered while using bespoke functionality.

ALV List

Sample program on REUSE_ALV_LIST_DISPLAY which demonstrate interactive alv, how to show icon on alv, how to show checkbox on alv, how to put hotspot, all these options are available on selection-screen.	BALVSD01
Simple sample program to demonstrate the use of REUSE_ALV_LIST_DISPLAY.	BALVSD02
Sample program for Hierarchical ALV List using REUSE_ALV_HIERSEQ_LIST_DISPLAY.	BALVHD01
Sample program on how to use REUSE_ALV_POPUP_TO_SELECT. This FM gives popup to user with ALV List to select a particular row.	BALV_POPUP_TO_SELECT
Sample program on how to create multiple ALV on same report using block list technique. Fm used for block list alv are REUSE_ALV_BLOCK_LIST_INIT, REUSE_ALV_BLOCK_LIST_APPEND, REUSE_ALV_BLOCK_LIST_DISPLAY	BALVBT01
Sample program on REUSE_ALV_GRID_DISPLAY	BALVSD02_GRID

Application Log Demo programs

Simple Sample Code to create and display Application Log	SBAL_DEMO_01
Demo program to show all possible formats of displaying Application log	SBAL_DEMO_04

Report Object Oriented ALV Grid using class CL_GUI_ALV_GRID

Processing Print Events	BCALV_GRID_01
Display Detail List in Dialog Box Container, Interaction in OO grid adding listener for double click event	BCALV_GRID_02
Detail List in Dialog Window, displaying a second ALV Control in a dialog dynpro.	BCALV_GRID_03
Display Exceptions (LEDs or Traffic Lights)	BCALV_GRID_04
Add a Self-Defined Button to the Toolbar	BCALV_GRID_05
Define Self-Defined Context Menu	BCALV_GRID_06
Define a Menu in the Toolbar	BCALV_GRID_07
Define a Menu with Default Pushbutton	BCALV_GRID_08
Saving Options for Layouts	BCALV_GRID_09
Load a layout before list display	BCALV_GRID_10
Test for new layout function modules	BCALV_GRID_11

Data Input using Object Oriented ALV Grid using class CL_GUI_ALV_GRID

Switch on and off the ready-for-input status of the entire grid	BCALV_EDIT_01
Define ready-for-input status at cell level	BCALV_EDIT_02
Verification of modified cells	BCALV_EDIT_03
Delete and append rows	BCALV_EDIT_04
Checkboxes	BCALV_EDIT_05
Dropdown Listbox at Column Level	BCALV_EDIT_06
Dropdown Listbox at Cell Level	BCALV_EDIT_07
Integrate Non-Standard F4 Help	BCALV_EDIT_08

Object Oriented ALV Tree using class CL_GUI_ALV_TREE

ALV Tree Control: Build Up the Hierarchy Tree	BCALV_TREE_01
ALV Tree Control: Event Handling	BCALV_TREE_02
ALV Tree Control: Use an Own Context Menu	BCALV_TREE_03
ALV Tree Control: Add a Button to the Toolbar	BCALV_TREE_04
ALV Tree Control: Add a Menu to the Toolbar	BCALV_TREE_05
ALV tree control: Icon column and icon for nodes/items	BCALV_TREE_06

SELECT-OPTION in Module Pool Screen

2008-06-24T18:16:00.001+05:30

My favourite interview question 'Can you define select option in module pool?'... Why not? .... How?...

The key for having select-option in module pool is loading selection-screen in module pool screen. We know that defining a select option in selection screen is just a matter of line. But do you know that selection screen can be defined as subscreen and that can be loaded into subscreen area module pool program. Bingo!! You got the solution. Still confused follow below steps

Step 1: Create a report with following code.

REPORT zreport  .

TABLES : ekko , ekpo .

SELECTION-SCREEN BEGIN OF SCREEN 300 AS SUBSCREEN.
PARAMETERS     : p_bukrs  TYPE ekko-bukrs OBLIGATORY DEFAULT '1000'.
SELECT-OPTIONS : s_ebeln  FOR  ekko-ebeln ,
s_ebelp  FOR  ekpo-ebelp .
SELECTION-SCREEN END OF SCREEN 300 . 
 
START-OF-SELECTION .
 
CALL SCREEN 100 .
 

*&---------------------------------------------------------------------*
*&      Module  status_0100  OUTPUT
*&---------------------------------------------------------------------*
MODULE status_0100 OUTPUT.
SET PF-STATUS 'ZPF01' .
SET TITLEBAR 'ZTITLE01' .
ENDMODULE.                 " status_0100  OUTPUT
 

*&---------------------------------------------------------------------*
*&      Module  user_command_0100  INPUT
*&---------------------------------------------------------------------*
MODULE user_command_0100 INPUT.
IF sy-ucomm = 'BACK' OR sy-ucomm = 'EXIT' .
LEAVE TO SCREEN 0 .
ENDIF.
ENDMODULE.                 " user_command_0100  INPUT

Step 2 : Define screen 100 with subcreen area SUB_1 as shown in below screen shot.

Also define PF status and title bar with names 'ZPF01' and 'ZTITLE01' respectively. This is not shown in any screen shot.

Step 3 : Put code in PBO and PA1 of screen as shown in below screen shot.

Activate all objects and execute the report you should get following module pool screen with select-options.

Try these..

Display ALV Grid (OOP) Fullscreen
Use of Application Log FMs to display Message List/Log
Creating custom page format for sapscript/smartform
Reset ALV Export Option for User

Add your own pattern in SE38

2008-06-23T00:04:00.000+05:30

SAP allow user to customize its most of the feature and so is the 'Pattern' feature which very handy for developers. You can actually add your own patterns to the existing ones. Below is the example with step-by-step screen shot. In this example I will create a pattern with name ZREP_TIT.

Step 1 : Open any report in SE38 and click 'Create Pattern' , follow the menu path as shown in below screen shot.

Step 2 : Enter the text which you want to appear when you select the pattern once it is created, then press save button. Once the text is saved exit this screen.

Step 3 : At this point the pattern is created. Lets use it in a report. In SE38 select the 'Pattern' button.

Step 4 : Select 'Other Pattern' and enter 'ZREP_TIT' and you should get the text which you entered in Step 2.

This is just an example, now you have to think about the scenarios which can be converted into Patterns and used again and again to save development time.

Call Transaction in New Window

2008-06-20T13:21:00.001+05:30

call function 'ABAP4_CALL_TRANSACTION'
        starting new task ivbak-vbeln
        exporting
          tcode                         = 'VA03'
          skip_screen                   = 'X'
       tables
          spagpa_tab                    = ispa
       exceptions
         call_transaction_denied       = 1
         tcode_invalid                 = 2
         others                        = 3.

Minimum Code Required to Send SAP Mail

2008-06-20T13:17:00.001+05:30


REPORT  ztest .
 
CONSTANTS : c_high TYPE sodocchgi1-priority VALUE '1' .
 
DATA : i_content TYPE TABLE OF solisti1  ,
       i_rec     TYPE TABLE OF somlreci1 .
 
DATA : wa_docdata TYPE sodocchgi1 ,
       wa_content TYPE solisti1   ,
       wa_rec     TYPE somlreci1  .
 
* Fill document data
wa_docdata-obj_name    = 'MESSAGE' .
wa_docdata-obj_descr   = 'test'    .
wa_docdata-obj_langu   = 'E'       .
wa_docdata-sensitivty  = 'F'       .
wa_docdata-obj_prio    = c_high    .
wa_docdata-no_change   = 'X'       .
wa_docdata-priority    = c_high    .
 
* Fill object content
CLEAR wa_content .
wa_content-line = 'test mail' .
APPEND wa_content TO i_content .
 
* Fill receivers
CLEAR wa_rec .
wa_rec-receiver = sy-uname .
wa_rec-rec_type = 'B'.
APPEND wa_rec TO i_rec .
 
 
CALL FUNCTION 'SO_NEW_DOCUMENT_SEND_API1'
  EXPORTING
    document_data              = wa_docdata
  TABLES
    object_content             = i_content
    receivers                  = i_rec
  EXCEPTIONS
    too_many_receivers         = 1
    document_not_sent          = 2
    document_type_not_exist    = 3
    operation_no_authorization = 4
    parameter_error            = 5
    x_error                    = 6
    enqueue_error              = 7
    OTHERS                     = 8.
 
IF sy-subrc <> 0.
  MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
          WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.

Calculate Tax of Purchase order Line Item

2008-06-20T13:11:00.000+05:30

To display a Tax of a Purchase Order line item follow these screen-shots.

1. Open a PO in ME23N. Select 'Invoice' tab and click on 'Taxes' button.

2. There you see the tax for the PO line item

These were two simple step to get the Tax for PO line item, however if you are unfortunate enough to get requirement to display Tax in PO report then you have to debug tones of SAP standard code to determine how SAP calculated that or you can copy below code.


REPORT zreport10 .
 
TABLES : ekko , ekpo , t001 , komk , komp .
 
DATA mwsbp TYPE komp-mwsbp .
 
PARAMETERS : p_ebeln TYPE ekpo-ebeln ,
             p_ebelp TYPE ekpo-ebelp .
 
 
START-OF-SELECTION .
 
  PERFORM calculate_tax USING p_ebeln p_ebelp CHANGING mwsbp .
 
  WRITE mwsbp .
 
 
*---------------------------------------------------------------------*
*       FORM calculate_tax                                            *
*---------------------------------------------------------------------*
FORM calculate_tax USING    p_ebeln TYPE ekpo-ebeln
                            p_ebelp TYPE ekpo-ebelp
                   CHANGING p_mwsbp TYPE komp-mwsbp .
 
  CONSTANTS: bstyp-info VALUE 'I',
             bstyp-ordr VALUE 'W',
             bstyp-banf VALUE 'B',
             bstyp-best VALUE 'F',
             bstyp-anfr VALUE 'A',
             bstyp-kont VALUE 'K',
             bstyp-lfpl VALUE 'L',
             bstyp-lerf VALUE 'Q'.
 
  DATA : taxcom TYPE taxcom ,
         t_konv TYPE TABLE OF komv WITH HEADER LINE .
 
 
  DATA: BEGIN OF tkomv OCCURS 50.
          INCLUDE STRUCTURE komv.
  DATA: END OF tkomv.
 
  DATA: BEGIN OF tkomvd OCCURS 50. "Belegkonditionen
          INCLUDE STRUCTURE komvd.
  DATA: END OF tkomvd.
 
  DATA : BEGIN OF tkomvh OCCURS 50.
          INCLUDE STRUCTURE komv.
  DATA : vtext LIKE t685t-vtext.
  DATA : END OF tkomvh.
 
  SELECT SINGLE *
    INTO ekko
    FROM ekko
   WHERE ebeln = p_ebeln .
 
  SELECT SINGLE *
     INTO ekpo
     FROM ekpo
    WHERE ebeln = p_ebeln
      AND ebelp = p_ebelp .
 
  SELECT SINGLE *
    INTO t001
    FROM t001
   WHERE bukrs = ekko-bukrs .
 
  taxcom-bukrs = ekpo-bukrs.
  taxcom-budat = ekko-bedat.
  taxcom-waers = ekko-waers.
  taxcom-kposn = ekpo-ebelp.
  taxcom-mwskz = ekpo-mwskz.
  taxcom-txjcd = ekpo-txjcd.
  taxcom-shkzg = 'H'.
  taxcom-xmwst = 'X'.
  IF ekko-bstyp EQ bstyp-best.
    taxcom-wrbtr = ekpo-netwr.
  ELSE.
    taxcom-wrbtr = ekpo-zwert.
  ENDIF.
 
  taxcom-lifnr = ekko-lifnr.
  taxcom-land1 = ekko-lands.
  taxcom-ekorg = ekko-ekorg.
  taxcom-hwaer = t001-waers.
  taxcom-llief = ekko-llief.
  taxcom-bldat = ekko-bedat.
  taxcom-matnr = ekpo-ematn.
  taxcom-werks = ekpo-werks.
  taxcom-bwtar = ekpo-bwtar.
  taxcom-matkl = ekpo-matkl.
  taxcom-meins = ekpo-meins.
 
  IF ekko-bstyp EQ bstyp-best.
    taxcom-mglme = ekpo-menge.
  ELSE.
    IF ekko-bstyp EQ bstyp-kont AND ekpo-abmng GT 0.
      taxcom-mglme = ekpo-abmng.
    ELSE.
      taxcom-mglme = ekpo-ktmng.
    ENDIF.
  ENDIF.
  IF taxcom-mglme EQ 0.
    taxcom-mglme = 1000.
  ENDIF.
  taxcom-mtart = ekpo-mtart.
 
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
 
  CALL FUNCTION 'J_1BSA_COMPONENT_ACTIVE'
       EXPORTING
            bukrs                = ekko-bukrs
            component            = 'BR'
       EXCEPTIONS
            component_not_active = 1
            OTHERS               = 2.
 
  IF sy-subrc IS INITIAL.
 
    komk-mandt = ekko-mandt.
    komk-kalsm = ekko-kalsm.
    IF ekko-kalsm = ''.
      komk-kalsm = 'RM0000'.
    ENDIF.
    komk-kappl = 'M'.
    komk-waerk = ekko-waers.
    komk-knumv = ekko-knumv.
    komk-lifnr = ekko-lifnr.
    komp-kposn = ekpo-ebelp.
    komp-matnr = ekpo-matnr.
    komp-werks = ekpo-werks.
    komp-matkl = ekpo-matkl.
    komp-infnr = ekpo-infnr.
    komp-evrtn = ekpo-konnr.
    komp-evrtp = ekpo-ktpnr.
 
 
    CALL FUNCTION 'RV_PRICE_PRINT_ITEM'
         EXPORTING
              comm_head_i = komk
              comm_item_i = komp
              language    = 'E'
         TABLES
              tkomv       = tkomv
              tkomvd      = tkomvd.
 
 
    CALL FUNCTION 'J_1B_NF_PO_DISCOUNTS'
         EXPORTING
              i_kalsm = ekko-kalsm
              i_ekpo  = ekpo
         IMPORTING
              e_ekpo  = ekpo
         TABLES
              i_konv  = t_konv.
 
    IF NOT ekko-llief IS INITIAL.
      taxcom-lifnr = ekko-llief.
    ENDIF.
 
  ENDIF.
 
  CALL FUNCTION 'FIND_TAX_SPREADSHEET'
       EXPORTING
            buchungskreis = t001-bukrs
       EXCEPTIONS
            not_found     = 1
            OTHERS        = 2.
 
  CALL FUNCTION 'CALCULATE_TAX_ITEM'
       EXPORTING
            i_taxcom            = taxcom
       IMPORTING
            e_taxcom            = taxcom
       EXCEPTIONS
            mwskz_not_defined   = 1
            mwskz_not_found     = 2
            mwskz_not_valid     = 3
            steuerbetrag_falsch = 4
            country_not_found   = 5
            OTHERS              = 6.
 
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
 
  p_mwsbp = taxcom-wmwst  .
 
ENDFORM.                    " calculate_tax

Send report as attachment in background

2008-06-20T13:03:00.000+05:30



REPORT zpwtest .
 
TABLES : t001 .
TYPE-POOLS slis .
 
DATA : t_t001     TYPE TABLE OF t001        ,
       t_abaplist TYPE TABLE OF abaplist    .
 
DATA : w_abaplist TYPE abaplist .
 
SELECT-OPTIONS : s_bukrs FOR t001-bukrs OBLIGATORY .
PARAMETERS     : p_list  TYPE c NO-DISPLAY .
 
START-OF-SELECTION .
 
  IF sy-batch = 'X' AND p_list IS INITIAL .
 
*   Submit report and get list in memory
    SUBMIT zpwtest EXPORTING LIST TO MEMORY
                   WITH s_bukrs IN s_bukrs
                   WITH p_list = 'X'
               AND RETURN.
 
*   Get the list from memory.
    CALL FUNCTION 'LIST_FROM_MEMORY'
         TABLES
              listobject = t_abaplist
         EXCEPTIONS
              not_found  = 1
              OTHERS     = 2.
    IF sy-subrc <> 0.
      MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
              WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    ENDIF.
 
*   Send report to mail receipent
    PERFORM send_mail .
 
  ELSE.
    PERFORM select_data .
    PERFORM display_data .
  ENDIF.
 
*SO_NEW_DOCUMENT_SEND_API1
 
*&---------------------------------------------------------------------*
*&      Form  select_data
*&---------------------------------------------------------------------*
FORM select_data.
 
  SELECT *
    INTO TABLE t_t001
    FROM t001
   WHERE bukrs IN s_bukrs .
 
ENDFORM.                    " select_data
 
*&---------------------------------------------------------------------*
*&      Form  display_data
*&---------------------------------------------------------------------*
FORM display_data.
 
  CALL FUNCTION 'REUSE_ALV_LIST_DISPLAY'
       EXPORTING
            i_structure_name = 'T001'
       TABLES
            t_outtab         = t_t001
       EXCEPTIONS
            program_error    = 1
            OTHERS           = 2.
 
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
 
ENDFORM.                    " display_data
 
*&---------------------------------------------------------------------*
*&      Form  send_mail
*&---------------------------------------------------------------------*
FORM send_mail.
 
  DATA: message_content LIKE soli OCCURS 10 WITH HEADER LINE,
        receiver_list LIKE soos1 OCCURS 5 WITH HEADER LINE,
        packing_list LIKE soxpl OCCURS 2 WITH HEADER LINE,
        listobject LIKE abaplist OCCURS 10,
        compressed_attachment LIKE soli OCCURS 100 WITH HEADER LINE,
        w_object_hd_change LIKE sood1,
        compressed_size LIKE sy-index.
 
 
*  Fot external email id
*  receiver_list-recextnam = 'XXXXXXXXXXXX@XXXXXX.COM'.
*  receiver_list-recesc = 'E'.
*  receiver_list-sndart = 'INT'.
*  receiver_list-sndpri = '1'.
 
* FOr internal email id
  receiver_list-recnam = sy-uname .
  receiver_list-esc_des = 'B'.
  APPEND receiver_list.
 
 
* General data
  w_object_hd_change-objla = sy-langu.
  w_object_hd_change-objnam = 'Object name'.
  w_object_hd_change-objsns = 'P'.
* Mail subject
  w_object_hd_change-objdes = 'Message subject'.
* Mail body
  APPEND 'Message content' TO message_content.
 
  CALL FUNCTION 'TABLE_COMPRESS'
       IMPORTING
            compressed_size = compressed_size
       TABLES
            in              = t_abaplist
            out             = compressed_attachment.
 
 
  DESCRIBE TABLE compressed_attachment.
 
  CLEAR packing_list.
  packing_list-transf_bin = 'X'.
  packing_list-head_start = 0.
  packing_list-head_num = 0.
  packing_list-body_start = 1.
  packing_list-body_num = sy-tfill.
  packing_list-objtp = 'ALI'.
  packing_list-objnam = 'Object name'.
  packing_list-objdes = 'Attachment description'.
  packing_list-objlen = compressed_size.
  APPEND packing_list.
 
  CALL FUNCTION 'SO_OBJECT_SEND'
       EXPORTING
            object_hd_change = w_object_hd_change
            object_type      = 'RAW'
            owner            = sy-uname
       TABLES
            objcont          = message_content
            receivers        = receiver_list
            packing_list     = packing_list
            att_cont         = compressed_attachment.

 
ENDFORM.                    " send_mail

Button on Selection-Screen

2008-06-18T15:21:00.001+05:30

REPORT zreport .
TABLES: sscrfields.
 
DATA smp_dyntxt TYPE smp_dyntxt.
 
SELECTION-SCREEN FUNCTION KEY 1.
PARAMETERS : p_m TYPE mara-matnr .


 
*&---------------------------------------------------------------------*
*& INITIALIZATION
*&---------------------------------------------------------------------*
INITIALIZATION .
 
  CLEAR smp_dyntxt.
  smp_dyntxt-text = text-t01.
  smp_dyntxt-icon_id = '@GX@'.
  smp_dyntxt-icon_text = 'Icon'.
  smp_dyntxt-quickinfo = 'Quick Info Text'.
  smp_dyntxt-path = 'T'.
  sscrfields-functxt_01 = smp_dyntxt.
 
*&---------------------------------------------------------------------*
*& AT SELECTION-SCREEN
*&---------------------------------------------------------------------*
AT SELECTION-SCREEN.
 
  CASE sscrfields-ucomm.
    WHEN 'FC01'.
  ENDCASE .

Here is the screen which you will get

Displaying Two ALV Grid on Screen

2008-06-11T17:34:00.000+05:30

In this tutorial I will try to explain how to display multiple ALV Grid on a single screen. This is a very simple concept, to render or to draw a ALV grid on a screen you need a CONTAINER. Usually we create a CONTAINER with class CL_GUI_CUSTOM_CONTAINER and pass this CONTAINER object while creating ALV grid in parameter I_PARENT. Now to display multiple ALV grid you need multiple CONTAINER, here the class CL_GUI_EAST_SPLITTER_CONTAINER comes in the picture. This class divides a particular CONTAINER into two and give you two CONTAINER in return. How it divides depend on the parameter you pass while creating object. You can divide it horizontally by passing argument CL_GUI_EAST_SPLITTER_CONTAINER=>ORIENTATION_HORIZONTAL or vertically by passing argument CL_GUI_EAST_SPLITTER_CONTAINER=>orientation_VERTICAL. Since it will give you two CONTAINER you can further divide resulting CONATINER into two. So each time you create a object of CL_GUI_EAST_SPLITTER_CONTAINER you get one more CONTAINER. Finally you can use these CONATINER to create ALV Grids, or any GUI controls for example CL_GUI_ALV_TREE or CL_GUI_MOVIE (SAP Movie Control.. sounds interesting).

If you are confuse with above explanation then just forgot it and see the example. I have created a SCREEN 100 with custom container name 'CONTAINER'.

Below is the code for above screen shot.

REPORT zreport.
TABLES : scarr .
DATA : it_scarr TYPE TABLE OF scarr .
 
DATA : ob_custom TYPE REF TO cl_gui_custom_container ,
       ob_split1 TYPE REF TO cl_gui_easy_splitter_container ,
       ob_split2 TYPE REF TO cl_gui_easy_splitter_container ,
       ob_grid1  TYPE REF TO cl_gui_alv_grid ,
       ob_grid2  TYPE REF TO cl_gui_alv_grid ,
       ob_grid3  TYPE REF TO cl_gui_alv_grid .
 
SELECT-OPTIONS : s_carrid FOR scarr-carrid .
 
START-OF-SELECTION .
 
SELECT *
  INTO TABLE it_scarr
  FROM scarr
 WHERE carrid IN s_carrid .
 
CALL SCREEN 100 .
 
*&---------------------------------------------------------------------*
*& Module status_0100 OUTPUT
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
 
MODULE status_0100 OUTPUT.
   SET TITLEBAR 'ZTITLE01' .
   SET PF-STATUS 'ZPF01' .

* This will create a container
   CREATE OBJECT ob_custom
      EXPORTING
        container_name = 'CONTAINER' . 
 
* This spit the container OB_CUSTOM into two
   CREATE OBJECT ob_split1
      EXPORTING
        parent = ob_custom
        orientation = cl_gui_easy_splitter_container=>orientation_vertical .
 
* Now we have two container
* OB_SPLIT1->TOP_LEFT_CONTAINER
* OB_SPLIT1->BOTTOM_RIGHT_CONTAINER
* Since these two are itself a container we can further devide them into two.
* Let try to divide OB_SPLIT1->BOTTOM_RIGHT_CONTAINER into two
 
    CREATE OBJECT ob_split2
       EXPORTING
          parent = ob_split1->bottom_right_container
          orientation = cl_gui_easy_splitter_container=>orientation_horizontal .
 
* Now we have total 3 container available with us
* OB_SPLIT1->TOP_LEFT_CONTAINER
* OB_SPLIT2->TOP_LEFT_CONTAINER
* OB_SPLIT2->BOTTOM_RIGHT_CONTAINER
* Note that OB_SPLIT1->BOTTOM_RIGHT_CONTAINER is not available because we divided
* that into two.
* Now Put a grid in each container
 
   CREATE OBJECT ob_grid1
      EXPORTING
        i_parent = ob_split1->top_left_container .
 
   CREATE OBJECT ob_grid2
      EXPORTING
        i_parent = ob_split2->top_left_container .
 
   CREATE OBJECT ob_grid3
      EXPORTING
        i_parent = ob_split2->bottom_right_container .
 
   CALL METHOD ob_grid1->set_table_for_first_display
      EXPORTING
        i_structure_name = 'SCARR'
      CHANGING
        it_outtab = it_scarr.
 
   CALL METHOD ob_grid2->set_table_for_first_display
      EXPORTING
         i_structure_name = 'SCARR'
      CHANGING
         it_outtab = it_scarr.
 
   CALL METHOD ob_grid3->set_table_for_first_display
      EXPORTING
        i_structure_name = 'SCARR'
      CHANGING
        it_outtab = it_scarr.
 
ENDMODULE. " status_0100 OUTPUT
 
*&---------------------------------------------------------------------*
*& Module user_command_0100 INPUT
*&---------------------------------------------------------------------*
* text
*----------------------------------------------------------------------*
MODULE user_command_0100 INPUT.

   IF sy-ucomm = 'BACK' OR sy-ucomm = 'EXIT' .
      FREE : ob_grid1 ,
             ob_grid2 ,
             ob_grid3 ,
             ob_split1 ,
             ob_split2 ,
             ob_custom .

       LEAVE TO SCREEN 0 .
   ENDIF.

ENDMODULE. " user_command_0100 INPUT

Function Module for getting information of Dictionary Object

2008-06-11T14:31:00.000+05:30

DDIF_DOMA_GET	To get information of domain e.g. data type, length, value table, check table and also value range.
DDIF_DTEL_GET	To get information of Data Element e.g. description, output length, memory id, texts etc.
DDIF_TABL_GET	To get information of Data Dictionary Table, its give type of table, field name, corresponding data element and domain. Bassically all the information available in SE11 will be provided by this FM. It can also be used to get information for structures.
DDIF_TABT_PUT	To get information of Technical Setting of table
DDIF_TTYP_GET	To read information of a Table Type from the ABAP Dictionary
DDIF_VIEW_GET	Reads the Dictionary sources of a view.

HR ABAP 02 - Getting Started - LDB PNP

2008-06-05T19:27:00.000+05:30

This blog belong to the series of blogs on HR ABAP. You may like to read following blogs first before you read this one.

HR ABAP 01- Data Stuctures - Infotypes Explained

Assuming that you already have knowledge of ABAP, I will try to explain thing specific/different to HR-ABAP. So when I write statement INCLUDE or TABLE I will not explain the meaning of it, rather I will more concentrate on the syntax uncommon to ABAP but required in HR-ABAP.

Logical database PNP can be activated/used by specifying it in program attributes in SE38. We use logical database in HR ABAP to retrieve data. It fulfill three main function:

1. Logical database take care of the relation between the infotypes and retrieve correct information for you for each employee. You don’t have to worry about the primary key and foreign key extra.
2. It provides you a consistent selection screen and automatic screening of data based on the input by user on selection screen.
3. Last but not the least is implicit authorization check. Authorization issue is taken care by logical database centrally.

This how a selection screen will look when you use logical database PNP (by default).

Consider following piece of code…

The INFOTYPE nnnn statement creates an internal table with the name Pnnnn for each declared infotype.

When the GET event occurs, the tabke of declared infotypes are filled with all of the record that exist for personnel number. The field PERNR-PERNE contains the personnel number.

When the GET event occurs, all internal infotype tables are filled. Therefore, only declare the infotypes you wish to process.

PROVIDE..ENDPROVIDE statement loops at all records of P0002 whose validity period overlaps the period selected in selection-screen. Selection-screen period is stored in PN-BEGDA and PN-ENDDA. PN Structure is defines in include DBDPNPCOM.

For example, if you choose current year in selection-screen, PN-BEGDA contains the first day of the year and PN-ENDDA contains the last day of the year. If you do not enter any data for the period in selection screen , PN-BEGDA contains the low date (01-01-1800) and PN-ENNDA contains the high date (31-12-9999) .

PROVIDE.. ENDPROVIDE can be replaced by LOOP.. ENLOOP statement, however PROVIDE.. ENDPROVIDE offer a wide variety of options.

For example, if the infotype you are processing contains subtype then you must include WHERE option in PROVIDE..ENDPROVIDE. In below example, processing of the infotype Address (0006) is restricted to subtype 1 (Permanent Address).

Frequently, you only want to display employees with data of specific infotype. In this case use the CHECK LINES(Pnnnn) statement to determine the number of filled line of an infotype table. See screen-shot below.

PROVIDE..ENDPROVIDE provides data for a specific period, that is according to the data selection period. In case more than one data exist for a specific period, only most recent or olderst infotype record is required from the selected period, rather than all of the records. The RP_PROVIDE_FROM_LAST and RP_PROVIDE_FROM_FRST macro can be used in such situation.

Once again consider the selection-screen of a typical HR-ABAP report.

Selection-screen is divided in two parts namely period and personal selection. Person selection is used to determine a group of employees for whom an evaluation takes place. For example, all of the monthly wage earners in a particular personnel subarea. The selection screen enables you to change the sort sequence for HR records.

The data from the start and end dates of the data selection period is transferred to fields PN-BEGDA and PN-ENDDA. If you use a data selection period, infotype data records are entered in the PROVIDE loop of their validity periods overlap with the period selected by at least one day.

The start and end dated of the person selection period that are entered by the use are available in the field PN-BEGPS and PN-ENDPS. This interval is the criterion used for selecting personnel number to be processed. All personnel numbers that fulfill the selection criteria specified at any given time in the person selection period entered by the user are used in processing.

If the period is specified using radio button, the fields PN-BEGDA/ENDDA and PN-BEGPS/ENDPS contains the same period.

All the selection-screen parameters define in report will appear after these two blocks.

All the fields are defined in include DBPNPSEL; as usual initial values can be set in INITIALIZATION event.

HR ABAP 01- Data Stuctures - Infotypes Explained

2008-05-31T15:34:00.002+05:30

Infotypes are information unit in HR. You can call Infotypes a structure, but if you do so then there will not be any difference in ABAP and HR-ABAP.
Groups of related data fields are bundled into Infotypes. Infotypes facilitates data entry and allow data to be saved for specific period; it serves as template for users to enter data. There is a time constraint in Infotypes, which determine how Infotype react to each other in terms of time. Several Infotypes have subtypes, which breakdown information further.

Database in HR includes transparent table and Cluster tables. Pannnn, PBnnnn and HRPnnnn are the transparent table and PCLn are clustered tables. In HR programming data is not directle extracted from these tables.

Infotypes are grouped in different number range.

0000-0999	HR Master data
1000-1999	Personal Planning
2000-2999	Time Management
4000-4999	Recruitment
9000-9999	Customer Specific

Technical Data Structures of Infotypes in Personal Administration
Each PAnnnn infotype table is defined in ABAP Dictionary using structure PAKEY, PSHD1 and PSnnnn. PAKEY and PSHD1 contains infotype table key field and administrative information on the infotype record. PSnnnn actually contains infotype specific information and data.

Each personnel administration infotype contains an include CI_Pnnnn in data structure PSnnnn. Customer-specific fields can be added to this include as enhancement to an infotype. In standard SAP system this include is empty.

Logical structure Pnnnn is used within program to store the data from Infotypes. The structure of Pnnnn is given below. No data record exits in database for this structure. These logical structures are primarily used in HR to avoid direct database access.

The Pnnnn structure contains an infotype's key fields and data fields. It contains INFTY field for infotype number, it does not contains MANDT field.

Structure Qnnnn exists for many infotypes. It contains screen field for data entry.

Control Data for Infotypes.

Each infotype have several dependent objects. Table T777D contains name for all infotype-dependent repository object such as table, structures, program subtypes and idocs.

Table T77ID supplements the above table for reason of memory space.

Apart from above two table T582A and T77CD exists to enable customer-specific setting for administration and planning respectively.

Report RHT777DCHECK can be used to see whether a infotype is consistently defined in the SAP System or not.

Subtypes

Subtypes are used to further break down infotypes, for example, to further classify infotype 0006 into main address, second address, business address and so on. As explained about subtype information can be found in control table T777D. Usually subtype field is SUBTY however it may also be field other than that and contains value of the subtype. In that case table T777D will have that information. See screen shot below for the subtype field for infotype 0006.

Debug a Background Job

2008-05-19T21:21:00.000+05:30

How to debug a background job?
Goto SM37 select the job which you want to debug and type JDBG in the OK-code, press Enter. Remember the key word JDBG.

Problem with Printing Page Number in Smartforms

2008-05-09T19:38:00.000+05:30

Total page number is displayed as '*'. A Smart Form has 10 or more pages. If you use SFSY-FORMPAGES to display the total number of pages, then you see only '*' on all pages between 1 and 9.

Reason Error in the 'symbol_write' subroutine. The length of SFSY_FORMPAGES was processed incorrect, even if you reserved enough space by using a formatting option like (3ZC).

Solution Apply SAP Note Number: 779492

Dynamic Selection Screen/Capturing Option button click

2008-02-18T20:02:00.002+05:30

This sample code illustrate how to captue a click of option button on selection screen and then based on the option button selected respective input will be made available to user to input data.

REPORT zpwtest.
 
TABLES : mara ,
t001 ,
t001w .
 
CONSTANTS : c_yes TYPE c VALUE '1' ,
c_no TYPE c VALUE '0' .
 
*Define three option button with USER-COMMAND clause
*Note the in option button group you can specify USER-COMMAND only once

PARAMETERS : p_opt1 TYPE c RADIOBUTTON GROUP radi USER-COMMAND op1 , "Material
p_opt2 TYPE c RADIOBUTTON GROUP radi ,                  "Company Code
p_opt3 TYPE c RADIOBUTTON GROUP radi .                  "Plant

*Define user inputs for respective option button, uset MODIF ID
*to identify the control as run time

SELECT-OPTIONS : s_mara FOR mara-matnr MODIF ID op1 , "Material 
s_bukrs FOR t001-bukrs MODIF ID op2 , "Company Code

s_werks FOR t001w-werks MODIF ID op3 . "Plant


 
*At selecttion screen output act as PBO where we can change the screen
*attributes, inside LOOP AT SCREEN
AT SELECTION-SCREEN OUTPUT .

LOOP AT SCREEN .

IF screen-group1 = 'OP1' .
IF p_opt1 = 'X' .
screen-invisible = c_no .
screen-active = c_yes .
ELSE.
screen-invisible = c_yes .
screen-active = c_no .
ENDIF.
MODIFY SCREEN .
ENDIF.

IF screen-group1 = 'OP2' .
IF p_opt2 = 'X' .
screen-invisible = c_no .
screen-active = c_yes .
ELSE.
screen-invisible = c_yes .
screen-active = c_no .
ENDIF.
MODIFY SCREEN .
ENDIF.

IF screen-group1 = 'OP3' .
IF p_opt3 = 'X' .
screen-invisible = c_no .
screen-active = c_yes .
ELSE.
screen-invisible = c_yes .
screen-active = c_no .
ENDIF.
MODIFY SCREEN .
ENDIF.

ENDLOOP.

SAP MM Document Flow, Transaction and Tables

2008-02-12T22:41:00.000+05:30

MM Process Flow

1. Purchase Requisition (ME51N)

Material requirement are identified either by the user, department or via material planning and control. For example a MRP Run in production planning or material falling short of reorder-point can automatically generate Purchase Requisition. At the same time PR can be created manually in the system.

2. Source Determination - RFQ (ME41)

Identify the possible source of supply based on the past order and existing long term purchase contract. Then create Request for Quotation, which can be then sent electronically to vendors.

3. Vendor Selection and Comparision of Quotation (ME49)

After receiving quotation system is capable to simulate pricing scenarios, allowing user to compare number of quotations and sent rejection letter automarically.

4. Purchase Order (ME21N)

Data from Quotation or Purchase Requisition can be adopted to create Purchase Orders. Purchase Order is then sent to Vendor to supply the goods.

5. Purchase Order Follow ups ME91, ME91F, ME92F

Reminder can be sent to vendors at predefined intervals.

6. Goods Receipts (MB01)

Goods were received.

7. Invoice Verification (MIRO)

Along with the goods vendor also submits Invoice, system verifies then invoice against the quantity received and PO data. The account payable clerk is notified.

Important Transactions in MM

MM01 Material Creation
Me51N Purchase Requisition
Me41 Request for Quotation
Me49 Comparision of Quotation
Me21N Purchase Order Creation
MIGO, MB01 Goods Receipt
MIRO Invoice Verification
MB1A Good Issue

Tables in MM

MARA Material General
MARC Material Plant Data
MAKT Material Description
MARD Material Storage Location Data
MAST Material BOM Link
MBEW Material Valuation
MKPF Material Document Header
MSEG Mateial Document Line Item
MVKE Mateial Sales Data
T023 Material Group
T024 Pruchase Organisation

EBAN Purchase Requisition
EBKN Account Assignment Purchase Requisition

EINA Purchasing Info Record - General Data
EINE Purchase Info Record - Purchase Organisation Data

EKKO Purchase Order Header Data
EKPO Purchase Order Line Item Data
EKKN Account Assignment Purchase Order
EKBE History Purchase Order
EKET Scheduling Agreement Purchase Order
EKAB Release Documentation

Restrict options available with SELECT-OPTIONS

2008-02-07T18:22:00.000+05:30

Type : Sample Code
Coded/Tested on Ver : SAP R/3 Enterprise

FM to SELECT_OPTIONS_RESTRICT can be use to supress options available with a SELECT-OPTIONS on a selection screen.

REPORT zpwtest.

*Include type pool SSCR
TYPE-POOLS sscr.
TABLES : marc.

*Define the object to be passed to the RESTRICTION parameter
DATA restrict TYPE sscr_restrict.

*Auxiliary objects for filling RESTRICT
DATA : optlist TYPE sscr_opt_list,
ass TYPE sscr_ass.

*Defining the selection-screen
SELECT-OPTIONS : s_matnr FOR marc-matnr,
s_werks FOR marc-werks.

INITIALIZATION.

*Restricting the MATNR selection to only EQ and 'BT'.
optlist-name = 'OBJECTKEY1'.
optlist-options-eq = 'X'.
optlist-options-bt = 'X'.
APPEND optlist TO restrict-opt_list_tab.

ass-kind = 'S'.
ass-name = 'S_MATNR'.
ass-sg_main = 'I'.
ass-sg_addy = space.
ass-op_main = 'OBJECTKEY1'.
APPEND ass TO restrict-ass_tab.

*Restricting the WERKS selection to CP, GE, LT, NE.
optlist-name = 'OBJECTKEY2'.
optlist-options-cp = 'X'.
optlist-options-ge = 'X'.
optlist-options-lt = 'X'.
optlist-options-ne = 'X'.
APPEND optlist TO restrict-opt_list_tab.

ass-kind = 'S'.
ass-name = 'S_WERKS'.
ass-sg_main = 'I'.
ass-sg_addy = space.
ass-op_main = 'OBJECTKEY2'.
APPEND ass TO restrict-ass_tab.

CALL FUNCTION 'SELECT_OPTIONS_RESTRICT'
EXPORTING
restriction = restrict
EXCEPTIONS
too_late = 1
repeated = 2
selopt_without_options = 3
selopt_without_signs = 4
invalid_sign = 5
empty_option_list = 6
invalid_kind = 7
repeated_kind_a = 8
OTHERS = 9.

IF sy-subrc <> 0.
MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.

Applying Change Document Technique on you Custom Table

2008-02-01T15:18:00.000+05:30

Type : Tutorial
Coded/Tested on Ver : SAP R/3 Enterprise

Change document concept is used to track down changes made to the data SAP. Whenever there is a change in data Change documents are created and stored in table CDHR, CDPOS. Data stored in table CDHDR and CDPOS, records all aspect of the changes made for example date, time, userid, table name, field name, old values, new values, currency and unit value if value changed happens to be price or quantity.

When you create custom table you need to follow some step before this whole concept work for you to record the changes. Overall there are three activities

1. Mark 'Change document'

Mark 'Change document' checkbox of data elememt of each field where you want the changes to be logged. Later on when system goes to log the changes, the dictionary is searched for which fields are to be logged for each table in the object definition.

2. Create 'Change Document Object' using transaction SCDO

A change document object definition contains the tables which represent a commercial object in the system. The definition can also specify whether the deletion of individual fields is to be documented. If a table contains fields whose values refer to units and currency fields, the associated table, containing the units and currencies, can also be specified.

2.a . Run transaction SCDO and press Create button

2.b. Enter name of the object class, this will be represent your object centrally in Change Document.

2.c. On next screen enter description of the object then add tables to it. In this example we have only one table 'ZMM_REQ_MATTYP', however in real life scenario a object class can have more than one table. For example the object class BANF was defined for the change document object "Purchase requisition", which consists of the tables EBAN (purchase requisition) and EBKN (purchase requisition account assignment).

In case of a object class with multiple table we use Object ID to differentiate between different table, .e.g. The object value BANF with the object ID "3000000000" consists of the records of the tables EBAN and EBKN with the order number "3000000000".

After inputting all relevant tables, choose Insert entries. The new entries are copied into the display. Then save your record.

2.d. We need to generate the Function Module which we will use in our program to create Change Document. We need to call these function module each time we perform any modification on data. Choose 'Generate update pgm' from Utilities menu.

2.e. Input function group name and press 'Generate' button.

2.f. Confirm following information and press 'Save' button

You will get message 'All generation made for object xxxxx' if everything goes well..

Above procedure will create function group with function module Zobject_name_WRITE_DOCUMENT. We need to call this function module before we execute any MODIFY, INSERT or DELETE command

Multiple Lines Header and Records in ALV List

2008-01-31T20:37:00.002+05:30

Type : Sample Code
Coded/Tested on Ver : SAP R/3 Enterprise

Few days back I faced a wierd user requirement to print multiple line header in ALV. Thank god user agreed to do this report in ALV List, in which I managed to print the header in multiple lines. Here is the sample program which shows how to achieve this functionality. Using similar technique one can print a long record in multiple lines. See screen shot below. Last column of the report is printed in multiple rows. Function Module RKD_WORD_WRAP is used to split the content into multiple lines.

REPORT zpw_alv_multipleline .
TYPE-POOLS slis .


*----------------------------------------------------------------------*
* Data Declarations
*----------------------------------------------------------------------*
CONSTANTS : c_len TYPE i VALUE 20 .

TYPES : BEGIN OF ty_t100 ,
sprsl TYPE t100-sprsl ,
arbgb TYPE t100-arbgb ,
msgnr TYPE t100-msgnr ,
text TYPE t100-text ,
fline TYPE t100-text ,
END OF ty_t100 .

TYPES : BEGIN OF ty_wrd ,
text TYPE char20 ,
END OF ty_wrd .

DATA : it_t100 TYPE TABLE OF ty_t100    ,
it_sentence TYPE TABLE OF ty_wrd ,
wa_t100 TYPE ty_t100             ,
wa_word TYPE ty_wrd              ,
v_repid TYPE syst-repid          ,
v_tabix TYPE syst-tabix          .

DATA : it_fld TYPE slis_t_fieldcat_alv ,
it_evt TYPE slis_t_event        ,
wa_fld TYPE slis_fieldcat_alv   ,
wa_evt TYPE slis_alv_event      ,
wa_lay TYPE slis_layout_alv     .


*----------------------------------------------------------------------*
* Initialization
*----------------------------------------------------------------------*
INITIALIZATION .
v_repid = sy-repid .


*----------------------------------------------------------------------*
* Start of Selection
*----------------------------------------------------------------------*
START-OF-SELECTION .


* Get some test data to display in ALV List
SELECT *
INTO TABLE it_t100
FROM t100
WHERE sprsl = 'EN'
AND arbgb = '00' .

LOOP AT it_t100 INTO wa_t100 .
v_tabix = sy-tabix .
CLEAR : it_sentence .


*   Word Wrap the text in multiple lines
CALL FUNCTION 'RKD_WORD_WRAP'
EXPORTING
textline  = wa_t100-text
outputlen = c_len
TABLES
out_lines = it_sentence.

IF NOT it_sentence IS INITIAL .
READ TABLE it_sentence INTO wa_word INDEX 1 .
wa_t100-fline = wa_word-text .
MODIFY it_t100 FROM wa_t100 INDEX v_tabix .
ENDIF.

ENDLOOP.


* Prepare fieldcatelog
CLEAR wa_fld .
wa_fld-fieldname = 'SPRSL' .
wa_fld-ref_tabname = 'T100' .
wa_fld-ref_fieldname = 'SPRSL' .
APPEND wa_fld TO it_fld .

CLEAR wa_fld .
wa_fld-fieldname = 'ARBGB' .
wa_fld-ref_tabname = 'T100' .
wa_fld-ref_fieldname = 'ARBGB' .
APPEND wa_fld TO it_fld .

CLEAR wa_fld .
wa_fld-fieldname = 'MSGNR' .
wa_fld-ref_tabname = 'T100' .
wa_fld-ref_fieldname = 'MSGNR' .
APPEND wa_fld TO it_fld .

CLEAR wa_fld .
wa_fld-fieldname = 'FLINE' .
wa_fld-inttype = 'CHAR' .
wa_fld-outputlen = 20 .
wa_fld-intlen = 20.
wa_fld-seltext_l = 'Text' .
wa_fld-ddictxt = 'L' .
APPEND wa_fld TO it_fld .


* Get event.. we will handle BEFORE and AFTER line output
CALL FUNCTION 'REUSE_ALV_EVENTS_GET'
IMPORTING
et_events = it_evt.

READ TABLE it_evt INTO wa_evt
WITH KEY name = slis_ev_after_line_output .
wa_evt-form = slis_ev_after_line_output .
MODIFY it_evt FROM wa_evt INDEX sy-tabix .

READ TABLE it_evt INTO wa_evt
WITH KEY name = slis_ev_top_of_page .
wa_evt-form = slis_ev_top_of_page .
MODIFY it_evt FROM wa_evt INDEX sy-tabix .
wa_lay-no_colhead = 'X' .

CALL FUNCTION 'REUSE_ALV_LIST_DISPLAY'
EXPORTING
i_callback_program = v_repid
it_fieldcat        = it_fld
is_layout          = wa_lay
it_events          = it_evt
TABLES
t_outtab           = it_t100.



*---------------------------------------------------------------------*
* FORM top_of_page *
*---------------------------------------------------------------------*
FORM top_of_page .
ULINE AT 1(58) .
FORMAT COLOR COL_HEADING .
WRITE: / sy-vline ,
02 'Header1' ,
10 sy-vline ,
11 'Header1' ,
31 sy-vline ,
32 'Header1' ,
37 sy-vline ,
38 'Header1' ,
58 sy-vline .
WRITE: / sy-vline ,
02 'Header2' ,
10 sy-vline ,
11 'Header2' ,
31 sy-vline ,
32 'Header2' ,
37 sy-vline ,
38 'Header2' ,
58 sy-vline .

ENDFORM.                    "top_of_page



*---------------------------------------------------------------------*
* FORM AFTER_LINE_OUTPUT *
*---------------------------------------------------------------------*
FORM after_line_output USING rs_lineinfo TYPE slis_lineinfo .

CLEAR : it_sentence ,
wa_t100      .

READ TABLE it_t100 INTO wa_t100 INDEX rs_lineinfo-tabindex .
CHECK sy-subrc = 0 .

CALL FUNCTION 'RKD_WORD_WRAP'
EXPORTING
textline  = wa_t100-text
outputlen = c_len
TABLES
out_lines = it_sentence.

DESCRIBE TABLE it_sentence LINES v_tabix .
CHECK v_tabix > 1 .

LOOP AT it_sentence INTO wa_word FROM 2 .
WRITE: / sy-vline ,
10 sy-vline ,
31 sy-vline ,
37 sy-vline ,
38 wa_word-text ,
58 sy-vline .
ENDLOOP.

ENDFORM .                    "after_line_output

Code to Upload and Download Standard Texts

2008-01-31T15:41:00.001+05:30

Type : Utility
Coded/Tested on Ver : SAP R/3 Enterprise

This program can be used to download Standard text to presentation server. Later one can modify the file with new language and corresponding translated text and upload it to create same standard text in new languages.

REPORT zpwupld .

TABLES thead .

*&---------------------------------------------------------------------*
*& DATA
*&---------------------------------------------------------------------*
TYPES : BEGIN OF ty_text ,
          tdobject TYPE stxh-tdobject ,
          tdname TYPE stxh-tdname ,
          tdid TYPE stxh-tdid ,
          tdspras TYPE stxh-tdspras ,
        END OF ty_text ,

        BEGIN OF ty_data ,
          tdobject TYPE stxh-tdobject ,
          tdname TYPE stxh-tdname ,
          tdid TYPE stxh-tdid ,
          tdspras TYPE stxh-tdspras ,
          line TYPE char2 ,
          tdformat TYPE tdformat ,
          tdline TYPE tdline ,
        END OF ty_data .

DATA : i_text TYPE TABLE OF ty_text ,
       i_data TYPE TABLE OF ty_data .

*&---------------------------------------------------------------------*
*& SELECTION-SCREEN
*&---------------------------------------------------------------------*
PARAMETERS : p_up TYPE c RADIOBUTTON GROUP radi ,
             p_do TYPE c RADIOBUTTON GROUP radi .
PARAMETERS : p_path TYPE text100 OBLIGATORY .
SELECT-OPTIONS : s_name FOR thead-tdname NO-EXTENSION NO INTERVALS ,
                 s_object FOR thead-tdobject NO-EXTENSION NO INTERVALS ,
                 s_id FOR thead-tdid NO-EXTENSION NO INTERVALS ,
                 s_lan FOR thead-tdspras NO-EXTENSION NO INTERVALS .
PARAMETERS : p_over TYPE c AS CHECKBOX .

*&---------------------------------------------------------------------*
*& AT SELECTION-SCREEN
*&---------------------------------------------------------------------*
AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_path .
  PERFORM get_file_help .

*&---------------------------------------------------------------------*
*& AT SELECTION-SCREEN
*&---------------------------------------------------------------------*
AT SELECTION-SCREEN .
  IF p_do = 'X' .
    IF s_name[] IS INITIAL .
      MESSAGE e208(00) WITH 'Enter Text Name'.
    ENDIF.
  ENDIF.

*&---------------------------------------------------------------------*
*& START OF SELECTION
*&---------------------------------------------------------------------*
START-OF-SELECTION .
  IF p_do = 'X' .
    PERFORM select_data .
  ENDIF.
  IF p_up = 'X' .
    PERFORM upload_and_update .
  ENDIF.

*&---------------------------------------------------------------------*
*& Form get_file_help
*&---------------------------------------------------------------------*
FORM get_file_help.
  DATA : i_file TYPE filetable ,
         w_file TYPE file_table ,
         l_rc TYPE i ,
         l_ua TYPE i .

  CALL METHOD cl_gui_frontend_services=>file_open_dialog
    CHANGING
      file_table              = i_file
      rc                      = l_rc
      user_action             = l_ua
    EXCEPTIONS
      file_open_dialog_failed = 1
      cntl_error              = 2
      error_no_gui            = 3
      OTHERS                  = 4.

  IF l_ua <> cl_gui_frontend_services=>action_cancel .
    READ TABLE i_file INTO w_file INDEX 1 .
    IF sy-subrc = 0 .
      p_path = w_file-filename .
    ENDIF.
  ENDIF.

ENDFORM. " get_file_help

*&---------------------------------------------------------------------*
*& Form SELECT_DATA
*&---------------------------------------------------------------------*
FORM select_data.
  DATA : w_text TYPE ty_text ,
         i_std TYPE TABLE OF tline WITH HEADER LINE ,
         w_data TYPE ty_data ,
         l_file TYPE string .

  SELECT tdobject
         tdname
         tdid
         tdspras
    INTO TABLE i_text
    FROM stxh
   WHERE tdobject IN s_object
     AND tdname IN s_name
     AND tdid IN s_id
     AND tdspras IN s_lan .

  IF sy-subrc <> 0 .
    MESSAGE i208(00) WITH 'No Data Found!'.
    LEAVE LIST-PROCESSING .
  ENDIF.

  LOOP AT i_text INTO w_text .
    REFRESH i_std[] .

    CALL FUNCTION 'READ_TEXT'
      EXPORTING
        id       = w_text-tdid
        language = w_text-tdspras
        name     = w_text-tdname
        object   = w_text-tdobject
      TABLES
        lines    = i_std.

    CLEAR w_data .
    w_data-tdobject = w_text-tdobject .
    w_data-tdname = w_text-tdname .
    w_data-tdid = w_text-tdid .
    w_data-tdspras = w_text-tdspras .

    LOOP AT i_std .
      w_data-line = sy-tabix .
      WRITE w_data-line TO w_data-line RIGHT-JUSTIFIED .
      TRANSLATE w_data-line USING ' 0' .
      w_data-tdformat = i_std-tdformat .
      w_data-tdline = i_std-tdline .
      APPEND w_data TO i_data .
    ENDLOOP.

  ENDLOOP .

  l_file = p_path .

* This method call will download the internal table data
* to path specified in variable l_file
  CALL METHOD cl_gui_frontend_services=>gui_download
    EXPORTING
      filename = l_file
    CHANGING
      data_tab = i_data.

ENDFORM. " SELECT_DATA

*&---------------------------------------------------------------------*
*& Form upload_and_update
*&---------------------------------------------------------------------*
FORM upload_and_update .

  DATA :  w_text TYPE ty_text ,
          i_std TYPE TABLE OF tline WITH HEADER LINE ,
          w_data TYPE ty_data ,
          w_temp TYPE ty_data ,
          l_file TYPE string ,
          i_dd TYPE TABLE OF text_512 ,
          w_dd TYPE text_512 ,
          l_header TYPE thead ,
          l_stxh TYPE stxh .
          l_file = p_path .

  CALL METHOD cl_gui_frontend_services=>gui_upload
    EXPORTING
      filename = l_file
    CHANGING
      data_tab = i_dd.

  LOOP AT i_dd INTO w_dd .
    CLEAR w_data .
    w_data-tdobject = w_dd+0(10) .
    w_data-tdname = w_dd+10(70) .
    w_data-tdid = w_dd+80(4) .
    w_data-tdspras = w_dd+84(1) .
    w_data-line = w_dd+85(2) .
    w_data-tdformat = w_dd+87(2) .
    w_data-tdline = w_dd+89(132).
    APPEND w_data TO i_data .
  ENDLOOP .

  SORT i_data BY tdobject tdname tdid tdspras line.

  LOOP AT i_data INTO w_data .
    w_temp = w_data .
    AT NEW tdspras .
      CLEAR l_header .
      REFRESH i_std .
    ENDAT .

    CLEAR i_std .
    i_std-tdformat = w_temp-tdformat .
    i_std-tdline = w_temp-tdline .
    APPEND i_std .

    AT END OF tdspras .
      CLEAR l_stxh .

      SELECT SINGLE *
        INTO l_stxh
        FROM stxh
       WHERE tdobject = w_temp-tdobject
         AND tdname = w_temp-tdname
         AND tdid = w_temp-tdid
         AND tdspras = w_temp-tdspras .

      IF sy-subrc = 0 .
        IF p_over = space .
          WRITE : / w_temp-tdname COLOR COL_GROUP,
          w_temp-tdspras COLOR COL_GROUP.
          CONTINUE .
        ENDIF.
      ENDIF.
      l_header-tdobject = w_temp-tdobject .
      l_header-tdname = w_temp-tdname .
      l_header-tdid = w_temp-tdid .
      l_header-tdspras = w_temp-tdspras .

      CALL FUNCTION 'SAVE_TEXT'
        EXPORTING
          header          = l_header
          savemode_direct = 'X'
        TABLES
          lines           = i_std
        EXCEPTIONS
          id              = 1
          language        = 2
          name            = 3
          object          = 4
          OTHERS          = 5.

      IF sy-subrc <> 0.
        WRITE : / w_temp-tdname COLOR COL_NEGATIVE,
        w_temp-tdspras COLOR COL_NEGATIVE.
      ELSE.
        WRITE : / w_temp-tdname COLOR COL_POSITIVE,
        w_temp-tdspras COLOR COL_POSITIVE.
      ENDIF.

    ENDAT .
  ENDLOOP .

ENDFORM. " upload_and_update

To handle unicode chracters you need to take care of following

1. Your program should be unicode compatible .i.e. in SE38 goto Attributes of this upload dowload code and check that 'Unicode check active' is checked

2. In SAP GUI multibyte functionality must be active.

This setting will take place only you restart you SAP logon pad .i.e. close all the session and restart the SAP Logon.

3. The text file should be saved as 'Unicode Encoding'